Compucolor.org – Virtual Media

Listing of file='FWORD.BAS;01' on disk='vmedia/ccug_14b-sector.ccvf'

0 CLEAR 1000:POKE 32940,236:POKE 32941,153:CLEAR 100
1 PLOT 27,4:PRINT "LOAD FWORD.XXX":PLOT 27,27
2 POKE 33283,237:POKE 33284,153
4 PLOT 27,11,6,6,14
5 PLOT 12:PRINT "FIND-A-WORD"
6 PRINT :INPUT "DO YOU NEED INSTRUCTIONS? ";A$
7 IF LEFT$ (A$,1)= "Y"THEN 1000
10 CLEAR 2000
11 PLOT 12
15 PLOT 6,6,15
20 DIM A$(20,10),W$(29)
25 INPUT "HOW MANY WORDS DO YOU WANT ME TO HIDE? ";N
30 N= N- 1:PRINT :PRINT :PRINT "ENTER WORDS":PRINT
31 IF N> 24THEN N= 24
40 FOR I= 0TO N:PRINT RIGHT$ (" "+ STR$ (I+ 1),3);
42 INPUT ") ";W$(I):NEXT I:PLOT 12
43 GOSUB 3000
45 PLOT 6,0
50 DEF FN R(Z)= INT (RND (1)* Z)
60 FOR I= 0TO 20:FOR J= 0TO 10:A$(I,J)= "+"
70 PLOT 3,3* I+ 1,2* J:PRINT "+"
75 NEXT J,I
80 FOR I= 0TO N
90 DX= FN R(3)- 1:DY= FN R(3)- 1
100 IF DX+ DY= 0THEN 90
110 L= LEN (W$(I))
120 SX= FN R(21- L* ABS (DX)):IF DX< 0THEN SX= 20- SX
130 SY= FN R(11- L* ABS (DY)):IF DY< 0THEN SY= 10- SY
140 CX= SX:CY= SY
150 FOR J= 1TO L
160 L$= MID$ (W$(I),J,1)
170 IF A$(CX,CY)= "+"THEN 190
180 IF L$< > A$(CX,CY)THEN 90
190 CX= CX+ DX:CY= CY+ DY
200 NEXT J
205 CX= SX:CY= SY
210 FOR J= 1TO L
220 A$(CX,CY)= MID$ (W$(I),J,1)
230 PLOT 3,3* CX+ 1,2* CY:PRINT A$(CX,CY)
235 CX= CX+ DX:CY= CY+ DY
240 NEXT J,I
250 FOR I= 0TO 20:FOR J= 0TO 10
260 IF A$(I,J)< > "+"THEN 290
270 L= FN R(26)+ 65
280 PLOT 3,3* I+ 1,2* J,L
290 NEXT J,I
300 PLOT 3,0,23
303 AD= 27392
304 X= 1:Y= 22
305 PLOT 6,6
310 FOR I= 0TO N
320 PLOT 3,X,Y:PRINT W$(I);:PLOT 8:PRINT
325 POKE AD,LEN (W$(I)):POKE AD+ 1,0
330 Y= Y+ 1:AD= AD+ 128
335 IF Y> 31THEN Y= 22:X= X+ 12:AD= AD- 1256
336 POKE AD,0:POKE AD+ 1,0
340 NEXT I
350 Z= CALL (0)
360 PLOT 3,1,21
361 PLOT 6,1
365 INPUT "PLAY AGAIN? ";A$
370 IF LEFT$ (A$,1)= "Y"THEN RUN 10
380 PLOT 1
1000 PLOT 12
1010 PRINT "     YOU INPUT A LIST OF WORDS (UP TO 25).  I HIDE THEM, AND"
1020 PRINT "YOU TRY TO FIND THEM.  WORDS MAY BE FORWARD OR BACKWARD, AND"
1030 PRINT "MAY BE POSITIONED VERTICALLY, HORIZONTALLY, OR DIAGONALLY."
1040 PRINT "WHEN YOU FIND A WORD, MOVE THE CURSOR TO A LETTER OF THE WORD"
1045 PRINT "BY PRESSING THE APPROPRIATE CURSOR CONTROL (GRAY ARROW) KEYS,"
1050 PRINT "AND PRESS THE RED ('Q') KEY.  DO THIS FOR ALL LETTERS IN THE"
1060 PRINT "WORD.  WHEN YOU HAVE FINISHED, ALL LETTERS IN THE WORD WILL"
1070 PRINT "TURN YELLOW.  IF YOU ACIDENTALLY CHANGE THE COLOR OF A LETTER"
1080 PRINT "YOU DO NOT WANT, POSITION THE CURSOR OVER THE LETTER, AND"
1090 PRINT "PRESS THE KEY OF THE COLOR THAT THE LETTER SHOULD BE.  IF YOU"
1095 PRINT "DECIDE TO QUIT, PRESS THE '(ESC)' KEY NEAR THE UPPER LEFT"
1097 PRINT "CORNER OF THE KEYBOARD."
1100 PRINT :INPUT "PRESS 'ENTER' TO START.";A$
2000 GOTO 10
3000 PRINT "PLEASE WAIT WHILE I HIDE THE WORDS."
3005 FOR I= 0TO N:IF LEN (W$(I))> 11THEN W$(I)= LEFT$ (W$(I),11)
3006 NEXT I
3010 FOR I= 0TO N- 1
3020 FOR J= I+ 1TO N
3030 IF W$(J)> W$(I)THEN 3050
3040 A$= W$(I):W$(I)= W$(J):W$(J)= A$
3050 NEXT J,I
3060 PLOT 12
3070 RETURN