Compucolor.org – Virtual Media

Listing of file='LIST.BAS;01' on disk='vmedia/chip_57-sector.ccvf'

5 CLEAR 500
10 PLOT 12,3,12,4,14,6,28
20 PRINT "  S T O C K    L I S T I N G S  ":PLOT 15,6,3:PRINT :PRINT
30 PRINT SPC( 10)"SELECT FROM THE FOLLOWING LIST :":PRINT :PRINT
40 PRINT SPC( 14)"1. LIST INDEX DISC":PRINT
50 PRINT SPC( 14)"2. LIST DATA DISC":PRINT
60 PRINT SPC( 14)"3. LIST LOW STOCKS":PRINT
65 PRINT SPC( 14)"4. RETURN TO MENU":PRINT :PRINT
70 PRINT SPC( 20);:INPUT "ENTER DESIRED SELECTION : ";SE
75 IF XY= > 20THEN 90
80 IF SE< 1OR SE> 4THEN PLOT 28,11:GOTO 70
90 ON SEGOTO 1000,2000,1900,3000
1000 PLOT 12,3,15,14
1001 INPUT "INSERT INDEX DISC - HIT 'RETURN' : ";Z$
1005 FILE "T",1015
1010 FILE "R",1,"PARTS.INX",1:FILE "R",2,"EQPT.INX",1
1012 GOTO 1020
1015 PRINT :PRINT SPC( 15)"FILE NOT ON DISC":PRINT :PRINT SPC( 15);:GOTO 1001
1020 GOSUB 6000
1030 FOR I= 1TO 2100:GET 1;PT$[8]:GET 2;EN$[16]
1040 IF VAL (PT$)= - 99OR VAL (EN$)= - 99THEN 1070
1050 PRINT SPC( 5)PT$;TAB( 15)EN$:GOTO 1080
1070 XS= XS+ 1:IF XS= > 20THEN XS= 0:GOTO 1090
1080 NEXT
1090 POKE 33265,TMP
1100 PRINT :PRINT SPC( 20);:INPUT "HIT 'ENTER' TO CONTINUE : ";Z$:GOTO 5
1900 PRINT :PRINT SPC( 14);:INPUT "ENTER MINIMUM ACCEPTABLE STOCK : ";MN
2000 PLOT 12,3,15,14
2001 INPUT "INSERT DATA DISC - HIT 'RETURN' : ";Z$
2005 FILE "T",2015
2010 FILE "R",1,"STOCKS",1:FILE "R",2,"DATA",1:GET 2,1,1;DD:FILE "C",2
2012 GOTO 2020
2015 PRINT :PRINT SPC( 15)"FILE NOT ON DISC":PRINT :PRINT SPC( 15);:GOTO 2001
2020 GOSUB 6000
2030 FOR I= 1TO 420
2040 GET 1;PN$[8],D$[25],EN$[16],LO$[7],QT
2045 IF VAL (PN$)= - 99THEN XS= XS+ 1:GOTO 2070
2047 IF SE= 3AND QT= > MNTHEN GOTO 2080
2050 PRINT SPC( 5)PN$;TAB( 15)EN$;TAB( 33)LO$;TAB( 48)QT
2060 GOTO 2080
2070 IF XS= > 20THEN XS= 0:GOTO 2100
2080 NEXT
2100 POKE 33265,TMP
2110 PRINT SPC( 15);:INPUT "HIT 'ENTER' TO CONTINUE : ";Z$:GOTO 5
3000 PLOT 12,3,15,14:INPUT "INSERT PROGRAM DISC - HIT 'RETURN' : ";Z$:PLOT 1
6000 REM
6010 REM  ***********************************************
6012 REM
6014 REM  ** PRINTER SELECTION AND PRINTOUT OF HEADER **
6016 REM
6020 PRINT :PRINT SPC( 15);:INPUT "OUTPUT TO PRINTER OR SCREEN ? ";P$
6030 IF P$< > "P"AND P$< > "S"THEN PLOT 28,11:GOTO 6020
6040 IF P$= "P"THEN TMP= PEEK (33265):PLOT 27,18,3,27,13
6042 IF P$= "S"THEN PLOT 12,3,0,5
6044 PRINT SPC( 15);:IF SE> 1GOTO 6046
6045 PRINT "INDEX DISK ENTRIES":GOTO 6050
6046 PRINT "RECORDS ON DATA DISK "DD:IF SE= 2GOTO 6050
6047 PRINT :PRINT SPC( 15)"WITH STOCK QUANTITY OF LESS THAN "MN
6050 PRINT :PRINT
6060 PRINT SPC( 5)"PART";TAB( 15)"EQPT.";:IF SE< > 1THEN PRINT TAB( 33)"LOCATION";TAB( 48)"QTY.
6065 IF SE= 1THEN PRINT
6070 PRINT SPC( 5)"NUMBER";TAB( 15)"NUMBER";:IF SE< > 1THEN PRINT TAB( 33)"(BIN NO.)":PRINT
6075 PRINT
6080 RETURN