Compucolor.org – Virtual Media

Listing of file='11P1.BAS;01' on disk='vmedia/color_graphics_1_suits-sector.ccvf'

5 REM  PROGRAM 11.1
6 REM  BLANK MENU
9
10 CLEAR 2000
20 DIM F$(27):REM  MAXIMUM OF 27 FILES
29
30 FOR J= 1TO 52:D$= D$+ ".":NEXT
33
34 REM  ENTER THE FILE NAMES STARTING AT LINE 40. FOR EXAMPLES:
35
36 REM        F$(1)="SUPER-HYPER REAL TIME SPACE OPERA"
37 REM        F$(2)="SANSKRIT -- LESSON II"
38 REM        ETC.
39
499
500 PLOT 15:REM  SMALL CHARACTERS; POSSIBLE BLINK OFF
510 PLOT 6,3,29:REM  SET COLORS; FLAG OFF
520 PLOT 12,27,11:REM  ERASE SCREEN; SCROLL MODE
528
529 REM  FIND OUT HOW MANY FILES THERE ARE
530 K= 0
539
540 FOR J= 27TO 1STEP - 1
550   IF F$(J)< > ""THEN K= J:J= 1
560 NEXT
569
570 IF K< 6THEN PLOT 14:REM  DOUBLE HEIGHT IF THERE'S ROOM
579
580 PRINT TAB( 27)"M E N U":PRINT
589
590 IF K= 0THEN PRINT :PRINT "NO FILES AVAILABLE!":END
597
598 REM  PRINT THE FILE NAMES
599
600 FOR J= 1TO K
610   PRINT TAB( 2)LEFT$ (F$(J)+ D$,52)J
618
619   REM  SPACE BETWEEN SELECTIONS IF THERE'S ROOM
620   IF K< 15THEN PRINT
630 NEXT
638
639 REM  SKIP A LINE AFTER ALL FILE NAMES HAVE BEEN PRINTED
640 IF K> 14THEN PRINT
649
650 PRINT TAB( 2)"ENTER YOUR SELECTION NUMBER AND ";
660 INPUT "PRESS RETURN ....... ";A$
670 F= VAL (A$)
678
679 REM  CHECK FOR INPUT ERROR
680 IF F< 1OR F< > INT (F)OR F> KTHEN 28,11:GOTO 650
686
687 REM  REPRINT CHOSEN FILE NAME IN RED
688
689 REM  FIRST GET Y CO-ORDINATE OF FILE NAME
690 IF K< 7THEN Y= 4* F+ 1
700 IF K> 6AND K< 15THEN Y= 2* F
710 IF K> 14THEN Y= F+ 1
719
720 PLOT 3,2,Y:PRINT F$(F)
729
730 PLOT 3,64,0:REM  HIDE THE CURSOR
739
740 ON FGOTO 801,802,803,804,805,806,807,808,809,810
750 ON F- 10GOTO 811,812,813,814,815,816,817,818,819,820
760 ON F- 20GOTO 821,822,823,824,825,826,827
799
800 REM  ENTER LAOD AND RUN INSTRUCTIONS BEGINNING AT 801