Compucolor.org – Virtual Media

Listing of file='12P6.BAS;01' on disk='vmedia/color_graphics_1_suits-sector.ccvf'

5 REM  PROGRAM 12.6
6 REM  AN ANIMATED JOKE
8
9 REM  SET UP
10 GOSUB 100
18
19 REM  PAUSE
20 GOSUB 200
28
29 REM  BIG BIRD
30 GOSUB 300
38
39 REM  PAUSE
40 GOSUB 200
48
49 REM  LITTLE BIRDS
50 GOSUB 500
58
59 REM  FIRST MESSAGE
60 GOSUB 700
68
69 REM  SECOND MESSAGE
70 GOSUB 800
78
79 REM  PAUSE
80 GOSUB 200
88
89
90 PLOT 6,2:END
95
96
97 REM   ********** SUBROUTINES **********
98
99 REM   ----- SET UP
100 PLOT 15,30,22,12:REM SMALL CHARACTERS; CLEAR SCREEN IN CYAN
110 PLOT 18,3,0,31,11:REM  ERASE BOTTOM LINE IN GREEN
120 PLOT 22,29,17:REM  BG=CYAN, FG=RED; FLAG OFF
130 RETURN
198
199 REM  ----- PAUSE
200 PLOT 8:FOR T= 1TO 2000:NEXT :RETURN
298
299 REM  ----- BIG BIRD
300 X= 40
309
310 FOR Y= 0TO 29
320   PLOT 3,X,Y:PRINT "    iidii"
330   PLOT 3,X,Y:PRINT "  iiggfdfggii"
339
340   GOSUB 470:REM  SLIGHT PAUSE
349
350   PLOT 3,X,Y:PRINT "iiiggggggdggggggiii"
360   PLOT 3,X,Y:PRINT "iggggggggdggggggggi"
370   PLOT 3,X,Y:PRINT "ffggiiiiidiiiiiggff"
380   PLOT 3,X,Y:PRINT "eeffggiiidiiiggffee"
388
390   GOSUB 470:REM  SLIGHT PAUSE
399
400   PLOT 3,X,Y:PRINT "gggggggggdggggggggg"
410   PLOT 3,X,Y:PRINT "iiigggfffdfffgggiii"
419
420   PLOT 28,11
430   X= X- 1
440 NEXT
449
450 PLOT 3,X+ 9,30:PRINT "d"
459
460 RETURN
468
469 REM  ----- SLIGHT PAUSE
470 FOR T= 1TO 30:NEXT :RETURN
498
499 REM  ----- LITTLE BIRDS
500 FOR J= 29TO 3STEP - 2
510 X= J:R= 30* RND (1)
519
520   FOR Y= 2TO 31
530     IF Y< 30THEN PLOT 3,X,Y:PRINT "ggggsgggg"
540     PLOT 3,X- 3,Y- 2:PRINT " igfsfgi"
550     IF Y< 30THEN PLOT 3,X,Y:PRINT " igfsfgi"
559
560     FOR T= 1TO R:NEXT
569
570     PLOT 3,X- 3,Y- 2:PRINT "ggggsgggg"
580     IF Y< 30THEN PLOT 3,X,Y:PRINT "ggggsgggg"
590     PLOT 3,X- 3,Y- 2:PRINT "efgisigfe"
600     IF Y< 30THEN PLOT 3,X,Y:PRINT "efgisigfe"
610     PLOT 3,X- 3,Y- 2:PRINT "ggggsgggg"
620     IF Y< 30THEN PLOT 3,X,Y:PRINT SPC( 9)""
630     PLOT 3,X- 3,Y- 2:PRINT SPC( 9)""
640     IF Y= 29THEN PLOT 3,X+ 5,30:PRINT "a"
649
650     X= X+ 1
660   NEXT
669
670   PLOT 3,X+ 1,30:PRINT "a"
679
680   FOR T= 1TO 2500* RND (1):NEXT
689
690 NEXT :RETURN
698
699 REM  ----- FIRST MESSAGE
700 PLOT 16:REM  FOREGROUND=BLACK
710 PLOT 2,37,15,242,34,25,255
719
720 PLOT 3,10,24:PRINT "YOU MAY WONDER WHY I'VE"
730 PLOT 3,8,25:PRINT "BROUGHT YOU ALL HERE TODAY"
739
740 GOSUB 200:REM  PAUSE
749
750 GOSUB 930:REM  ERASE MESSAGE
759
760 RETURN
798
799 REM  ----- SECOND MESSAGE
800 PLOT 2,85,17,242,83,24,242,253,100,20,242,90,30
810 PLOT 253,110,20,242,110,29,255
820 PLOT 14:REM  DOUBLE HEIGHT CHARACTERS
829
830 PLOT 3,40,24:PRINT "YES"
840 PLOT 3,43,22:PRINT "YES!"
849
850 PLOT 15:REM  REGULAR HEIGHT
860 PLOT 30:REM  FLAG ON FOR QUADRUPLE HEIGHT CHARACTERS
870 PLOT 3,53,23
880 PLOT 124,126,32,123,101,32,99,102
890 PLOT 3,53,24
900 PLOT 98,32,32,108,127,32,103,100
910 PLOT 29:REM  FLAG OFF
919
920 GOSUB 200:REM  PAUSE
928
929 REM  ERASE MESSAGE
930 FOR Y= 22TO 29:PLOT 3,0,Y,11:NEXT
939
940 RETURN