Compucolor.org – Virtual Media

Listing of file='MENU.BAS;0A' on disk='vmedia/comm_pgms-sideB-sector.ccvf'

10 REM  *** TERMINAL EMULATOR DRIVER ***
15 REM
20 REM  SET UP THE DEFAULT VALUES AS FOLLOWS:
25 REM  BAUD RATE:   DB = 1,2,3,4
30 REM  DUPLEX:      DD = 1 (HALF) OR 255 (FULL)
35 REM  PARITY:      DP = 255 (ODD), 0 (NONE), 1 (EVEN)
40 REM  AUTO-REPEAT: AR = 0 (DISABLE), 1 (ENABLE)
45 REM
50 DB =  3:DD =  255:DP =  0:AR =  1
55 REM
65 REM  BAUD RATE MASKS
70 DIM  B(5):B(1)= 1:B(2)= 130:B(3)= 132:B(4)= 136
75 REM
100 PLOT  6,2,29,12:PRINT "BASIC DRIVER FOR TERMINAL EMULATOR"
110 PLOT  27,4:PRINT  "LOAD TERM":PLOT  27,27
115 POKE  33282,195:POKE  33283,4:POKE  33284,144:REM  CALL(X) VECTOR
120 INPUT "BAUD RATE (110,150,300 OR 1200) ? ";BR
121 IF  BR= 0 THEN  BR= DB
122 IF BR= 110THEN BR= 1
123 IF BR= 150THEN BR= 2
124 IF BR= 300THEN BR= 3
125 IF BR= 1200THEN BR= 4
126 IF  BR< 0 OR  BR> 4 GOTO  120
127 POKE  36864,B(BR)
130 INPUT  "HALF OR FULL DUPLEX (H OR F) ? ";DP$
131 POKE  36865,DD
132 IF DP$= "H"THEN POKE 36865,1
133 IF DP$= "F"THEN POKE 36865,255
140 INPUT  "EVEN, ODD OR NO PARITY (E, O, OR N) ?) ";PR$
141 POKE  36866,DP
142 IF  PR$= "E" THEN  POKE  36866,1
143 IF  PR$= "N" THEN  POKE  36866,0
144 IF  PR$= "O" THEN  POKE  36866,255
150 INPUT  "ENABLE AUTO-REPEAT FEATURE (Y OR N) ? ";AN$
151 POKE  36867,AR
152 IF  AN$= "Y" THEN  POKE  36867,1
153 IF  AN$= "N" THEN  POKE  36867,0
190 INPUT  "SAVE THIS CONFIGURATION (Y OR N) ? ";AN$
191 IF  AN$< > "Y" GOTO  200
192 INPUT  "FILE NAME ";FN $
193 PLOT  27,4:PRINT  "SAVE ";FN $;",9000-9470,9004,9000"
194 PLOT  27,27
200 X =  CALL (0)
210 PLOT 12
240 INPUT "RE-ESTABLISH COMMUNICATIONS ? ";AN$
250 IF LEFT$ (AN$,1)= "Y"GOTO 200
300 END