Listing of file='DEP.BAS;01' on disk='vmedia/equity-sector.ccvf'
100 REM ** DEPRECIATION - DEC 21,1978 **
110 CLEAR 100
120 PLOT 29,14,6,34,12,27,11,3,8,0,6,40
130 PRINT " C O M P U C O L O R C O R P O R A T I O N "
140 PLOT 6,34:PRINT
150 PRINT "THIS PROGRAM WILL CALCULATE THE DEPRECIATION OF";
160 PRINT " AN ASSET BY ANY"
170 PRINT "OF THE FOLLOWING METHODS.":PRINT
180 RESTORE 200:PLOT 6,35
190 FOR I= 1 TO 6:READ L$:PRINT TAB( 15);I;". ";L$:NEXT I
200 DATA "STRAIGHT-LINE "
210 DATA "DOUBLE-DECLINING-BALANCE"
220 DATA "CONSTANT-PERCENTAGE "
230 DATA "SUM-OF-THE-DIGITS "
240 DATA "SINKING-FUND"
250 DATA "EXIT PROGRAM"
260 PRINT :PRINT TAB( 9):PLOT 6,37
270 INPUT "ENTER LINE NUMBER OF DEPRECIATION DESIRED ";DT
280 IF DT< 1 OR DT> 6 THEN 120
290 IF DT= 6 THEN LOAD "MENU":RUN
300 REM
310 PLOT 14
320 PLOT 6,34,12,3,20,0,6,40
330 PRINT " D E P R E C I A T I O N "
340 RESTORE 200
350 FOR I= 1 TO DT: READ L$: NEXT I
360 L$= " "+ L$+ " METHOD "
370 PLOT 3,((64- LEN (L$))/ 2)+ 1,2:PRINT L$
380 PLOT 15,3,0,4,6,39
390 PRINT "VALUE OF ASSET"
400 PRINT " START OF PERIOD:";
410 INPUT "";A:V= A: PLOT 3,18,5: GOSUB 1170:PRINT
420 IF DT= 2 THEN 450
430 PRINT " END OF PERIOD:";
440 INPUT "";S:V= S: PLOT 3,18,6: GOSUB 1170: PRINT
450 IF DT< > 3 OR S> 0 THEN 490
460 PRINT
470 PRINT "DEPRECIATION RATE PER PERIOD (%) ";
480 INPUT "";RD
490 PLOT 3,37,5: PRINT "NUMBER OF YEARS"
500 PLOT 3,37,6: PRINT "DEPRECIATED OVER: ";
510 INPUT "";N
520 IF N= 0 THEN 490
530 IF DT< > 5 THEN 580
540 PLOT 3,37,8: PRINT "INTEREST RATE ON"
550 PLOT 3,37,9: PRINT "SINKING FUND (%): ";
560 INPUT "";IS:IS= IS/ 100
570 IF IS= 0 THEN 540
580 PLOT 3,0,10
590 FOR I= 1TO 63:PRINT "-";:NEXT I
600 PRINT
610 PRINT TAB( 22);"DEPRECIATION BOOK"
620 PRINT TAB( 13);"YEAR EXPENSE VALUE"
630 FOR I= 1TO 63:PRINT "-";:NEXT I
640 PRINT
650 REM ******CALCULATE***********
660 ON DT GOTO 670,690,720,780,820
670 REM ********STRAIGHT-LINE***********
680 GOTO 860
690 REM *******DOUBLE DECLINING********
700 DR= 2/ N
710 GOTO 750
720 REM *******DECLINING***************
730 DR= 1- (S/ A)^ (1/ N)
740 IF S= 0 THEN DR= RD/ 100
750 PLOT 3,0,8:PRINT "ANNUAL DEPRECIATION RATE: ";INT (DR* 10000)/ 100;"%";
760 PRINT " "
770 GOTO 860
780 REM *******SUM OF DIGITS***********
790 SD= 0
800 FOR J= 1 TO N: SD= SD+ J:NEXT J
810 GOTO 860
820 REM *******SINKING FUND************
830 SN= ((1+ IS)^ N- 1)/ IS
840 SN= (A- S)/ SN
850 REM
860 BV= A: IT= 0
870 PLOT 18,3,0,14:V= A: PRINT TAB( 38): GOSUB 1170: PRINT
880 FOR I= 1 TO N
890 ON DT GOTO 900,930,940,970,1000
900 REM ***STRAIGHT-LINE
910 DE= (A- S)/ N
920 GOTO 1020
930 REM ***DOUBLE DECLINING
940 REM ***DECLINING
950 DE= BV* DR
960 GOTO 1020
970 REM ***SUM OF DIGITS
980 DE= ((N+ 1- I)/ SD)* (A- S)
990 GOTO 1020
1000 REM ***SINKING FUND
1010 DE= SN* (1+ IS)^ (I- 1)
1020 BV= BV- DE
1030 PLOT 19:PRINT TAB( 13);I;
1040 PLOT 17: V= DE : PRINT TAB( 22):GOSUB 1170
1050 PLOT 18: V= BV : PRINT TAB( 38):GOSUB 1170
1060 IF N< 13 THEN 1130
1070 IT= IT+ 1:IF IT< 12 THEN 1130
1080 IT= 0: PRINT :PRINT
1090 INPUT " HIT RETURN TO CONTINUE LISTING";I$
1100 IF I$= "END" THEN I= N:GOTO 1130
1110 PLOT 3,0,14: FOR K= 1 TO 15: PLOT 11: PRINT : NEXT K
1120 PLOT 3,0,14
1130 PRINT : NEXT I
1140 PLOT 3,0,28
1150 INPUT "TO RETURN TO DEPRECIATION MENU - HIT RETURN ";I$
1160 GOTO 120
1170 REM
1180 IF V> - .005 AND V< .005 THEN V= 0
1190 D1= INT (ABS (V)):IF V< 0 THEN D1= - D1
1200 E1= INT ((1.005+ ABS (V)- ABS (D1))* 100)
1210 PRINT RIGHT$ (" "+ STR$ (D1)+ "."+ RIGHT$ (STR$ (E1),2),10);
1220 RETURN