Compucolor.org – Virtual Media

Listing of file='ADDACT.BAS;01' on disk='vmedia/home_budget_1-sector.ccvf'

100 REM  *************** ADD ACCOUNTS ************************
110 REM
120 GOTO 350
130 REM
140 REM  ****************** YES/NO ***************************
150 POKE 33278,0
160 IF PEEK (33278)= 0GOTO 160
170 IF PEEK (33278)= 89THEN PRINT "ES":Q$= "Y":RETURN
180 IF PEEK (33278)= 78THEN PRINT "O":Q$= "N":RETURN
190 PLOT 26,32,26:GOTO 150
200 REM
210 REM  ************** INKEY (SINGLE KEY INPUT) *************
220 POKE 33278,0
230 Y= PEEK (33278)
240 IF Y= 0GOTO 230
250 Y$= CHR$ (Y):RETURN
260 REM
270 REM  *************** PROTECTED FIELDS ********************
280 PO= PEEK (32940)+ PEEK (32941)* 256+ 1:SA= 28672+ 128* Y+ X+ X:ZZ= INT (SA/ 256):POKE PO+ 3,SA- 256* ZZ:POKE PO+ 4,ZZ:SA= SA- 2:POKE PO+ 1,ASC (NA$):FI$= ""
290 PLOT 3,X,Y:KB= CALL (ML):IF KB= 9OR PEEK (PO)= 0THEN RETURN
300 FOR I= 2TO PEEK (PO)* 2STEP 2:FI$= FI$+ CHR$ (PEEK (SA+ I)):NEXT I:RETURN
350 PLOT 27,4:PRINT "RUN FIELDS":PLOT 27,27:CLEAR 5000
360 DD= PEEK (65535):DSK$= MID$ (STR$ (DD- 1),2)+ ":"
400 IF DD= 1THEN PLOT 12,14,3,10,15:INPUT "LOAD DATA DISK AND HIT <RETURN> ";A
420 PLOT 12,15,3,25,1:PRINT "ADD ACCOUNTS"
430 PRINT :PRINT :PRINT "OPTIONS ARE:"
440 PRINT :PRINT "	1. ADD INCOME ACCOUNT (OTHER THAN PAY)"
450 PRINT "	2. ADD A BANK ACCOUNT"
460 PRINT "	3. ADD EXPENDITURE ACCOUNT (OTHER THAN PAY DEDUCTION)"
470 PRINT "	4. ADD AN ASSET ACCOUNT"
480 PRINT "	5. ADD A LIABILITY ACCOUNT"
490 PRINT "	9. END"
500 PRINT :PRINT :PRINT "PLEASE MAKE A SELECTION....";:GOSUB 220:ANS= VAL (Y$):PRINT
510 IF NOT ((ANS> = 1AND ANS< = 5)OR ANS= 9)THEN PLOT 7:GOTO 420
520 ON ANSGOSUB 1000,2000,3000,4000,5000,9000,9000,9000,9000
530 GOTO 420
1000 REM  ************* ADD INCOME ACCOUNT ********************
1010 REM
1020 FILE "R",1,DSK$+ "INCTIT",1
1030 GET 1,1;NREC:NACCT= NREC- 1
1040 IF NACCT> 18THEN 1200
1050 PLOT 12,3,1,1:PRINT "CURRENT ACCOUNTS ARE:"
1060 PLOT 3,32,1:PRINT "SUGGESTED INCOME CATEGORIES ARE:"
1070 FOR REC= 2TO NREC- 1
1080 GET 1,REC;NAME$[12]:PLOT 3,5,REC+ 3:PRINT REC- 1,""NAME$""
1090 NEXT REC
1100 PLOT 3,32,5:PRINT " 1. PAY"
1110 PLOT 3,32,6:PRINT " 2. CHILD ENDOWMENT"
1120 PLOT 3,32,7:PRINT " 3. SOCIAL WELFARE"
1130 PLOT 3,32,8:PRINT " 4. DIVIDENDS AND INTEREST"
1140 PLOT 3,32,9:PRINT " 5. RENTAL INCOME"
1150 PLOT 3,32,10:PRINT " 6. BUSINESS INCOME"
1160 GOSUB 10000:REM           INPUT PAY DETAILS
1170 PUT 1,NREC;INCAC$[12],BUDCAT$[1],TAX$[1],FRQ$[2],FAMT
1180 NREC= NREC+ 1:PUT 1,1;NREC
1190 PLOT 12:GOTO 1210
1200 PLOT 7,12,3,5,15:PRINT "YOU HAVE USED YOUR QUOTA OF 19 INCOME ACCOUNTS"
1210 PRINT :PLOT 3,5,17:PRINT "DO YOU WISH TO ADD ANY MORE INCOME ACCOUNTS (Y/N)? ";:GOSUB 150:IF NOT (Q$= "Y"OR Q$= "N")THEN PLOT 7,28,11,28:GOTO 1210
1220 IF Q$= "Y"THEN 1030
1230 FILE "C",1:RETURN
2000 REM  ************* ADD BANK ACCOUNT ********************
2010 REM
2020 FILE "R",1,DSK$+ "BNKTIT",1
2030 GET 1,1;NREC:NACCT= NREC- 1
2040 IF NACCT> 9THEN 2200
2050 PLOT 12,3,1,1:PRINT "CURRENT ACCOUNTS ARE :"
2060 PLOT 3,32,1:PRINT "SUGGESTED 'BANK' CATEGORIES ARE:"
2065 IF NACCT= 1GOTO 2100
2070 FOR REC= 2TO NREC- 1
2080 GET 1,REC;NAME$[12]:PLOT 3,5,REC+ 3:PRINT REC- 1,""NAME$""
2090 NEXT REC
2100 PLOT 3,32,5:PRINT " 1. SAVINGS ACCOUNTS"
2110 PLOT 3,32,6:PRINT " 2. CHEQUE ACCOUNTS"
2120 PLOT 3,32,7:PRINT " 3. BUILDING SOCIETIES"
2130 PLOT 3,32,8:PRINT " 4. CREDIT UNIONS"
2160 GOSUB 11000:REM           INPUT BANK DETAILS
2170 PUT 1,NREC;BNKAC$[12],DETAIL$[13],BAL,LDATE$[9]
2180 NREC= NREC+ 1:PUT 1,1;NREC
2190 PLOT 12:GOTO 2210
2200 PLOT 7,12,3,5,15:PRINT "YOU HAVE USED YOUR QUOTA OF 9 BANK ACCOUNTS"
2210 PRINT :PLOT 3,5,17:PRINT "DO YOU WISH TO ADD ANY MORE BANK ACCOUNTS (Y/N)? ";:GOSUB 150:IF NOT (Q$= "Y"OR Q$= "N")THEN PLOT 7,28,11,28:GOTO 2210
2220 IF Q$= "Y"THEN 2030
2230 FILE "C",1:RETURN
3000 REM  ************* ADD EXPENDITURE ACCOUNT ***************
3010 REM
3020 FILE "R",1,DSK$+ "EXPTIT",1
3030 GET 1,1,5;NREC:NACCT= NREC- 1
3040 IF NACCT> 63THEN 3340
3050 IF NACCT> 1THEN PLOT 12,3,1,1:PRINT "CURRENT ACCOUNTS ARE :"
3060 IF NACCT= 1GOTO 3130
3070 FOR REC= 2TO NREC- 1
3080 GET 1,REC;NAME$[12]
3090 IF REC< = 15THEN PLOT 3,0,REC+ 1:PRINT REC- 1;" "NAME$"":GOTO 3130
3084 IF REC< = 29THEN PLOT 3,16,REC- 13:PRINT REC- 1;" "NAME$"":GOTO 3130
3110 IF REC< = 43THEN PLOT 3,32,REC- 27:PRINT REC- 1;" "NAME$"":GOTO 3130
3120 PLOT 3,48,REC- 41:PRINT REC- 1;" "NAME$""
3130 NEXT REC
3132 PLOT 3,5,25:PRINT "DO YOU WISH TO SEE SAMPLE CATEGORIES (Y/N)? ";:GOSUB 150:IF NOT (Q$= "Y"OR Q$= "N")THEN PLOT 7:GOTO 3132
3140 IF Q$= "N"THEN PLOT 28,11:GOTO 3300
3150 PLOT 12:PRINT "SAMPLE CATEGORIES OF EXPENDITURE ACCOUNTS ARE:"
3160 PRINT :PRINT :PRINT "LIFE INSURANCE			HOUSEHOLD INSURANCE"
3170 PRINT "MEDICAL/HOSPITAL EXPENSES	MEDICAL/HOSPITAL SUBS"
3180 PRINT "RENT				RATES"
3190 PRINT "MORTGAGE REPAYMENTS		HOUSE REPAIRS"
3200 PRINT "FOOD AND LIFING			HOUSEHOLD REPLACEMENTS"
3210 PRINT "ELECTRICITY/GAS/FUEL		TELEPHONE"
3220 PRINT "LAUNDRY AND CLEANING		CLOTHING"
3230 PRINT "CHILD CARE/EDUCATION		ENTERTAINMENT"
3240 PRINT "FARES				AUTOMOBILE RUNNING COSTS"
3250 PRINT "HIRE PURCHASE PAYMENTS		LOAN PAYMENTS"
3260 PRINT "BUSINESS EXPENSES		MISCELLANEOUS"
3270 PRINT :PRINT :INPUT "HIT <RETURN> TO CONTINUE....";ANS
3280 GOTO 3050
3290 REM
3300 GOSUB 12000:REM           INPUT EXPENDITURE DETAILS
3310 PUT 1,NREC;EXAC$[12],BUDCAT$[1],TAX$[1],FRQ$[2],FCAST,LIABAC$[2],INCAC$[2],BAL,"         "[9],"N"[1]
3320 NREC= NREC+ 1:PUT 1,1,5;NREC
3330 PLOT 12:GOTO 3350
3340 PLOT 7,12,3,5,15:PRINT "YOU HAVE USED YOUR QUOTA OF 63 EXPENDITURE ACCOUNTS"
3350 PRINT :PLOT 3,5,17:PRINT "DO YOU WISH TO ADD ANY MORE EXPENDITURE ACCOUNTS (Y/N)? ";:GOSUB 150:IF NOT (Q$= "Y"OR Q$= "N")THEN PLOT 7:GOTO 3350
3360 IF Q$= "Y"THEN 3030
3370 FILE "C",1:RETURN
4000 REM  ************* ADD ASSET ACCOUNT ********************
4010 REM
4020 FILE "R",1,DSK$+ "ASSETS",3
4030 GET 1,1;NREC:NACCT= NREC- 1
4040 IF NACCT> 23THEN 4190
4050 PLOT 12,3,1,1:PRINT "CURRENT ACCOUNTS ARE :"
4060 IF NREC< = 13THEN PLOT 3,30,1:PRINT "SUGGESTED 'ASSET' CATEGORIES ARE:"
4070 IF NACCT= 1GOTO 4110
4080 FOR REC= 2TO NREC- 1
4090 GET 1,REC;NAME$[20]
4091 IF REC< = 13THEN PLOT 3,5,REC+ 1:PRINT REC- 1,""NAME$"":GOTO 4100
4092 PLOT 3,32,REC- 11:PRINT REC- 1;" "NAME$""
4100 NEXT REC
4108 IF NREC> 13GOTO 4150
4110 PLOT 3,30,5:PRINT " 1. REAL ESTATE"
4120 PLOT 3,30,6:PRINT " 2. SHARES AND DEBENTURES"
4130 PLOT 3,30,7:PRINT " 3. INSURANCE POLS (SURRENDER VAL)"
4140 PLOT 3,30,8:PRINT " 4. MOTOR VEHICLES"
4142 PLOT 3,30,9:PRINT " 5. FURNITURE & PERSONAL EFFECTS"
4150 GOSUB 13000:REM           INPUT ASSET DETAILS
4160 PUT 1,NREC;ASSAC$[20],VA,VADATE$[9],APPRATE,INFRATE
4170 NREC= NREC+ 1:PUT 1,1;NREC
4180 PLOT 12:GOTO 4200
4190 PLOT 7,12,3,5,15:PRINT "YOU HAVE USED YOUR QUOTA OF 23 ASSET ACCOUNTS"
4200 PRINT :PLOT 3,5,17:PRINT "DO YOU WISH TO ADD ANY MORE ASSET ACCOUNTS (Y/N)? ";:GOSUB 150:IF NOT (Q$= "Y"OR Q$= "N")THEN PLOT 7:GOTO 4200
4210 IF Q$= "Y"THEN 4030
4220 FILE "C",1:RETURN
5000 REM  ************* ADD LIABILITY ACCOUNT ********************
5010 REM
5020 FILE "R",1,DSK$+ "LIABS",3
5030 GET 1,1;NREC:NACCT= NREC- 1
5040 IF NACCT> 23THEN 5200
5050 PLOT 12,3,1,1:PRINT "CURRENT ACCOUNTS ARE :"
5060 IF NREC< = 13THEN PLOT 3,30,1:PRINT "SUGGESTED CATEGORIES ARE:"
5070 IF NACCT= 1GOTO 5110
5080 FOR REC= 2TO NREC- 1
5090 GET 1,REC;NAME$[20]
5091 IF REC< = 13THEN PLOT 3,5,REC+ 1:PRINT REC- 1," "NAME$"":GOTO 5100
5092 PLOT 3,32,REC- 11:PRINT REC- 1;" "NAME$""
5100 NEXT REC
5101 IF NREC> 13GOTO 5160
5110 PLOT 3,30,5:PRINT " 1. MORTGAGE"
5120 PLOT 3,30,6:PRINT " 2. OVERDRAFTS"
5130 PLOT 3,30,7:PRINT " 3. LOANS"
5140 PLOT 3,30,8:PRINT " 4. HIRE PURCHASE"
5150 PLOT 3,30,9:PRINT " 5. CREDIT CARDS"
5160 GOSUB 14000:REM           INPUT LIABILITY DETAILS
5170 PUT 1,NREC;LIABAC$[20],BAL,BALDATE$[9],INRATE,PERIOD
5180 NREC= NREC+ 1:PUT 1,1;NREC
5190 PLOT 12:GOTO 5210
5200 PLOT 7,12,3,1,15:PRINT "YOU HAVE USED YOUR QUOTA OF 23 LIABILITY ACCOUNTS"
5210 PRINT :PLOT 3,1,17:PRINT "DO YOU WISH TO ADD ANY MORE LIABILITY ACCOUNTS (Y/N)? ";:GOSUB 150:IF NOT (Q$= "Y"OR Q$= "N")THEN PLOT 7:GOTO 5210
5220 IF Q$= "Y"THEN 5030
5230 FILE "C",1:RETURN
9000 PLOT 12,6,2,3,5,12:INPUT "LOAD APPROPRIATE PROGRAM DISK AND HIT <RETURN> ";ANS:LOAD "MENU":RUN
10000 REM  ****************** PROTECTED FIELDS *****************
10010 PLOT 3,23,16
10020 PRINT "ENTER INCOME DETAILS"
10030 PLOT 3,0,18,15
10040 PLOT 3,1,20:PRINT "ACCOUNT NUMBER"
10050 PLOT 3,1,21:PRINT "ACCOUNT NAME"
10060 PLOT 3,1,22:PRINT "BUDGET CATEGORY"
10070 PLOT 3,1,23:PRINT "TAXABLE (Y/N)?"
10080 PLOT 3,1,24:PRINT "TIMES PER YEAR"
10085 PLOT 3,1,25:PRINT "FORECAST AMOUNT        $"
10090 PLOT 3,25,20:PRINT ""NACCT""
10100 PLOT 3,25,21:PRINT "            "
10110 PLOT 3,25,22:PRINT " "
10120 PLOT 3,25,23:PRINT " "
10130 PLOT 3,25,24:PRINT "  "
10135 PLOT 3,25,25:PRINT "         "
10140 REM
10150 PLOT 6,2,3,0,27:GOSUB 20000
10210 X= 25:Y= 21:ML= 12:NA$= "A":PLOT 6,38
10230 GOSUB 280:IF KB= 9GOTO 10230
10250 INCAC$= FI$
10260 X= 25:Y= 22:ML= 1:NA$= "A":PLOT 6,38:GOSUB 280:IF KB= 9GOTO 10210
10300 BUDCAT$= FI$
10310 X= 25:Y= 23:ML= 10:NA$= "A":PLOT 6,38:GOSUB 280:IF KB= 9GOTO 10260
10350 TAX$= FI$
10360 X= 25:Y= 24:ML= 2:NA$= "A":PLOT 6,38:GOSUB 280:IF KB= 9GOTO 10310
10400 FRQ$= FI$
10420 X= 25:Y= 25:ML= 9:NA$= "N":PLOT 6,38:GOSUB 280:IF KB= 9GOTO 10360
10450 FAMT= VAL (FI$):PLOT 6,2:RETURN
11000 REM  **************   PROTECTED FIELDS.  *****************
11010 PLOT 3,23,16
11020 PRINT "ENTER BANK DETAILS"
11030 PLOT 3,0,18,15
11040 PLOT 3,1,20:PRINT "ACCOUNT NUMBER"
11050 PLOT 3,1,21:PRINT "ACCOUNT NAME"
11060 PLOT 3,1,22:PRINT "ACCOUNT IDENTIFICATION"
11070 PLOT 3,1,23:PRINT "BALANCE                $"
11080 PLOT 3,1,24:PRINT "LAST DATE (D.M.YY)"
11100 PLOT 3,25,20:PRINT ""NACCT""
11110 PLOT 3,25,21:PRINT "            "
11120 PLOT 3,25,22:PRINT "             "
11130 PLOT 3,25,23:PRINT "          "
11140 PLOT 3,25,24:PRINT "         "
11160 REM
11170 PLOT 6,2,3,0,27:GOSUB 20000
11230 X= 25:Y= 21:ML= 12:NA$= "A":PLOT 6,38
11250 GOSUB 280:IF KB= 9GOTO 11250
11270 BNKAC$= FI$
11280 X= 25:Y= 22:ML= 13:NA$= "A":PLOT 6,38:GOSUB 280:IF KB= 9GOTO 11230
11320 DETAIL$= FI$
11330 X= 25:Y= 23:ML= 10:NA$= "N":PLOT 6,38:GOSUB 280:IF KB= 9GOTO 11280
11370 BAL= VAL (FI$)
11380 X= 25:Y= 24:ML= 8:NA$= "A":PLOT 6,38:GOSUB 280:IF KB= 9GOTO 11330
11420 TD$= FI$:GOSUB 21000:IF ERR= 1THEN PLOT 7:GOTO 11380
11430 LDATE$= TD$:PLOT 6,2:RETURN
12000 REM  *****
************* PROTECTED FIELDS ****************
12010 PLOT 3,23,20
12020 PRINT "ENTER EXPENDITURE DETAILS"
12030 PLOT 3,0,18,15
12040 PLOT 3,1,22:PRINT "ACCOUNT NUMBER"
12050 PLOT 3,1,23:PRINT "ACCOUNT NAME"
12060 PLOT 3,1,24:PRINT "BUDGET CATEGORY"
12070 PLOT 3,1,25:PRINT "TAXABLE (Y/N)?"
12080 PLOT 3,1,26:PRINT "TIMES PER YEAR"
12090 PLOT 3,1,27:PRINT "FORECAST AMOUNT        $"
12100 PLOT 3,1,28:PRINT "LIABILITY A/C NUMBER"
12110 PLOT 3,1,29:PRINT "INCOME A/C NUMBER"
12120 PLOT 3,1,30:PRINT "BALANCE                $"
12130 PLOT 3,25,22:PRINT ""NACCT""
12140 PLOT 3,25,23:PRINT "            "
12150 PLOT 3,25,24:PRINT " "
12160 PLOT 3,25,25:PRINT " "
12170 PLOT 3,25,26:PRINT "  "
12180 PLOT 3,25,27:PRINT "         "
12190 PLOT 3,25,28:PRINT "  "
12200 PLOT 3,25,29:PRINT "  "
12210 PLOT 3,25,30:PRINT "         "
12220 REM
12230 PLOT 6,2
12240 X= 25:Y= 23:ML= 12:NA$= "A":PLOT 6,38
12260 GOSUB 280:IF KB= 9GOTO 12260
12280 EXAC$= FI$
12290 X= 25:Y= 24:ML= 1:NA$= "A":PLOT 6,38:GOSUB 280:IF KB= 9GOTO 12240
12330 BUDCAT$= FI$
12340 X= 25:Y= 25:ML= 1:NA$= "A":PLOT 6,38:GOSUB 280:IF KB= 9GOTO 12290
12380 TAX$= FI$
12390 X= 25:Y= 26:ML= 2:NA$= "A":PLOT 6,38:GOSUB 280:IF KB= 9GOTO 12340
12430 FRQ$= FI$
12440 X= 25:Y= 27:ML= 9:NA$= "N":PLOT 6,38:GOSUB 280:IF KB= 9GOTO 12390
12470 FCAST= VAL (FI$)
12480 X= 25:Y= 28:ML= 2:NA$= "A":PLOT 6,38:GOSUB 280:IF KB= 9GOTO 12440
12510 LIABAC$= FI$
12520 X= 25:Y= 29:ML= 2:NA$= "A":PLOT 6,38:GOSUB 280:IF KB= 9GOTO 12480
12550 INCAC$= FI$
12560 X= 25:Y= 30:ML= 9:NA$= "N":PLOT 6,38:GOSUB 280:IF KB= 9GOTO 12520
12590 BAL= VAL (FI$):PLOT 6,2:RETURN
13000 REM  **************   PROTECTED FIELDS.  *****************
13010 PLOT 3,23,16
13020 PRINT "ENTER ASSET DETAILS"
13030 PLOT 3,0,18,15
13040 PLOT 3,1,20:PRINT "ACCOUNT NUMBER"
13050 PLOT 3,1,21:PRINT "ACCOUNT NAME"
13060 PLOT 3,1,22:PRINT "VALUE                  $"
13070 PLOT 3,1,23:PRINT "DATE OF VALUE"
13080 PLOT 3,1,24:PRINT "APPRECIATION RATE"
13082 PLOT 3,1,25:PRINT "INFLATION RATE"
13090 PLOT 3,25,20:PRINT ""NACCT""
13100 PLOT 3,25,21:PRINT "                    "
13110 PLOT 3,25,22:PRINT "         "
13120 PLOT 3,25,23:PRINT "        "
13130 PLOT 3,25,24:PRINT "     %"
13132 PLOT 3,25,25:PRINT "     %"
13140 REM
13150 PLOT 6,2,3,0,27:GOSUB 20000
13160 X= 25:Y= 21:ML= 20:NA$= "A":PLOT 6,38
13180 GOSUB 280:IF KB= 9GOTO 13180
13200 ASSAC$= FI$
13210 X= 25:Y= 22:ML= 9:NA$= "N":PLOT 6,38:GOSUB 280:IF KB= 9GOTO 13160
13250 VA= VAL (FI$)
13260 X= 25:Y= 23:ML= 8:NA$= "A":PLOT 6,38:GOSUB 280:IF KB= 9GOTO 13210
13300 TD$= FI$:GOSUB 21000:IF ERR= 1THEN PLOT 7:GOTO 13260
13305 VADATE$= TD$
13310 X= 25:Y= 24:ML= 5:NA$= "N":PLOT 6,38:GOSUB 280:IF KB= 9GOTO 13260
13350 APPRATE= VAL (FI$)
13351 X= 25:Y= 25:ML= 5:NA$= "N":PLOT 6,38:GOSUB 280:IF KB= 9GOTO 13310
13355 INFRATE= VAL (FI$):PLOT 6,2:RETURN
14000 REM  **************   PROTECTED FIELDS.  *****************
14010 PLOT 3,23,16
14020 PRINT "ENTER ASSET DETAILS"
14030 PLOT 3,0,18,15
14040 PLOT 3,1,20:PRINT "ACCOUNT NUMBER"
14050 PLOT 3,1,21:PRINT "ACCOUNT NAME"
14060 PLOT 3,1,22:PRINT "BALANCE                $"
14070 PLOT 3,1,23:PRINT "BALANCE DATE"
14080 PLOT 3,1,24:PRINT "INTEREST RATE"
14090 PLOT 3,1,25:PRINT "INTEREST PERIOD (365,12)"
14100 PLOT 3,25,20:PRINT ""NACCT""
14110 PLOT 3,25,21:PRINT "                    "
14120 PLOT 3,25,22:PRINT "         "
14130 PLOT 3,25,23:PRINT "        "
14140 PLOT 3,25,24:PRINT "     %"
14150 PLOT 3,25,25:PRINT "     "
14160 REM
14170 PLOT 6,2,3,0,27:GOSUB 20000
14180 X= 25:Y= 21:ML= 20:NA$= "A":PLOT 6,38
14200 GOSUB 280:IF KB= 9GOTO 14200
14220 LIABAC$= FI$
14230 X= 25:Y= 22:ML= 9:NA$= "N":PLOT 6,38:GOSUB 280:IF KB= 9GOTO 14180
14270 BAL= VAL (FI$)
14280 X= 25:Y= 23:ML= 8:NA$= "A":PLOT 6,38:GOSUB 280:IF KB= 9GOTO 14230
14320 TD$= FI$:GOSUB 21000:IF ERR= 1THEN PLOT 7:GOTO 14280
14325 BALDATE$= TD$
14330 X= 25:Y= 24:ML= 5:NA$= "N":PLOT 6,38:GOSUB 280:IF KB= 9GOTO 14280
14370 INRATE= VAL (FI$)
14380 X= 25:Y= 25:ML= 5:NA$= "N":PLOT 6,38:GOSUB 280:IF KB= 9GOTO 14330
14420 PERIOD= VAL (FI$):PLOT 6,2:RETURN
19997 REM
19998 REM  ************** INPUT INSTRUCTIONS (******************
19999 REM
20000 PRINT "           1. ONLY LEFT & RIGHT CURSOR ALLOWED."
20010 PRINT "           2. CURSOR WON'T GO OUT OF A FIELD."
20020 PRINT "           3. DEL/INS CHAR AND DEL LINE ALL WORK."
20030 PRINT "           4. ALPHA CHARS DISABLED IN NUMERIC FLD."
20040 PRINT "           5. TAB KEY BACKS UP A FIELD.";
20050 RETURN
21000 REM  ******************** DATE ROUTINE *******************
21010 REM
21020 REM  INPUT DATE AS D.M.YY ,ASSIGN TO TD$, AND CALL THIS
21030 REM  OUTPUT IS TD$ IN THE FORM OF '12 JAN 81'
21040 REM
21045 ERR= 0:IF LEN (TD$)= 0THEN ERR= 1:GOTO 21120
21047 FOR JI= 1TO LEN (TD$):T6= ASC (MID$ (TD$,JI,1)):IF NOT (T6= 46OR (T6> 47AND T6< 58))THEN ERR= 1:GOTO 21120
21049 NEXT JI
21050 STRMTH$= "  JANFEBMARAPRMAYJUNJULAUGSEPOCTNOVDEC"
21060 IF  MID$ (TD$,2,1)= "."THEN TD$= "0"+ TD$
21070 IF  MID$ (TD$,5,1)= "."THEN TD$= LEFT$ (TD$,3)+ "0"+ RIGHT$ (TD$,4)
21080 MM= VAL (MID$ (TD$,4,2))
21090 MM$= " "+ MID$ (STRMTH$,MM* 3,3)+ " "
21100 TD$= LEFT$ (TD$,2)+ MM$+ RIGHT$ (TD$,2)
21110 IF  LEFT$ (TD$,1)= "0"THEN TD$= " "+ RIGHT$ (TD$,8)
21120 IF ERR= 1THEN PLOT 7
21130 RETURN