Listing of file='VID6.BAS;01' on disk='vmedia/home_video_library-sector.ccvf'
100 CLEAR 1000
110 DIM TD$(16)
120 DIM RE(500)
130 PLOT 12,14,29,18
140 PLOT 3,26,5
150 PRINT "VIDEO 6"
160 PLOT 22
170 PLOT 3,16,9
180 PRINT "PRINT BRIEF PROGRAM LIST"
190 PLOT 15
200 PLOT 3,12,15
210 INPUT "TURN PRINTER ON AND HIT 'ENTER' ";JU$
220 FILE "R",3,"DATE",1
230 GET 3,1,1;DD,MM,YY,DA$[38]
240 FILE "C",3
250 HA$= "Brief Program List as at: "
260 HA$= HA$+ DA$
270 LA= LEN (HA$)
280 HB$= LEFT$ ("____________________________________________________________",LA)
290 HC$= "NUM Cass Title Comment"
300 FILE "R",4,"VCAT",1
310 PLOT 19
320 FOR A= 1TO 16
330 GET 4,A,1;CN$[2],CD$[24]
340 TD$(A)= CD$
350 NEXT A
360 FILE "C",4
370 FILE "R",1,"VPROG",2
380 FILE "R",2,"VPROG.IDX",2
390 GET 1,1,1;TR
400 FOR NR= 1TO TR- 2
410 GET 2,NR,1;RE(NR)
420 NEXT NR
430 GOSUB 1000
440 FOR NR= 1TO TR- 2
450 GET 1,RE(NR),1;PP$[3],PC$[2],PT$[30],PB$[20]
460 IF LEFT$ (PB$,7)= "DELETED"GOTO 640
470 GET 1,RE(NR),56;P1$[20],P2$[20],P3$[20],PT,PN$[3]
480 IF LC> 56THEN GOSUB 1000
490 IF PC$= LC$GOTO 580
500 LC$= PC$
510 CC= VAL (PC$)
520 GOSUB 2000
530 PRINT
540 PRINT TD$(CC)
550 PRINT
560 GOSUB 2100
570 LC= LC+ 3
580 REM ******* PRINT EACH LINE ********
590 PL$= PN$+ " "+ PT$+ " "+ PB$
600 PL$= PP$+ " "+ PL$
610 GOSUB 2000
620 PRINT PL$
630 GOSUB 2100
640 NEXT NR
650 REM
660 REM *********** WIND UP PROGRAM ***********
670 REM
680 PUT 2,1,1;NR
690 FILE "C",2
700 PLOT 27,11
710 LOAD "0:VMENU",RUN
1000 REM
1010 REM ******** PRINT HEADINGS ***********
1020 REM
1030 GOSUB 2000
1040 PLOT 12
1050 FOR A= 1TO 4
1060 PRINT
1070 NEXT A
1080 PRINT HA$
1090 PRINT HB$
1100 PRINT
1110 PRINT HC$
1120 PRINT
1130 GOSUB 2100
1140 RETURN
2000 REM
2010 REM ******** TURN PRINTER ON **********
2020 REM
2030 POKE 33289,80
2040 POKE 33265,14
2050 RETURN
2100 REM
2110 REM ******* TURN PRINTER OFF **********
2120 REM
2130 POKE 33289,64
2140 POKE 33265,0
2150 RETURN