Listing of file='ORDER.BAS;01' on disk='vmedia/invoice_order-sector.ccvf'
0 GOTO 10
5 GOTO 400
10 PLOT 12,14,3,15,2:PRINT "*** GENERAL ORDER PROGRAM ***":PRINT
20 PRINT "WHEN YOU RUN THIS PROGRAM THE FIRST TIME ENTER YOUR PERSONAL"
30 PRINT "DATA IN THE LINE 140 FOLLOWING THE DATA STATEMENT IN THE"
40 PRINT "FORM:"
50 PRINT "140 DATA 'YOUR NAME','ABBREVIATION','ADDRESS','CITY, STATE ZIP','PHONE NUMBER'"
60 PRINT "USE AS QUOTES (') ALWAYS DOUBLE QUOTES."
70 PRINT "AS SECOND STEP DELETE LINE #2 BY TYPING: 0 <RETURN>"
80 PRINT "THEN SAVE THIS VERSION ON AN EMPTY DISK UNDER THE NAME MENU"
90 PLOT 15:END
95 REM
100 REM
110 REM PROGRAM COPYRIGHT BY *EIKE MUELLER*"
120 REM
130 REM VERS.820113"
132 REM
133 REM
140 REM DATA
141 REM DATA
150 NN= LEN (NN$):NN= INT (30- NN/ 2):RETURN
200 MT= INT (MT* 100+ .5)
210 SG$= " ":IF MT< 0THEN SG$= "-":MT= ABS (MT)
220 A1$= STR$ (INT (MT/ 100))
230 A2$= "."+ RIGHT$ (STR$ (MT+ 100- INT (MT/ 100)* 100),2)
240 MT$= RIGHT$ (" "+ SG$+ A1$+ A2$,8)
250 RETURN
400 REM
410 POKE 33289,120
500 CLEAR 2500
501 PLOT 27,24:REM PAGE MODE
505 DIM IN$(25),DE$(25),QT(25),SP(25)
508 RESTORE 140:READ NN$:GOSUB 150
510 PLOT 12,3,NN,1,14,6,38
520 PRINT " "+ NN$+ " "
525 READ NN$:GOSUB 150
530 PLOT 15,3,NN,2,30,17,29,23
540 PRINT " "+ NN$+ " "
550 PLOT 6,2
560 A= 4:REM A= FIRST LINE FOR CLEAR DISPLAY
570 REM
580 PRINT :PRINT TAB( 8):INPUT "DO YOU WANT TO REVIEW ORDERS FROM DATA BASE? ";RP$
590 IF LEFT$ (RP$,1)= "Y"THEN 4000
600 GOSUB 6000
610 PRINT TAB( 15):INPUT "RETRIEVE SUPPLIER FROM DATA BASE? ";RS$
612 IF LEFT$ (RS$,1)= "Y"THEN 4500
615 PRINT TAB( 15):INPUT "ENTER SUPPLIER DATA IN SUPP FILE? ";EF$
620 GOTO 6700
630 GOSUB 6000
650 PRINT :PRINT TAB( 15):INPUT "ENTER SALES TAX IN % ";TX
660 PRINT :PRINT TAB( 15):INPUT "ENTER DATE (MM/DD/YY) ";DA$
700 PRINT :PRINT TAB( 15)"ENTER ORDER NUMBER: ";
701 PRINT " ";
702 FOR X= 1TO 10:PLOT 26:NEXT X
703 PLOT 6,38:INPUT "";NO$
704 PLOT 6,2
705 PRINT :PRINT TAB( 15):INPUT "ENTER CASH WITH ORDER DISCT. % ";CA
708 PRINT :PRINT TAB( 15):INPUT "ENTER LAST BALANCE $ ";VD
710 PRINT :PRINT TAB( 15):INPUT "ENTER NUMBER OF COPIES ";CO
717 CO= CO+ 1
720 GOSUB 6000
730 L= 1:REM
740 REM DATA ENTRY
750 GOSUB 6000
770 PRINT TAB( 5):INPUT "ENTER ITEM NUMBER-OR END ";IN$(L)
775 IF IN$(L)= "END"THEN 932
780 PRINT TAB( 5):PRINT "ENTER ITEM DESCRIPTION ";" ";
781 FOR X= 1TO 29:PLOT 26:NEXT X
782 PLOT 6,38:INPUT "";DE$(L)
783 PLOT 6,2
785 PRINT TAB( 5):INPUT "ENTER QUANTITY ";QT(L)
790 PRINT TAB( 5):INPUT "ENTER DEALER COST $ ";SP(L)
795 PO$= "O"
800 GOSUB 6000
805 IF LEFT$ (AC$,1)= "Y"THEN 3000
810 PLOT 3,50,0:PRINT "COST SO FAR:"
820 PLOT 3,50,1:PRINT "$ "
830 S1= SP(L)* QT(L)
840 S2= S1- S1* CA/ 100
850 S2= INT (S2* 100)/ 100
852 S3= S2* TX/ 100:S3= INT (S3* 100)/ 100
860 SF= SF+ S2+ S3
870 PLOT 3,53,1:PRINT SF
880 REM
900 REM
910 L= L+ 1
920 PLOT 3,0,4
930 GOTO 770
932 PRINT TAB( 5):INPUT "ENTER SHIPPING CHARGE $ ";SC
940 GOSUB 6000
941 J= 0
942 J= J+ 1
945 INPUT "ENTER COMMENT ";CO$(J)
946 IF CO$(J)= ""THEN 970
950 GOTO 942
970 A= 4:GOSUB 6000
980 GOSUB 3000
985 GOSUB 7000:REM BAUD RATE SELECTION
990 REM
1000 REM PRINTOUT
1001 PRINT TAB( 10):INPUT "EPSON, PAPERTIGER, OR OTHER PRINTER? ";PE$
1002 IF LEFT$ (PE$,1)= "P"OR LEFT$ (PE$,1)= "O"THEN GOSUB 6000:GOTO 1008
1003 IF LEFT$ (PE$,1)= "E"THEN 5000
1004 PLOT 7,28,11
1005 GOTO 1001
1008 IF LEFT$ (PE$,1)= "O"THEN PE= 1:GOTO 1020
1010 INPUT "HIT ENTER WHEN PRINTER DIP S4: 1,4,6 S3: 1,3,4,5,6,7 ON ";EN
1012 PRINT :PRINT "NOTE: PAPERTIGER BUAD RATE SET TO 1200 BAUD":FOR X= 1TO 1000:NEXT X
1014 PLOT 27,18,4
1020 GOSUB 6000
1030 PRINT TAB( 6):INPUT "HIT ENTER WHEN READY FOR PRINTOUT ";EN
1040 GOSUB 6000
1045 L= 0:C= 1:TC= 0
1050 PRINT :PRINT :PRINT :PRINT :PRINT :PRINT TAB( 22)" P R I N T I N G"
1060 POKE 33265,14:OUT 8,199:IF PE= 1THEN 1070
1062 PLOT 17
1064 PLOT 29,2
1070 PRINT "ORDER #";NO$;
1071 IF PE= 1THEN 1090
1080 PLOT 31,1
1090 RESTORE 140:READ NN$:NN= LEN (NN$):NN= INT (32- NN/ 2)
1095 IF PE= 1THEN NN= LEN (NN$):NN= INT (40- NN/ 2)
1100 PRINT TAB( NN)NN$;
1101 IF PE= 1THEN PRINT TAB( 64)"DATE: ";DA$:GOTO 1135
1110 PLOT 29,2
1120 PRINT TAB( 60)"DATE: ";DA$
1130 PLOT 29,1
1135 READ NN$:NN= LEN (NN$):NN= INT (20- NN/ 2)
1136 IF PE= 1THEN NN= LEN (NN$):NN= INT (40- NN/ 2)
1140 PRINT TAB( NN)NN$
1141 IF PE= 1THEN 1155
1150 PLOT 30,1
1155 READ NN$:NN= LEN (NN$):NN= INT (25- NN/ 2)
1156 IF PE= 1THEN NN= LEN (NN$):NN= INT (40- NN/ 2)
1160 PRINT TAB( NN)NN$
1165 READ NN$:NN= LEN (NN$):NN= INT (25- NN/ 2)
1166 IF PE= 1THEN NN= LEN (NN$):NN= INT (40- NN/ 2)
1170 PRINT TAB( NN)NN$
1171 IF PE= 1THEN 1185
1180 PLOT 29,2
1185 READ NN$:NN= LEN (NN$):NN= INT (36- NN/ 2)
1186 IF PE= 1THEN NN= LEN (NN$):NN= INT (40- NN/ 2)
1190 PRINT TAB( NN)NN$
1200 PRINT :PRINT :PRINT
1201 IF PE= 1THEN 1220
1210 PLOT 31,1
1220 PRINT "TO: ";VN$
1230 PRINT " ";VA$
1240 PRINT " ";VS$
1250 PRINT " ";VC$
1270 PRINT :PRINT :PRINT
1275 IF PE= 1THEN PRINT :FOR X= 1TO J:PRINT CO$(X):NEXT X:PRINT :GOTO 1288
1280 PRINT
1285 PLOT 30,2:FOR X= 1TO J:PRINT CO$(X):NEXT X
1287 PRINT :PLOT 30,2:GOTO 1290
1288 PRINT "LINE# ITEM# ITEM DESCRIPTION QUANTITY UNIT PRICE AMOUNT"
1289 PRINT "________________________________________________________________________________":GOTO 1310
1290 PRINT "LINE# ITEM# ITEM DESCRIPTION QUANTITY UNIT PRICE AMOUNT"
1300 PRINT "_________________________________________________________________________________________"
1310 PRINT
1320 L= L+ 1:C= C+ 1:IF C= 6THEN C= 1:PRINT
1330 IF QT(L)< 1THEN 1390
1340 MT= SP(L):GOSUB 200
1350 IF PE= 1THEN 7200
1360 PRINT LTAB( 6)IN$(L)TAB( 17)DE$(L)TAB( 52)QT(L)TAB( 60)MT$;
1362 MT= SP(L)* QT(L):GOSUB 200
1365 PRINT TAB( 75)MT$
1370 TC= TC+ SP(L)* QT(L):TC= INT (TC* 100)/ 100
1380 GOTO 1320
1390 IF PE= 1THEN PRINT "________________________________________________________________________________":GOTO 1410
1400 PRINT "_________________________________________________________________________________________"
1410 PRINT
1415 REM
1416 IF PE= 1THEN 1425
1420 PLOT 30,1
1425 MT= TC:GOSUB 200
1430 PRINT "TOTAL VALUE OF THESE ITEMS:";TAB( 35)"$ ";TAB( 37)MT$
1435 IF CA> 0THEN D1= TC* CA/ 100:D1= INT (D1* 100)/ 100
1437 IF CA= 0THEN 1455
1440 DI= TC* DC/ 100:DI= INT (DI* 100)/ 100
1445 MT= - D1:GOSUB 200
1450 PRINT "CASH WITH ORDER DISCOUNT :";CA;" %";TAB( 37)MT$
1455 REM
1465 IF TX= 0THEN TT= 0:GOTO 1476
1467 TT= (TC- D1)* TX/ 100:TT= INT (TT* 100)/ 100
1468 MT= TT:GOSUB 200
1470 PRINT "SALES TAX: ";TX;" %";TAB( 37)MT$
1476 IF SC= 0THEN 1482
1480 MT= SC:GOSUB 200
1481 PRINT "SHIPPING CHARGE:";TAB( 37)MT$
1482 IF VD= 0THEN 1485
1483 MT= - VD:GOSUB 200
1484 PRINT "LAST BALANCE :";TAB( 37)MT$
1485 PRINT TAB( 35)"---------------"
1486 YP= TC- D1+ TT+ SC- VD:MT= YP:GOSUB 200
1487 PRINT "T O T A L :";TAB( 35)"$ ";TAB( 37)MT$
1490 MT= - PT:GOSUB 200
1492 PRINT :PRINT "PAYMENT ENCLOSED: ";TAB( 37)MT$
1493 PRINT TAB( 35)"---------------"
1494 YY= TC- D1+ TT+ SC- VD- PT
1495 MT= YY:GOSUB 200
1500 PRINT "B A L A N C E F O R W A R D : ";TAB( 35)"$ ";TAB( 37)MT$
1505 IF PE= 1THEN PRINT "================================================================================":GOTO 1515
1510 PRINT "==================================================":GOTO 1520
1515 IF PO$= "O"THEN PRINT :PRINT TAB( 28)"T H A N K Y O U":GOTO 1530
1520 IF PO$= "O"THEN PRINT :PRINT TAB( 15)"T H A N K Y O U"
1530 PLOT 12
1540 PLOT 19:WAIT 1,128,128:OUT 8,207:POKE 33265,0
1550 CO= CO- 1:IF CO< 1THEN 1600
1570 GOSUB 6000
1585 PE= 0:PLOT 27,18,7:GOTO 1000
1590 REM
1600 GOSUB 7300:REM PRINT LABEL
1610 A= 4:GOSUB 6000:REM STORE DATA IN DATA FILE"
1620 PRINT TAB( 10):INPUT "HIT ENTER WHEN ORD DATA BASE IS INSERTED ";EN
1630 FILE "T",6200
1640 FILE "R",1,"ORD",8
1650 LI= 0
1700 LI= LI+ 1:IF LI> 200THEN 2000
1710 GET 1,LI;NB$[10]
1711 REM PRINT LI,NO$
1720 IF VAL (NB$)< 1THEN 1800
1730 GOTO 1700
1790 REM
1800 REM UPDATE DATA BASE
1805 TD= TC- DI
1806 DD= D1+ VD
1807 REM PRINT NO$
1810 PUT 1,LI;NO$[10],DA$[8],VN$[29],TC,DD,TT,YP
1820 FILE "C",1
1830 PRINT TAB( 10):PRINT "ORD DATA FILE IS UPDATED"
1840 PRINT :PRINT TAB( 10):INPUT "FINISHED WITH THESE ACTIVITIES? ";EN$
1850 IF LEFT$ (EN$,1)= "N"THEN RUN
1860 PLOT 12,3,15,15:PRINT "A U F W I E D E R S E H E N"
1870 PLOT 3,0,0:INPUT "";EN
1880 RUN
1990 REM
2000 A= 4:GOSUB 6000
2010 PRINT "THERE IS NO MORE ROOM IN THIS DATA BASE"
2020 PRINT :INPUT "PLEASE INSERT ANOTHER DISK FOR THE DATA & HIT ENTER ";EN
2040 GOTO 6240
2990 REM
3000 REM REVIEW ITEMS
3005 PLOT 3,50,0:PRINT " ":PLOT 3,50,1:PRINT " "
3010 L= 0:C= 0:TC= 0:GOSUB 6000
3015 PLOT 3,0,4
3020 PRINT "LINE # QTY. ITEM DESCRIPTION COST TOTAL "
3030 PRINT "______________________________________________________________"
3040 PRINT
3050 L= L+ 1:C= C+ 1:IF C= 12THEN C= 0:A= 7:PRINT "______________________________________________________________":GOSUB 6100:GOSUB 6000
3060 IF QT(L)< 1THEN 3100:REM NO MORE DATA
3065 TC= TC+ SP(L)* QT(L):TC= INT (TC* 100)/ 100
3068 MT= SP(L)* QT(L):GOSUB 200
3070 PRINT "";LTAB( 7)"";QT(L)TAB( 12)"";DE$(L)TAB( 42)"";MT$;
3074 MT= TC:GOSUB 200
3076 PRINT TAB( 54)"";MT$
3080 GOTO 3050
3100 REM PRINT TOTALS
3110 PRINT "______________________________________________________________"
3111 PRINT
3112 CD= TC* CA/ 100:CD= INT (CD* 100)/ 100:MT= - CD:GOSUB 200
3115 IF CA> 0THEN PRINT "CASH DISCOUNT: ";CA;"%= $";TAB( 26)MT$;
3116 IF VD< > 0THEN MT= VD:GOSUB 200:PRINT TAB( 38)"LAST BALANCE: $";TAB( 54)MT$:GOTO 3120
3117 PRINT
3120 T2= TC- CD
3122 T1= T2* TX/ 100:T1= INT (T1* 100)/ 100:MT= T1:GOSUB 200
3124 IF TX> 0THEN PRINT "SALES TAX: ";TX;"%= $";TAB( 26)MT$
3125 MT= SC:GOSUB 200
3126 IF TX> 0THEN T2= T2+ T1
3127 IF SC> 0THEN PRINT "SHIPPING CHARGE: $";TAB( 26)MT$
3128 T2= T2+ SC- VD:MT= T2:GOSUB 200
3130 PRINT "BALANCE FORWARD: $";TAB( 26)MT$
3135 PRINT
3140 PRINT TAB( 5):INPUT "ANY CHANGES? ";AC$
3150 IF LEFT$ (AC$,1)< > "Y"THEN 3195
3160 PLOT 28,11,7
3170 PRINT TAB( 5):INPUT "ENTER LINE # - OR 0 TO CHANGE SHIPPING CHARGE ";L
3171 PLOT 28,11
3175 IF L= 0THEN PRINT TAB( 5):INPUT "ENTER SHIPPING CHARGE $ ";SC
3177 IF L= 0THEN PLOT 28,11:GOTO 3000
3180 PRINT TAB( 5)"PREVIOUS ITEM NUMBER: ";IN$(L);" "
3190 GOTO 770
3195 PLOT 28,11,7
3200 INPUT "PAYMENT ENCLOSED $ ";PT
3210 RETURN
3990 REM
4000 REM RETRIEVE PROPOSAL
4002 A= 4:GOSUB 6000
4004 PRINT "NUMBER SUPPLIER DATE"
4006 PRINT "COST DISC.[$] TAX [$] PAID [$]"
4008 PRINT "______________________________________________________________"
4010 FILE "T",6400
4020 FILE "R",1,"ORD",16
4030 LI= 0
4040 LI= LI+ 1:IF LI> 200THEN 4150
4050 GET 1,LI;NO$[10]
4060 IF VAL (NO$)< 1THEN 4130
4070 GET 1,LI;NO$[10],DA$[8],VN$[29],TC,DD,TT,YP
4074 YP= TC- DD+ TT
4075 REM PRINT LI,NO$
4080 PRINT "";NO$;TAB( 11)"";VN$TAB( 49)"";DA$
4090 PRINT "";TCTAB( 10)"";DDTAB( 28)"";TTTAB( 48)"";YP
4095 KO= KO+ TC:DT= DT+ DD:TA= TA+ TT:BZ= BZ+ YP:PLOT 15
4100 B= B+ 1:IF B> 10THEN B= 0:A= 7:PRINT "______________________________________________________________":GOSUB 6100:GOSUB 6000
4120 GOTO 4040
4130 PRINT "______________________________________________________________"
4150 PRINT " ";KOTAB( 10)" "DTTAB( 28)" ";TATAB( 48)" ";BZ:REM
4160 PRINT " ______________________________________________________________"
4170 GOSUB 6100
4180 A= 4:GOSUB 6000
4190 KO= 0:DT= 0:TA= 0:BZ= 0:FILE "C",1
4200 GOTO 610
4490 REM
4500 REM SUPPLIER DATA BASE
4510 A= 4:GOSUB 6000
4520 FILE "T",6600
4530 FILE "R",2,"SUPP",16
4535 IF C> 3THEN C= 0:GOTO 4600
4540 V= V+ 1:IF V> 50THEN 4600:REM >20 FOR COMPUCOLOR
4550 GET 2,V;VN
4560 IF VN< 1THEN C= C+ 1:GOTO 4535
4570 GET 2,V;VN,VA,VS,VC,VN$[VN],VA$[VA],VS$[VS],VC$[VC]
4580 PRINT "";VTAB( 5)"";VN$
4590 GOTO 4540
4600 PRINT
4610 PRINT TAB( 10):INPUT "ENTER # OF SUPPLIER AND HIT RETURN ";V
4620 GET 2,V;VN,VA,VS,VC,VN$[VN],VA$[VA],VS$[VS],VC$[VC]
4630 A= 4:GOSUB 6000
4640 FILE "C",2
4650 GOTO 650
4990 REM
5000 REM EPSON PRINTER
5005 GOSUB 6000
5010 PRINT TAB( 10):INPUT "HIT ENTER WHEN PRINTER POWER ON ";EN
5020 GOSUB 6000
5040 L= 0:C= 0:TC= 0
5050 PRINT :PRINT :PRINT :PRINT :PRINT :PRINT TAB( 22)" P R I N T I N G"
5060 POKE 33265,14:OUT 8,199
5062 PLOT 17
5063 PLOT 20,18,27,70,27,72
5064 PLOT 27,69,27,71,14
5065 PRINT "ORDER ORDER"
5066 PRINT :PRINT
5070 PRINT "ORDER #";NO$;
5080 RESTORE 140:READ NN$:NN= LEN (NN$):NN= INT (37- NN/ 2)
5100 PRINT TAB( NN)NN$;
5120 PLOT 20,18:PRINT TAB( 60)"DATE: ";DA$
5130 PLOT 15,14,27,71,27,69
5135 READ NN$:NN= LEN (NN$):NN= INT (19- NN/ 2)
5140 PRINT TAB( NN)NN$
5150 PLOT 15,14,27,70,27,71
5155 READ NN$:NN= LEN (NN$):NN= INT (32- NN/ 2)
5160 PRINT TAB( NN)NN$
5165 PLOT 15,14,27,71
5168 READ NN$:NN= LEN (NN$):NN= INT (32- NN/ 2)
5170 PRINT TAB( NN)NN$
5180 PLOT 20,27,70,27,71,15
5185 READ NN$:NN= LEN (NN$):NN= INT (63- NN/ 2)
5190 PRINT TAB( NN)NN$
5200 PRINT :PRINT
5210 PLOT 20,15,27,70,27,72
5215 PRINT "TO-"
5225 PLOT 15,14:PRINT TAB( 5)VN$
5235 PLOT 15,14:PRINT TAB( 5)VA$
5245 PLOT 15,14:PRINT TAB( 5)VS$
5255 PLOT 15,14:PRINT TAB( 5)VC$
5257 PRINT :PRINT
5260 PLOT 15,14,27,69,27,72
5270 PRINT "PLEASE SHIP THE FOLLOWING ITEMS:"
5280 PRINT
5282 PLOT 18,27,70
5285 FOR X= 1TO J:PRINT CO$(X):NEXT X
5287 PLOT 27,70:PRINT
5288 PLOT 18,20,27,71,15,14
5289 PRINT "=================================================================":PLOT 27,72
5290 PLOT 18,20,27,69:PRINT "LINE# ITEM# ITEM DESCRIPTION QUANTITY UNIT PRICE AMOUNT"
5295 PLOT 18,20,27,71
5300 PRINT "___________________________________________________________________________"
5305 C= 1
5306 PLOT 27,72
5310 PRINT
5320 L= L+ 1:C= C+ 1:IF C= 6THEN C= 1:PRINT
5330 IF QT(L)< 1THEN 5400
5340 PLOT 18,20,27,69
5350 MT= SP(L):GOSUB 200
5360 PRINT LTAB( 6)IN$(L)TAB( 15)DE$(L)TAB( 45)QT(L)TAB( 51)MT$;
5362 MT= SP(L)* QT(L):GOSUB 200
5363 REM
5364 PRINT TAB( 63)MT$
5370 TC= TC+ SP(L)* QT(L):TC= INT (TC* 100)/ 100
5380 GOTO 5320
5400 PLOT 18,20,27,70,27,71,15,14
5405 PRINT "=================================================================":PLOT 27,72
5410 PRINT
5420 PLOT 18,20,27,72,15,14
5425 MT= TC:GOSUB 200
5430 PRINT TAB( 1)"VALUE OF THESE ITEMS:";TAB( 50)"$ ";TAB( 52)MT$
5435 IF CA> 0THEN D1= TC* CA/ 100:D1= INT (D1* 100)/ 100
5437 IF CA= 0THEN 5455
5440 DI= TC* DC/ 100:DI= INT (DI* 100)/ 100
5445 PLOT 18,20,15,14
5447 MT= - D1:GOSUB 200
5450 PRINT TAB( 1)"CASH WITH ORDER DISCOUNT: ";CA;" %";TAB( 52)MT$
5455 REM
5465 IF TX= 0THEN TT= 0:GOTO 5475
5467 TT= (TC- D1)* TX/ 100:TT= INT (TT* 100)/ 100
5468 PLOT 18,20,15,14
5469 MT= TT:GOSUB 200
5470 PRINT TAB( 1)"SALES TAX: ";TX;" %";TAB( 52)MT$
5475 IF SC= 0THEN 5480
5477 PLOT 18,20,15,14:MT= SC:GOSUB 200
5478 PRINT TAB( 1)"SHIPPING CHARGE:";TAB( 52)MT$
5480 IF VD= 0THEN 5483
5481 PLOT 18,20,15,14:MT= - VD:GOSUB 200
5482 PRINT TAB( 1)"LAST BALANCE :";TAB( 52)MT$
5483 YP= TC- D1+ TT+ SC- VD:MT= YP:GOSUB 200
5486 PLOT 18,20,15,14:PRINT TAB( 50)"--------------"
5487 PLOT 18,20,15,14:PRINT TAB( 1)"T O T A L: ";TAB( 50)"$ ";TAB( 52)MT$
5491 PRINT :MT= - PT:GOSUB 200:PLOT 18,20,15,14
5492 PRINT TAB( 1)"PAYMENT ENCLOSED: ";TAB( 52)MT$
5493 YY= TC- D1+ TT+ SC- VD- PT
5494 PLOT 18,20,15,14:PRINT TAB( 50)"--------------"
5495 PLOT 18,20,15,14
5498 MT= YY:GOSUB 200
5500 PRINT TAB( 12)"B A L A N C E F O R W A R D : ";TAB( 50)"$ ";TAB( 52)MT$
5515 PRINT :PLOT 18,20,27,70,27,71,15,14
5518 PRINT "================================================================="
5520 PLOT 18,20,15,14:PRINT TAB( 22)"T H A N K Y O U"
5525 PLOT 20,18,27,70,27,72
5526 PLOT 27,71,27,69,15,14
5527 PRINT "ORDER ORDER"
5530 PLOT 12
5540 PLOT 27,70,19
5545 WAIT 1,128,128:OUT 8,207:POKE 33265,0
5550 CO= CO- 1:IF CO< 1THEN 1600
5570 GOSUB 6000
5580 GOTO 1000
5590 REM
6000 REM CLEAR DISPLAY
6010 FOR X= 30TO ASTEP - 1:PLOT 3,0,X,11:NEXT X:RETURN
6090 REM
6100 REM NEXT DISPLAY
6110 PLOT 3,10,30:INPUT "HIT ENTER TO CONTINUE ";EN
6120 RETURN
6190 REM
6200 REM CREATE ORD FILE
6210 A= 4:GOSUB 6000
6220 PRINT TAB( 16)"ORD DATA BASE NOT YET CREATED"
6230 PRINT TAB( 16):INPUT "HIT ENTER WHEN READY TO DO IT ";EN
6232 GOSUB 6000
6234 PRINT TAB( 16)"THIS WILL TAKE ABOUT 5 MINUTES"
6240 FILE "N","ORD",500,64,2
6250 FILE "R",1,"ORD",16
6260 AZ$= " "
6270 FOR X= 1TO 500
6280 PUT 1,X;AZ$[64]
6290 NEXT X
6300 A= 4:GOSUB 6000
6310 LI= 1
6320 GOTO 1800
6390 REM
6400 REM WRONG DISK
6410 INPUT "PLEASE INSERT DATA BASE DISK & HIT RETURN ";EN
6420 A= 4:GOSUB 6000
6430 GOTO 4000
6490 REM
6500 REM CREATE SUPP FILE
6510 A= 4:GOSUB 6000
6520 PRINT TAB( 16)"SUPP DATA BASE NOT YET CREATED"
6530 PRINT :PRINT TAB( 16):INPUT "HIT ENTER WHEN READY TO DO IT ";EN
6540 FILE "N","SUPP",50,128,1:REM 20 LINES FOR COMPUCOLOR
6550 FILE "R",2,"SUPP",8
6560 AZ$= " "
6570 FOR X= 1TO 50:REM TO 20 FOR COMPUCOLOR
6580 PUT 2,X;AZ$[128]
6590 NEXT X
6595 A= 4:GOSUB 6000
6598 GOTO 6780
6599 REM
6600 REM WRONG DISK
6610 A= 4:GOSUB 6000
6620 PRINT TAB( 15)"CAN NOT LOCATE SUPPLIER FILE"
6630 PRINT
6640 PRINT TAB( 12):INPUT "HIT ENTER WHEN RIGHT DISK IS INSERTED ";EN
6645 PRINT
6650 PRINT TAB( 16)"T H A N K Y O U"
6660 FOR X= 1TO 100:NEXT X
6670 GOTO 4500
6690 REM
6700 REM ENTER SUPPLIER INFO
6705 A= 4:GOSUB 6000
6710 PRINT TAB( 10):INPUT "ENTER SUPPLIER NAME ";VN$
6720 PRINT TAB( 10):INPUT "ATTN.: ";VA$
6730 PRINT TAB( 10):INPUT "ADDRESS: ";VS$
6740 PRINT TAB( 10):INPUT "CITY, STATE. ZIP ";VC$
6742 REM
6745 IF LEFT$ (EF$,1)< > "Y"THEN 630
6750 VN= LEN (VN$):VA= LEN (VA$):VS= LEN (VS$):VC= LEN (VC$)
6760 FILE "T",6500
6770 FILE "R",2,"SUPP",4
6780 V= 0
6790 V= V+ 1:IF V> 50THEN 6900: > 20 FOR COMPUCOLOR
6800 GET 2,V;VV
6810 IF VV> 1THEN 6790
6820 PUT 2,V;VN,VA,VS,VC,VN$[VN],VA$[VA],VS$[VS],VC$[VC]
6830 FILE "C",2
6840 PRINT TAB( 15)"SUPPLIER INFO STORED"
6850 FOR X= 1TO 2000:NEXT X
6860 GOSUB 6000
6870 GOTO 650
6890 REM
6900 REM SUPP FILE FULL
6910 GOSUB 6000
6920 PRINT TAB( 15)"NO MORE ROOM IN SUPP FILE"
6930 FOR X= 1TO 200:PLOT 7:NEXT X
6940 FOR X= 1TO 2000:NEXT X
6950 GOTO 650
7000 REM BAUD RATE SELECTION
7010 A= 4:GOSUB 6000
7020 PLOT 3,0,6
7030 PRINT TAB( 15)"ENTER BAUD RATE: "
7040 PRINT :PRINT TAB( 15)"1 - 110"
7050 PRINT TAB( 15)"2 - 150"
7060 PRINT TAB( 15)"3 - 300"
7070 PRINT TAB( 15)"4 - 1200"
7080 PRINT TAB( 15)"5 - 2400"
7090 PRINT TAB( 15)"6 - 4800"
7100 PRINT TAB( 15)"7 - 9600"
7110 PLOT 3,34,6:INPUT "";BA
7120 IF BA< 1OR BA> 7THEN PLOT 7,3,34,6:PRINT " ":GOTO 7110
7130 PLOT 27,18,BA
7140 GOSUB 6000:RETURN
7200 REM
7210 PRINT LTAB( 6)IN$(L)TAB( 14)DE$(L)TAB( 48)QT(L)TAB( 58)MT$;
7220 MT= SP(L)* QT(L):GOSUB 200:PRINT TAB( 71)MT$:GOTO 1370
7300 A= 4:GOSUB 6000:PRINT TAB( 10):INPUT "HIT ENTER WHEN READY TO PRINT ADDRESS LABEL ";EN
7310 POKE 33265,14:OUT 8,199
7350 PRINT VN$:IF VA$< "!"THEN 7365
7360 PRINT VA$
7365 IF VS$< "!"THEN 7380
7370 PRINT VS$
7380 PRINT VC$:PRINT :PRINT :PRINT :WAIT 1,128,128:OUT 8,207:POKE 33265,0:RETURN