# Compucolor.org – Virtual Media

Listing of file='ROSES.BAS;01' on disk='vmedia/taylor-sideA-sector.ccvf'

```1 PRINT CHR\$ (12)
5 PRINT "       PREPARED BY THE FACULTY AND STUDENTS "
6 PRINT "            AT SAN JOSE STATE UNIVERSITY"
7 PRINT "                  APRIL 2, 1980"
10 FOR K= 1TO 1500:NEXT K
20 PRINT CHR\$ (12)
100 PRINT "    THE FORMULA FOR THE GRAPH OF A ROSE IS "
105 PRINT
111 PRINT "              R = M * COS ( N * P )"
115 PRINT :PRINT
116 FOR K= 1TO 1000:NEXT K
121 PRINT " P IS THE INDEPENDENT VARIABLE; IT IS AN ANGLE IN RADIANS."
122 PRINT "THE COMPUTER WILL VARY P FROM 0 TO 25.2 RADIANS."
123 PRINT "        25.2 = =  8 * PI "
124 PRINT :FOR K= 1TO 3000:NEXT K
125 PRINT " R IS THE DEPENDENT VARIABLE; IT IS THE RADIUS,"
126 PRINT "    THE DISTANCE OF THE POINT FROM THE ORIGIN."
128 PRINT "M IS A CONSTANT (15) WHICH ENLARGES THE GRAPH TO FILL THE SCREEN"
129 FOR K= 1TO 4500:NEXT K
130 PRINT :PRINT :PRINT :PRINT
135 PRINT "    N HAS TO DO WITH THE NUMBER OF PETALS THE ROSE HAS."
136 PRINT :PRINT
140 PRINT "YOUR ASSIGNMENT IS TO VARY N TO DETERMINE WHAT EFFECT IT HAS ON THE GRAPH."
150 PRINT :PRINT :PRINT
160 PRINT TAB( 8);"WHAT VALUE OF N WOULD YOU LIKE TO TRY?"
170 PRINT :PRINT TAB( 20);:INPUT N
200 PRINT CHR\$ (12)
250 PRINT "    N = ";N
280 M= 15
285 PLOT 17
290 PLOT 2
300 FOR P= 0TO 25.2STEP .05
310 R= M* COS (N* P)
315 REM  ******* 3 AND 4 IN FORMULAS FOR X AND Y ARE TO CORRECT FOR NORMAL SCREEN DISTORTION
320 X= 63+ 3* R* COS (P)
330 Y= 63+ 4* R* SIN (P)
340 PLOT X,Y
350 NEXT P
360 PLOT 255
400 INPUT "PRESS <RETURN> WHEN READY TO CONTINUE.";Y\$
410 GOTO 160
```