Compucolor.org – Virtual Media

Listing of file='BLUFF.BAS;01' on disk='vmedia/taylor_2-sector.ccvf'

100 PLOT 6,33,12,27,11,14,3,18,6,6,25
110 PRINT "COMPUCOLOR PRESENTS BLUFF"
120 PLOT 3,64,0
130 FOR I= 1TO 2500:NEXT I
140 PLOT 6,1,12
150 PRINT :PRINT :PRINT
160 PLOT 6,4,14
170 DIM C(11),H(5),H5(5),E(11)
180 X= 5:X= - ABS (X):Z= RND (X):I0= 0
190 I1= 1:I2= 2:I3= 3:I4= 4:I5= 5:I8= 11:I9= - 1:F8= - 1:IF RND (I1)> .5THEN F8= I1
200 G= I0
210 G1= I0
220 G5= I0
230 FOR I= I1TO I8:C(I)= I:NEXT I
240 PLOT 12
250 PRINT "THE REFEREE DEALS THE CARDS -- HE TOSSES THE COIN AND---"
260 W= RND (- PEEK (33209)):GOSUB 750:FOR I= I1TO I5:Z= I+ I5:H(I)= C(I):H5(I)= C(Z):NEXT I
270 M= C(I8)
280 N1= I5:N5= I5
290 B1= I0:B5= I0
300 F= I0:N9= I0:X= I0
310 F8= F8* I9
320 PLOT 6,6
330 IF F8< I0THEN PRINT "YOU GO FIRST THIS GAME"
340 IF F8> I0THEN PRINT "I'LL GO FIRST THIS GAME"
350 GOSUB 650
360 IF F8< I0THEN 380
370 IF F8> I0THEN 560
380 PLOT 6,15
390 INPUT "YOUR PLAY (0 IS GUESS, 1-11 ARE ASKS)? ";X
400 PLOT 6,2,12
410 IF X< I0THEN 380
420 IF X> I8THEN 380
430 X= INT (X):IF X> I0THEN 450
440 PRINT :INPUT "WHAT DO YOU THINK THE SECRET CARD IS? ";X:GOTO 1370
450 GOSUB 1210:PRINT :F= I0
460 PLOT 6,2
470 IF B5< I0THEN PRINT "REFEREE SAYS THE";- B5;"IS ALREADY EXPOSED"
480 IF B5< I0THEN 510
490 GOSUB 1110:IF F< I0THEN PRINT "REFEREE SAYS I DON'T HAVE THE";X
500 IF F> I0THEN PRINT "REFEREE SAYS I DO HAVE THE";X:GOSUB 1050:GOSUB 770
510 IF B1< = I0THEN 550
520 PLOT 6,6
530 PRINT :PRINT "I WAS BLUFFING LAST TIME ABOUT THE";B1:X= B1:GOSUB 1050
540 GOSUB 770
550 PRINT
560 GOSUB 810:IF X< I0THEN 1370
570 GOSUB 1030:GOSUB 1140:IF F> I0THEN GOSUB 1280:GOSUB 770
580 IF F< > I0THEN 600
590 IF B1= I0THEN B1= - X
600 IF B5< = I0THEN 640
610 PLOT 6,2
620 PRINT :PRINT "REFEREE SAYS YOU BLUFFED LAST TIME ABOUT THE";B5:X= B5
630 GOSUB 1280:GOSUB 770
640 GOSUB 650:GOTO 380
650 PRINT :IF N5= I0THEN PRINT "YOUR HAND HAS NO CARDS LEFT":GOTO 690
660 PLOT 6,15:PRINT "YOUR HAND IS ";:FOR I= I1TO N5
670 PRINT H5(I);:NEXT I:
680 PLOT 6,2:PRINT
690 PRINT N1;" CARDS ARE IN MY HAND"
700 IF N9= I0THEN PRINT "NO CARDS ARE EXPOSED YET":RETURN
710 PRINT "CARDS EXPOSED ARE ";
720 PLOT 6,4
730 FOR I= I1TO N9:PRINT E(I);:NEXT
740 PRINT :RETURN
750 FOR I= I8TO I2STEP I9:Z= INT (RND (I1)* I)+ I1:J= C(Z):C(Z)= C(I)
760 C(I)= J:NEXT I:RETURN
770 IF N9= I0THEN 800
780 Z= I0:FOR I= I1TO N9:IF E(I)= XTHEN Z= I1
790 NEXT I:IF Z= I1THEN RETURN
800 N9= N9+ I1:E(N9)= X:RETURN
810 IF B1< I0THEN X= B1:RETURN
820 L= N1:L1= N1:IF N5> N1THEN L= N5
830 IF N5< N1THEN L1= N5
840 IF L1< = I0THEN 860
850 IF L> I1THEN 870
860 GOSUB 940:X= - X:RETURN
870 Y= I1/ L:IF F< I0THEN 900
880 GOSUB 940:IF RND (I1)< YTHEN X= H(I1)
890 RETURN
900 IF RND (I1)> YTHEN 920
910 X= F:RETURN
920 GOSUB 970:IF RND (I1)< YTHEN X= H(I1)
930 RETURN
940 Z= N5+ I1:J= INT (RND (I1)* Z)+ I1:IF J= ZTHEN X= M
950 IF J< ZTHEN X= H5(J)
960 RETURN
970 Z= N5+ I1:J= INT (RND (I1)* Z)+ I1:IF J= ZTHEN X= M
980 IF J< ZTHEN X= H5(J)
990 IF X< > - FTHEN RETURN
1000 IF J> I1THEN X= H5(J- I1)
1010 IF J= I1THEN X= M
1020 RETURN
1030 B1= I0:FOR I= I1TO N1:IF H(I)= XTHEN B1= X
1040 NEXT I:RETURN
1050 IF N1= I0THEN RETURN
1060 Z= I0
1070 FOR I= I1TO N1
1080 IF X= H(I)THEN Z= I
1090 NEXT I:IF Z= I0THEN RETURN
1100 H(Z)= H(N1):N1= N1- I1:RETURN
1110 F= - X:IF N1= I0THEN RETURN
1120 FOR I= I1TO N1:IF H(I)= XTHEN F= X
1130 NEXT I:RETURN
1140 PLOT 6,6
1150 PRINT "DO YOU HAVE THE";X;"?"
1160 GOSUB 1340:PRINT
1170 PLOT 6,2
1180 IF F= I0THEN PRINT "REFEREE SAYS YOU DO NOT HAVE THE";X
1190 IF F> I0THEN PRINT "REFEREE SAYS YOU DO HAVE THE";X
1200 RETURN
1210 B5= X
1220 IF N9= I0THEN 1250
1230 FOR I= I1TO N9:IF E(I)= XTHEN B5= - X
1240 NEXT I:IF B5< I0THEN RETURN
1250 IF N5= I0THEN RETURN
1260 B5= I0:FOR I= I1TO N5:IF H5(I)= XTHEN B5= X
1270 NEXT I:RETURN
1280 IF N5= I0THEN RETURN
1290 Z= I0:FOR I= I1TO N5:IF X= H5(I)THEN Z= I
1300 NEXT I:IF Z= I0THEN RETURN
1310 IF Z= N5THEN 1330
1320 FOR I= ZTO N5- I1:H5(I)= H5(I+ I1):NEXT I
1330 N5= N5- I1:RETURN
1340 F= I0:IF N5= I0THEN RETURN
1350 FOR I= I1TO N5:IF H5(I)= XTHEN F= I1
1360 NEXT I:RETURN
1370 PLOT 6:PLOT 2:PRINT :IF X> I0THEN PRINT "YOU GUESSED THE";X
1380 IF X< I0THEN PLOT 6,6
1390 IF X< I0THEN PRINT "I'M GOING TO GUESS AT THE SECRET CARD"
1400 IF X< I0THEN PRINT "I THINK IT'S THE";- X
1410 PLOT 6,5
1420 PRINT :PRINT "THE SECRET CARD IS THE......";
1430 PLOT 6,3:PRINT M
1440 PLOT 6:PLOT 2
1450 PRINT :G= G+ I1:Z= I0
1460 IF X< = I0THEN 1480
1470 IF X= MTHEN Z= I1
1480 IF X= > I0THEN 1510
1490 IF - X< > MTHEN Z= I1
1500 PLOT 6,1,31
1510 IF Z= I0THEN G1= G1+ I1:PRINT "I WIN"
1520 IF Z= I1THEN PRINT "YOU WIN":G5= G5+ I1
1530 FOR I= 1TO 1000:NEXT I
1540 PLOT 15,14,6,4
1550 PRINT :PRINT "WE'VE PLAYED";G;" GAME(S) THIS SERIES"
1560 PRINT "I'VE WON";G1
1570 PRINT "YOU'VE WON";G5:PRINT
1580 PLOT 6,6:INPUT "HOW ABOUT ANOTHER GAME ?";N$
1590 IF LEFT$ (N$,1)= "Y"THEN PLOT 12:GOTO 260
1600 PRINT
1610 PRINT :PRINT "SO LONG. IT'S BEEN FUN"
1620 FOR I= 1TO 1000:NEXT I
1630 PLOT 6,2,12,1