Compucolor.org – Virtual Media

Listing of file='RESCUE.BAS;01' on disk='vmedia/word_puzzle-sector.ccvf'

0 REM WRITTEN BY M.BRENNER
1 REM (C) 1981 BY CREATIVE COMPUTING BORKEN (C.C.B.)
2 T= 100:GOSUB 9000
3 PLOT 12:S= S+ 1
4 PLOT 15:PRINT TAB( 44)"(C) 1981 BY (C.C.B.)":PLOT 14,8
5 PRINT TAB( 10)"*** S P A C E - R E S C U E ***"
6 PRINT TAB( 45);
7 PRINT C;:PRINT ":SHIP DESROYED"
8 PRINT TAB( 45);
9 PRINT E;:PRINT ":SHIP RESCUED"
10 PLOT 2,10,0,242,117,0,255
13 T= T- 10
15 R= 7:F= 17:Y= 120:X= 60:XX= 58:YY= 0
20 W= INT (RND (5)* 3)
30 IF W= 1THEN X= X+ R
40 IF W= 2THEN X= X- R
45 IF X< 1THEN X= X+ R
46 IF X> 127THEN X= X- R
50 Y= Y- 6
55 GOSUB 1000
56 FOR I= 1TO T:NEXT I
60 GOSUB 2000
70 U= VAL (CHR$ (PEEK (33278)))
75 PLOT 32:PLOT 8
76 PLOT 3,64,64
80 IF U= 1THEN XX= XX- R
90 IF U= 3THEN XX= XX+ R
95 IF XX> 127THEN XX= XX- R
96 IF XX< 1THEN XX= XX+ R
100 YY= YY+ 6
110 GOSUB 3100
120 FOR I= 1TO T:NEXT I
130 GOSUB 3000
140 IF XX+ 2= XAND Y= 60THEN GOTO 6000
145 IF YY> YTHEN GOTO 7000
160 IF S= 7THEN 8000
300 GOTO 20
500 END
1000 REM
1005 PLOT 29,17
1010 PLOT 2,X,Y,242,X+ 6,Y,255
1020 PLOT 2,X+ 2,Y+ 1,242,X+ 4,Y+ 1,255
1030 PLOT 2,X+ 2,Y- 1,242,X+ 4,Y- 1,255
1040 IF F1= 1THEN PLOT 2,X,Y+ 1,X+ 6,Y+ 1,255:F1= 0:GOTO 1060
1050 PLOT 2,X,Y- 1,X+ 6,Y- 1,255:F1= 1
1060 PLOT 29,18
1090 REM
1095 RETURN
2000 PLOT 29,16
2010 PLOT 2,X,Y- 1,242,X+ 6,Y- 1,255
2020 PLOT 2,X,Y,242,X+ 6,Y,255
2030 PLOT 2,X,Y+ 1,242,X+ 6,Y+ 1,255
2040 PLOT 29,18
2050 RETURN
2990 PLOT 29,20
3000 PLOT 2,XX,YY,242,XX+ 10,YY,255
3010 PLOT 2,XX,YY+ 1,XX+ 10,YY+ 1,255
3020 PLOT 29,18
3025 X2= XX:Y2= YY
3030 RETURN
3100 PLOT 29,16
3110 PLOT 2,X2,Y2,242,X2+ 10,Y2,255
3120 PLOT 2,X2,Y2+ 1,X2+ 10,Y2+ 1,255
3130 PLOT 29,18
3140 RETURN
6000 PLOT 29,17
6010 PLOT 2,X,Y+ 2,242,X+ 6,Y+ 2,255
6020 PLOT 29,18
6025 PRINT :PRINT :PRINT :PRINT :PRINT TAB( 10);
6030 PRINT "R E S C U E D !!!"
6035 E1= 6
6036 E= E+ 1
6040 FOR I= 1TO 500:NEXT I:GOTO 3
7000 C= C+ 1
7005 PRINT :PRINT :PRINT :PRINT TAB( 30);
7006 PRINT "DESTROYED"
7010 FOR I= 1TO 500:NEXT I:GOTO 3
8000 REM
8010 FOR I= 1TO 5:PRINT :NEXT I
8020 PRINT C;:PRINT ":SHIP DESTROYED"
8030 PRINT E;:PRINT ":SHIP RESCUED"
8040 PRINT TAB( 20)"G A M E  O V E R"
8050 PRINT :PRINT TAB( 10)"WANT TO PLAY AGAIN ";
8055 INPUT A$
8060 IF A$= "J"OR A$= "Y"THEN RUN
8070 LOAD "MENU":RUN
9000 REM
9001 PLOT 12
9005 PRINT TAB( 10);
9010 PRINT "* * * S P A C E - R E S C U E * * *"
9020 PRINT :PRINT :PRINT :PRINT
9030 PRINT "YOU HAVE TO RESCUE 6 SHIPS WICH ARE WITHOUT PETROL"
9040 PRINT "SINKING TO THE GROUND."
9050 PRINT "IF YOU DON'T CATCH THEM THEY WILL DESTROY ON THE GROUND"
9055 PRINT :PRINT
9060 PRINT "YOR MOVES ARE 1-LEFT,3-RIGHT AND ANY OTHER KEY TO"
9070 PRINT "FLY DIRECT TO THE SKY."
9075 PRINT
9080 INPUT "ARE YOU READY THEN PRESS RETURN";AA
9100 RETURN