Compucolor.org – Virtual Media

Listing of file='INV2CD.BAS;01' on disk='vmedia/chip_107-sector.ccvf'

60 PLOT 12,3,0,4,15
100 CLEAR 500:DIM INX$(16,9),SRT$(63):GOTO 290
220 PUT 1,M;SRT$[64]:RETURN
230 GET 1,M;SRT$[64]:RETURN
240 GET 1,M,15;V$[12]:RETURN
250 GET 1,M;N$[10]:RETURN
260 GET 1,M;N$[10],C,V$[10],E$[12],D,L,H,S,A$[8],P:RETURN
270 PUT 1,M;N$[10],C,V$[10],E$[12],D,L,H,S,A$[8],P:RETURN
280 GET 2,1;NU:RETURN
290 FILE "R",1,"CD1:INV",1:FILE "R",2,"CD1:NOITEM",1
300 PLOT 12,3,15,4:PRINT "COLORDATA INVENTORY CONTROL (C)1981":PRINT
310 PRINT TAB( 23)"RENAISSANCE MARKETING":PLOT 3,0,10
360 PRINT TAB( 45)"________":PLOT 28
370 PRINT TAB( 12):INPUT "TYPE IN THE DATE, AS : 01/14/79  ";D$:IF LEN (D$)< > 8THEN PLOT 28,11:GOTO 360
375 PRINT :PRINT :PRINT TAB( 23)"INDEXING DATA FILES...":GOSUB 5000
380 PLOT 12,3,0,2
410 PRINT TAB( 15)"I N V E N T O R Y   C O N T R O L":PRINT
420 PRINT TAB( 13)"ENTER YOUR CHOICE TO THE PROGRAM PROMPT"
425 GOSUB 7000:PRINT
440 PRINT TAB( 15)"( 1 ) = MINIMUM QUANTITY SEARCH":PRINT
460 PRINT TAB( 15)"( 2 ) = INVENTORY LIST":PRINT
480 PRINT TAB( 15)"( 3 ) = INVENTORY LIST BY CLASS":PRINT
500 PRINT TAB( 15)"( 4 ) = INVENTORY LIST BY VENDOR":PRINT
520 PRINT TAB( 15)"( 5 ) = UPDATE THE INVENTORY":PRINT
540 PRINT TAB( 15)"( 6 ) = INVENTORY LIST BY ITEM":PRINT
560 PRINT TAB( 15)"( 7 ) = STOP PROGRAM":PRINT
580 PRINT TAB( 13):INPUT "WHICH REPORT WOULD YOU LIKE TO RUN ? ";R:IF R< 1OR R> 7THEN PLOT 28,11:GOTO 580
600 ON RGOTO 690,1140,1540,2010,2460,3280,3640:GOTO 580
690 PLOT 12:PRINT :SS= 0
750 PRINT "    M I M I M U M    Q U A N T I T Y    S E A R C H  ";D$
780 PRINT :PRINT
800 PRINT TAB( 7)"EXAMPLE : TO CHECK FOR 0 STOCK ITEMS TYPE A (1)":PRINT
820 PRINT TAB( 7)"TO CHECK ITEMS WITH < 5 TYPE A (5). (0=EXIT)":PRINT
860 INPUT "        INPUT QUANTITY : ";A5:IF A5< = 0THEN 380
870 PLOT 12:GOSUB 280
930 PRINT "    MINIMUM QUANTITY ON HAND SEARCH REPORT   ";D$
940 PRINT :PRINT
960 PRINT  " ITEM";TAB( 15)"DESCRIPTION";TAB( 30)"QTY.";TAB( 45)"# SOLD";TAB( 55)"LOCATION
970 GOSUB 7000:PLOT 22:FOR M= 1TO NU:GOSUB 260:IF PEEK (33278)= 64THEN 1120
1030 IF H< A5THEN 1050
1040 GOTO 1090
1050 REM
1060 PRINT TAB( 1)N$;TAB( 15)E$;TAB( 30)H;TAB( 45)S;TAB( 55)L
1070 SS= SS+ 1:IF SS= 24THEN SS= 0:GOSUB 4100:PLOT 22
1090 NEXT :PRINT :PRINT
1120 PLOT 18:INPUT " HIT RETURN TO CONTINUE";X:GOTO 380
1140 PLOT 12:GOSUB 7010:PRINT TAB( 17):INPUT "INVENTORY LIST ( E=EXIT ) :";X$:IF X$= "E"THEN 380
1160 PLOT 12:PRINT "      L I S T    O F   I N V E N T O R Y     ";D$:PRINT
1180 PRINT "ITEM";TAB( 10)"CLASS #";TAB( 21)"VENDOR";TAB( 37)"COST $";TAB( 50)"DESCRIPTION":PRINT
1200 PRINT "LOCATION #";TAB( 15)"QTY.";TAB( 26)"# SOLD";TAB( 37)"SELLING PRICE";
1210 PRINT TAB( 55)"LST DATE":GOSUB 7000
1230 SS= 0:A1= 0:A2= 0:A3= 0:A4= 0:PLOT  22:GOSUB  280
1290 FOR M= 1TO NU:GOSUB 260
1295 IF PEEK (33278)= 64THEN 1430
1300 IF LEFT$ (N$,1)= "0"THEN 1420
1310 K= D:GOSUB 6900
1330 PRINT N$;TAB( 10)C;TAB( 21)V$;TAB( 37)K$;TAB( 50)E$
1340 K= P:GOSUB 6900
1360 PRINT L;TAB( 15)H;TAB( 26)S;TAB( 37)K$;TAB( 55)A$
1370 GOSUB 7010:PLOT 22
1380 SS= SS+ 1:IF SS= 8THEN SS= 0:GOSUB 4080:PLOT 22
1390 A1= A1+ D* H:A2= A2+ P* S:A3= A3+ H
1420 NEXT
1430 PRINT :PLOT 18:PRINT :K= A1:GOSUB 6900
1460 PRINT "PRESENT INVENTORY COST  = ";K$
1470 PRINT "TOTAL NUMBER OF PIECES  = ";A3:K= A2:GOSUB 6900
1480 PRINT "TOTAL LST SALES PERIODS = ";K$:N= NU
1500 PRINT "TOTAL NUMBER OF INVENTORY ITEMS ON RECORD = ";N
1510 PRINT :INPUT " HIT RETURN TO CONTINUE";X:GOTO 380
1540 REM
1550 PLOT 12,3,0,4
1570 PRINT "THIS REPORT GENERATES A LIST BY CLASS CODE FROM THE ITEMS"
1580 PRINT "PRESENTLY ON YOUR INVENTORY RECORD ."
1583 PRINT :GOSUB 6000:PRINT :PRINT
1590 INPUT "TYPE IN THE CLASS CODE YOU WANT SEARCHED (0=EXIT):";A5
1600 SS= 0:B1= 0:B2= 0:B3= 0:PLOT  12:IF  A5= 0 THEN  380
1640 PRINT "       C L A S S  C O D E  #  ";A5;"  L I S T   ";D$
1650 PRINT :PRINT
1670 PRINT  " CLASS #";TAB( 13)"ITEM";TAB( 25)"DESCRIPTION";TAB( 40)"QTY.";TAB( 55)"VENDOR"
1690 GOSUB 7000:PRINT :A7= 0:PLOT  22:GOSUB  280
1730 FOR M= 1TO NU:GOSUB 260
1735 IF PEEK (33278)= 64THEN 1860
1740 IF C= A5THEN 1770
1750 NEXT :GOTO  1860
1770 SS= SS+ 1:IF SS= 25THEN SS= 0:GOSUB 4100:PLOT 22
1780 PRINT C;TAB( 13)N$;TAB( 25)E$;TAB( 40)H;TAB( 53)V$
1810 B1= B1+ H* D:B2= B2+ 1:B3= B3+ H:A7= 1
1850 GOTO 1750
1860 PRINT
1900 K= B1:GOSUB 6900
1910 PRINT "TOTAL CLASS COST  = ";K$
1920 PRINT "TOTAL NUMBER OF ITEMS  = ";B2
1930 PRINT "TOTAL NUMBER OF PIECES = ";B3
1940 PLOT 18:PRINT :PRINT
1960 INPUT "WOULD YOU LIKE TO CHECK ANOTHER CLASS CODE (YES OR NO)  ";Y$
1980 IF Y$= "YES"OR Y$= "Y"THEN 1550
2000 GOTO 380
2010 REM
2020 PLOT 12
2025 PRINT TAB( 20)"INVENTORY LIST BY VENDOR":GOSUB 7010
2030 PLOT 3,42,4:PRINT "__________"
2040 PLOT 3,8,4:INPUT "ENTER THE VENDOR CODE ( E=EXIT ): ";T$:PRINT :IF T$= "E"OR T$= ""THEN 380
2045 GOSUB 7010
2050 PLOT 12
2060 PRINT "      V E N D O R    C O D E    L I S T    ";D$
2070 PRINT
2090 PRINT  " VENDOR";TAB( 13)"ITEM";TAB( 30)"COST";TAB( 41)"QTY.";TAB( 52)"DESCRIPTION"
2100 GOSUB 7000:X= LEN (T$)
2110 SS= 0:U2= 0:PLOT 22:A1= 0:B1= 0:A7= 0:GOSUB 280
2170 FOR M= 1TO NU:GOSUB 240
2175 IF PEEK (33278)= 64THEN 2340
2180 IF LEFT$ (V$,X)= T$THEN GOSUB 260:GOTO 2225
2210 PLOT 22:NEXT
2220 GOTO 2310
2225 K= D:GOSUB 6900:SS= SS+ 1:IF SS= 25THEN SS= 0:GOSUB 4100
2240 PRINT V$;TAB( 13)N$;TAB( 25)K$;TAB( 41)H;TAB( 51)E$
2270 A7= 1:A1= A1+ 1:B1= B1+ D* H:GOTO  2210
2310 PRINT :IF A7= 1THEN 2340
2330 PRINT " VENDOR NOT IN INVENTORY LIST":PRINT :GOTO 2380
2340 PLOT 3,0,26:PRINT
2350 PRINT "TOTAL NUMBER OF ITEMS = ";A1
2360 K= B1:GOSUB 6900
2365 PRINT
2370 PRINT "TOTAL COST THIS VENDOR = ";K$
2380 PLOT 18:PRINT
2410 INPUT "WOULD YOU LIKE TO CHECK ANOTHER VENDOR ";Y$
2430 IF Y$= "Y"OR Y$= "YES"THEN 2010
2450 GOTO 380
2460 REM
2470 PLOT 12,3,0,4
2490 PRINT  TAB( 15)"THIS IS THE UPDATING SECTION"
2500 GOSUB 7000:PRINT
2520 PRINT TAB( 15)"( 1 ) = EXIT THIS SECTION":PRINT
2540 PRINT TAB( 15)"( 2 ) = ADD A NEW ITEM":PRINT
2560 PRINT TAB( 15)"( 3 ) = UPDATE AN OLD ITEM":PRINT
2580 PRINT TAB( 15)"( 4 ) = DELETE AN OLD ITEM":PRINT
2585 PRINT TAB( 15)"( 5 ) = CHANGE FILE DATA":PRINT
2590 PRINT TAB( 15)"( 6 ) = CLEAR NUMBER SOLD":PRINT :PRINT
2600 INPUT "          WHICH REPORT WOULD YOU LIKE TO RUN ?  ";F:IF F< 1OR F> 6THEN PLOT 28,11:GOTO 2600
2610 ON FGOTO 380,2670,2990,3720,4400,4900:GOTO 2600
2670 REM
2690 PLOT 12:SX= 0:GOSUB 280:X= 768- (NU+ 1)
2720 PRINT :PRINT " NUMBER OF INV. FILES REMAINING = ";X
2730 GOSUB 7010
2740 PRINT :GOTO 2780
2770 PLOT 12,3,0,4
2780 PRINT " ENTER THE ITEM DATA AS FOLLOWS : ":PRINT
2785 PRINT "                       __________":PLOT 3,0,6
2790 INPUT " MODEL OR ITEM #  AN = ";GH$
2795 IF GH$= "EXIT"OR GH$= ""THEN GOTO 2980
2810 INPUT "         CLASS #   N = ";C1
2815 PRINT "                       __________":PLOT 3,0,8
2820 INPUT "          VENDOR  AN = ";V1$
2825 PRINT "                       ____________":PLOT 3,0,9
2830 INPUT "     DESCRIPTION  AN = ";E1$
2840 INPUT "            COST   N = ";D1
2850 INPUT "      LOCATION #   N = ";L1
2860 INPUT "            QTY.   N = ";ZJ
2870 INPUT "          # SOLD   N = ";ZS
2880 INPUT "DATE OF LST SALE  AN = ";A1$
2885 IF A1$= "D"THEN A1$= D$:PLOT 28:PRINT D$
2890 INPUT "   SELLING PRICE   N = ";PZ
2900 PRINT
2910 INPUT "ANY CHANGES ? ( Y OR N, E=EXIT ): ";Y$:IF Y$= "Y"THEN 2770
2915 IF Y$= "E"THEN 2470
2935 GOSUB  6100
2940 NU= NU+ 1:PUT 2,1;NU
2960 FILE "D",1,2
2970 GOTO 2670
2980 PLOT 12:GOSUB 5000:GOTO 2460
2990 REM
3000 PLOT 12:PRINT TAB( 20)"UPDATE ITEM DATA":GOSUB 7010:PRINT
3030 INPUT " INPUT THE ITEM # < 10 CHR. (E=EXIT) * ";P$:IF P$= "E"OR P$= ""THEN 2470
3040 X= LEN (P$):GOSUB 5090:GOSUB 280:FOR M= TITO NU:GOSUB 250
3050 IF LEFT$ (N$,X)= P$THEN PRINT :GOSUB 260:GOTO 3130
3055 NEXT
3120 PRINT  " ITEM NOT ON FILE":FOR I= 1TO 500:NEXT I:GOTO 2990
3130 PRINT "# ON HAND = ";H
3140 GOSUB 7010
3150 PRINT :PRINT "  ENTER THE ITEM DATA AS FOLLOWS : "
3160 PRINT
3170 INPUT " # OF INCOMMING     = ";II
3180 IF II< = 0THEN IT= 1:GOTO 3200
3185 PRINT
3187 K= D:GOSUB 6900
3190 PRINT " CURRENT COST       = ";K$;
3191 INPUT "    ANY CHANGES ( Y OR N ) : ";X$
3192 IF X$= "N"OR  X$= ""THEN H= H+ II:GOTO 3200
3195 PRINT :INPUT " ENTER NEW COST     = ";CA
3196 IF H= 0AND IT= 1THEN D= CA:GOTO 3199
3197 W1= H* D:W2= II* CA:D= (W1+ W2)/ (H+ II)
3199 H= H+ II
3200 PRINT :INPUT " # SOLD THIS PERIOD = ";IS
3210 S= S+ IS:PRINT
3220 INPUT " ENTER TRANS. DATE  = ";A$
3225 IF A$= "D"THEN A$= D$
3240 H= H- IS:GOSUB 270
3260 FILE "D",1:GOTO 3000
3280 PLOT 12:B1= 0:PRINT TAB( 19)"INVENTORY SEARCH BY ITEM":GOSUB 7010
3285 PRINT TAB( 31)"__________":PLOT 3,0,2
3330 INPUT " ENTER THE ITEM #  ( E=EXIT ) : ";P$:IF P$= "E"OR P$= ""THEN 380
3335 GOSUB 7010:GOSUB 280
3340 X= LEN (P$):GOSUB 5090:IF TI= 0THEN TI= 1
3400 FOR M= TITO NU:GOSUB 250
3460 IF LEFT$ (N$,X)= P$THEN PRINT :GOSUB 260:GOSUB 4500:GOTO 3510
3485 NEXT
3510 B1= B1+ D* H
3530 K= B1:GOSUB 6900
3540 GOSUB 7010:PRINT " TOTAL COST THIS ITEM = ";K$:PRINT
3550 INPUT " WOULD YOU LIKE TO CHECK ANOTHER ITEM ? ";X$:IF X$= "Y"OR X$= "YES"THEN PLOT 18:GOTO 3280
3560 GOTO 380
3580 REM
3640 PLOT 12
3650 FILE "C",1,2:LOAD  "MENU;1":RUN
3720 SS= 0:REM
3730 PLOT 12:PRINT TAB( 18)"DELETE ITEM FROM INVENTORY":GOSUB 7010:PLOT 3,44,4:PRINT "__________"
3740 PLOT 3,10,4:INPUT " ENTER ITEM # < 10 CHR. (E=EXIT): ";IN$:IF IN$= "E"AND SS= 0THEN 3885
3745 IF IN$= "E"THEN GOSUB 5000:GOTO 3885
3750 X= LEN (IN$):PRINT :GOSUB 7010:GOSUB 280:FOR M= 1TO NU:GOSUB 260
3790 IF LEFT$ (N$,X)= IN$THEN 3830
3800 NEXT :PRINT
3820 PRINT " ITEM # NOT ON FILE ":FOR I= 1TO 750:NEXT I:GOTO 3880
3830 PRINT  V$;TAB( 15)N$;TAB( 30)C;TAB( 40)H;TAB( 45)M;TAB( 50)E$
3840 PRINT :PRINT "SORTING DO NOT INTERRUPT ":PRINT :GOSUB 6500
3870 PRINT " ITEM DELETED FROM INVENTORY LIST "
3880 FILE "D",1,2:PRINT :INPUT " DELETE ANOTHER ITEM ? ( Y OR N ) ";X$:IF X$= "Y"THEN SS= 1:GOTO 3720
3885 GOSUB 5000:GOTO 2460
3890 X= LEN (GH$):FOR M= 1TO NU:GOSUB 260
3920 IF LEFT$ (N$,X)= GH$THEN 3980
3950 NEXT :RETURN
3980 PRINT "   ITEM # ALREADY ON FILE ":FOR I= 1TO 500:NEXT I:GOTO 2460
4080 PRINT "HIT 'BREAK TO STOP', (CR) TO CONTINUE, P= PREVIOUS, E= EXIT : ":PLOT 16
4081 JZ= 00:FOR I= 1TO 1250:NEXT I
4082 JZ= PEEK (33278):IF JZ= 69THEN 380
4085 IF JZ= 80AND M= > 16THEN M= M- 16:FOR I= 1TO 25:PLOT 28,11:NEXT I:POKE 33278,46:RETURN
4086 FOR I= 1TO 25:PLOT 28,11:NEXT I:POKE 33278,46:RETURN
4100 PRINT "HIT 'BREAK' TO STOP, (CR) TO CONTINUE,  E= EXIT : ":PLOT 16
4110 JZ= 00:FOR I= 1TO 1250:NEXT I
4120 JZ= PEEK (33278):IF JZ= 69THEN 380
4130 FOR I= 1TO 25:PLOT 28,11:NEXT I:POKE 33278,46:RETURN
4400 PLOT 12:PRINT TAB( 20)"CHANGE ITEM DATA":GOSUB 7010:PLOT 3,37,2:PRINT "__________":PLOT 3,5,2
4405 INPUT "      ENTER ITEM # ( E=EXIT ) : ";P$:IF P$= "E"OR P$= ""THEN 2470
4420 GOSUB 7010:GOSUB 280
4440 X= LEN (P$):GOSUB 5090:IF TI= 0THEN TI= 1
4445 FOR M= TITO NU:GOSUB 250
4450 IF LEFT$ (N$,X)= P$THEN GOSUB 260:GOSUB 4500:GOTO 4600
4455 NEXT
4460 PRINT "ITEM NOT ON FILE ":FOR I= 1TO 1000:NEXT I:GOTO 2470
4500 PRINT TAB( 15)"(1) MODEL OR ITEM # = ";N$:PRINT
4510 PRINT TAB( 15)"(2)         CLASS # = ";C:PRINT
4520 PRINT TAB( 15)"(3)          VENDOR = ";V$:PRINT
4530 PRINT TAB( 15)"(4)     DESCRIPTION = ";E$:PRINT
4535 K= D:GOSUB 6900
4540 PRINT TAB( 15)"(5)            COST = ";K$:PRINT
4550 PRINT TAB( 15)"(6)      LOCATION # = ";L:PRINT
4560 PRINT TAB( 15)"(7)            QTY. = ";H:PRINT
4570 PRINT TAB( 15)"(8)          # SOLD = ";S:PRINT
4580 PRINT TAB( 15)"(9)DATE OF LST SALE = ";A$:PRINT
4585 K= P:GOSUB 6900
4590 PRINT TAB( 15)"(10)  SELLING PRICE = ";K$:PRINT :RETURN
4600 INPUT "ANY CHANGES ? ( Y OR N, E=EXIT ): ";Y$
4610 IF Y$= "N"OR Y$= "E"THEN 2470
4620 IF Y$= "Y"THEN 4630
4625 PLOT 28,11:GOTO 4600
4630 PRINT :INPUT "ENTER # OF CHANGE ( 2 TO 10 ) : ";X
4640 GOSUB 7010
4650 ON XGOTO 4655,4660,4670,4680,4690,4700,4710,4720,4730,4740
4655 GOTO 2470
4660 INPUT "ENTER NEW CLASS CODE : ";C:GOTO 4800
4670 INPUT "ENTER NEW VENDOR : ";V$:GOTO 4800
4680 INPUT "ENTER NEW DESCRIPTION : ";E$:GOTO 4800
4690 INPUT "ENTER NEW COST : ";D:GOTO 4800
4700 INPUT "ENTER NEW LOCATION # : ";L:GOTO 4800
4710 INPUT "ENTER NEW QTY. : ";H:GOTO 4800
4720 INPUT "ENTER NEW # SOLD : ";S:GOTO 4800
4730 INPUT "ENTER NEW DATE : ";A$:GOTO 4800
4740 INPUT "ENTER NEW SELLING PRICE : ";P:GOTO 4800
4800 GOSUB 270:FILE "D",1:FOR I= 1TO 5:PLOT 28,11:NEXT I:GOTO 4600
4810 GOTO 2470
4900 PLOT 12:PRINT TAB( 15):INPUT "C = CLEAR MTD SALES ( E=EXIT ): ";X$:IF X$= "E"OR X$= ""THEN 380
4905 PRINT :PRINT TAB( 15)"THIS WILL TAKE A WHILE....."
4910 GOSUB 280:FOR M= 1TO NU:GOSUB 260:S= 0:GOSUB 270:NEXT M
4930 FILE "D",1:GOTO 2460
5000 M= 0:FOR NX= 1TO 16:M= M+ 48:GOSUB 250:INX$(NX,9)= N$:NEXT NX
5010 RETURN
5090 REM
5100 M= 1:FOR NX= 1TO 16:IF LEFT$ (INX$(NX,9),X)> P$THEN TI= (NX- 1)* 48:RETURN
5105 IF INX$(NX,9)= "          "THEN TI= (NX- 1)* 48:RETURN
5110 NEXT NX:TI= 15* 48:RETURN
6000 GOSUB 7010:Q1= 8
6008 PLOT 22
6010 DATA "AMP-POWER","AMP-INT","CAR-BOOSTER","CAR-RECV.","CAR-SPK'S","CALCULATORS"
6020 DATA "COMPACTS","COMPUTERS","DECK-CASSETTE","DECK-REEL","EQUALIZERS","GAMES"
6030 DATA "RACKS","RECEIVERS","TUNERS","TURNTABLES-B","TURNTABLES-D"
6035 DATA " "," "," "
6040 RESTORE 6010:PRINT :FOR I= 1TO 20
6045 READ A$
6050 IF I> 10THEN 6070
6060 PRINT I,A$
6065 NEXT I:PLOT 18:RETURN
6070 Q1= Q1+ 1:PLOT 3,31,Q1
6073 PRINT I,A$
6075 GOTO 6065
6100 GET 2,1;NU
6110 X= LEN (GH$):CC= NU
6120 FOR M= CCTO 1STEP - 1
6130 GOSUB  230
6135 IF LEFT$ (SRT$,X)> GH$THEN 6200
6160 N$= GH$:C= C1:V$= V1$:E$= E1$:D= D1:L= L1:H= ZJ:S= ZS:A$= A1$:P= PZ
6170 M= M+ 1:GOSUB 270:GOTO 6190
6180 NEXT
6190 RETURN
6200 M= M+ 1:GOSUB 220
6230 M= M- 1:GOSUB 220
6240 GOTO 6180
6500 Z2= M+ 1:M= 0
6510 FOR M= Z2TO NU
6520 GOSUB 230:M= M- 1
6530 GOSUB 220:M= M+ 1
6540 NEXT
6550 N$= " ":C= 0:V$= " ":E$= " ":D= 0:L= 0:H= 0:S= 0:A$= " ":P= 0
6560 GOSUB 270:NU= NU- 1:PUT 2,1;NU:RETURN
6900 IF K= 0THEN K$= "      0.00":RETURN
6905 IF K= INT (K)THEN K$= STR$ (ABS (K))+ ".00":GOTO 6920
6910 K$= LEFT$ (STR$ (SGN (K)),1)+ MID$ (STR$ (INT (ABS (K))),2)+ MID$ (STR$ ((ABS (K))- INT (ABS (K))+ 1.001),3,3)
6920 K$= RIGHT$ ("      "+ K$,10):RETURN
7000 PRINT "---------------------------------------------------------------":RETURN
7010 PRINT "---------------------------------------------------------------":RETURN