Compucolor.org – Virtual Media

Listing of file='IPT2CD.BAS;01' on disk='vmedia/chip_107-sector.ccvf'

60 PLOT 27,24:PLOT 12,3,0,4
100 PLOT 15:CLEAR 300:DIM E$(12):GOTO 290
240 GET 1,M,15;V$[12]:RETURN
250 GET 1,M;N$[10]:RETURN
260 GET 1,M;N$[10],C,V$[10],E$[12],D,L,H,S,A$[8],P:RETURN
280 GET 2,1;NU:RETURN
290 FILE "R",1,"CD1:INV",1:FILE "R",2,"CD1:NOITEM",1
300 PLOT 12,3,15,4:PRINT "COLORDATA INVENTORY CONTROL (C)1981":PRINT
310 PRINT TAB( 23)"RENAISSANCE MARKETING":PLOT 3,0,10
340 PRINT TAB( 15)"THIS IS THE INVENTORY REPORTS PROGRAM":PRINT :PRINT
360 PRINT TAB( 45)"________":PLOT 28
370 PRINT TAB( 12):INPUT "TYPE IN THE DATE, AS : 01/14/79  ";D$:IF LEN (D$)< > 8THEN PLOT 28,11:GOTO 360
375 PRINT :PRINT :PRINT TAB( 18):INPUT "SELECT BAUD RATE ( 1 TO 7 ) :";BR:IF BR< 1OR BR> 7THEN PLOT 28,11:GOTO 375
378 PLOT 14,27,18,BR,15:POKE  33289,120
380 PLOT 12,3,0,2
410 PRINT TAB( 15)"I N V E N T O R Y   C O N T R O L":PRINT
420 PRINT TAB( 13)"ENTER YOUR CHOICE TO THE PROGRAM PROMPT"
425 GOSUB 7000:PRINT
460 PRINT TAB( 15)"( 1 ) = PRINT INVENTORY LIST":PRINT
500 PRINT TAB( 15)"( 2 ) = PRINT INVENTORY LIST BY VENDOR":PRINT
540 PRINT TAB( 15)"( 3 ) = PRINT ITEM DATA":PRINT
560 PRINT TAB( 15)"( 4 ) = STOP PROGRAM":PRINT
580 PRINT TAB( 13):INPUT "WHICH REPORT WOULD YOU LIKE TO RUN ? ";R
600 ON RGOTO 1140,2010,3280,3640:GOTO 580
1140 PLOT 12:GOSUB 7010:PRINT TAB( 17):INPUT "INVENTORY LIST ( E=EXIT ) :";X$:GOSUB 7010:IF X$= "E"THEN 380
1145 PRINT TAB( 15)"OUTPUT TO PRINTER ........"
1150 GOSUB 5000:GOSUB 1160:GOTO 1230
1160 PRINT TAB( 20)"L I S T    O F   I N V E N T O R Y    ";D$:PRINT
1180 PRINT "ITEM";TAB( 11)"QTY";TAB( 18)"VENDOR";TAB( 30)"DESCRIPTION";TAB( 48)"COST $";
1200 PRINT TAB( 58)"L #";TAB( 64)"CLASS";TAB( 71)"# SOLD";TAB( 80)"RETAIL PRICE";
1210 PRINT TAB( 94)"LST DATE":PRINT "-------------------------------------------------------------";
1215 PRINT "-----------------------------------------":RETURN
1230 TT= 0:A1= 0:A2= 0:A3= 0:A4= 0:PLOT  22:GOSUB  280
1290 IN$= "0":X= LEN (IN$):FOR M= 1TO NU:GOSUB 260
1295 JZ= PEEK (33278):IF JZ= 64THEN 1430
1300 IF LEFT$ (N$,X)= IN$THEN 1420
1305 TT= TT+ 1:IF TT= 56THEN TT= 0:PLOT 12:GOSUB 1160
1310 K= D:GOSUB 4000:XC= P:GOSUB 4100
1330 PRINT N$;TAB( 10)H;TAB( 18)V$;TAB( 30)E$;TAB( 44)K$;TAB( 58)L;TAB( 65)C;TAB( 72)S;TAB( 79)XC$;TAB( 94)A$
1390 A1= A1+ D* H:A2= A2+ P* S:A3= A3+ H
1420 NEXT
1430 PRINT :PRINT :K= A1:GOSUB 4000
1460 PRINT "PRESENT INVENTORY COST  = ";K$
1470 PRINT "TOTAL NUMBER OF PIECES  = ";A3:K= A2:GOSUB 4000
1480 PRINT "TOTAL LST SALES PERIODS = ";K$:N= NU
1500 PRINT "TOTAL NUMBER OF INVENTORY ITEMS ON RECORD = ";N
1505 PLOT 12:GOSUB 5500
1510 PRINT :INPUT " HIT RETURN TO CONTINUE";X:GOTO 380
2010 REM
2020 PLOT 12
2025 PRINT TAB( 20)"INVENTORY LIST BY VENDOR":GOSUB 7010
2030 PLOT 3,42,4:PRINT "__________"
2040 PLOT 3,8,4:INPUT "ENTER THE VENDOR CODE ( E=EXIT ): ";T$:PRINT :IF T$= "E"THEN 380
2045 GOSUB 7010
2047 PRINT TAB( 15)"OUTPUT TO PRINTER ......":GOSUB 5000
2048 GOSUB 2060:GOTO 2110
2060 PRINT TAB( 15)"V E N D O R    C O D E    L I S T    ";D$
2070 PRINT
2090 PRINT  " VENDOR";TAB( 13)"ITEM";TAB( 30)"COST";TAB( 41)"QTY.";TAB( 51)"DESCRIPTION";TAB( 66)"EXTD. COST $"
2100 PRINT "-------------------------------------------------------------------------------":RETURN
2110 X= LEN (T$):TT= 0:U2= 0:A1= 0:B1= 0:A7= 0:GOSUB 280
2170 FOR M= 1TO NU:GOSUB 240
2175 JZ= PEEK (33278):IF JZ= 64THEN 2340
2180 IF LEFT$ (V$,X)= T$THEN GOSUB 260:GOTO 2225
2210 NEXT
2220 GOTO 2310
2225 K= D:GOSUB 4000:XC= D* H:GOSUB 4100
2240 PRINT V$;TAB( 13)N$;TAB( 25)K$;TAB( 41)H;TAB( 51)E$;TAB( 66)XC$
2260 TT= TT+ 1:IF TT= 56THEN TT= 0:PLOT 12:GOSUB 2060
2270 A7= 1:A1= A1+ 1:B1= B1+ D* H:GOTO  2210
2310 PRINT :IF A7= 1THEN 2340
2330 PRINT " VENDOR NOT IN INVENTORY LIST":PRINT :GOTO 2380
2340 PRINT :REM
2350 PRINT "TOTAL NUMBER OF ITEMS = ";A1
2360 K= B1:GOSUB 4000
2370 PRINT "TOTAL COST THIS VENDOR = ";K$
2380 PLOT 12:GOSUB  5500:PRINT
2410 INPUT "WOULD YOU LIKE TO CHECK ANOTHER VENDOR ";Y$
2430 IF Y$= "Y"OR Y$= "YES"THEN 2010
2450 GOTO 380
3280 PLOT 12:B1= 0:PRINT TAB( 19)"INVENTORY SEARCH BY ITEM":GOSUB 7010
3285 PRINT TAB( 31)"__________":PLOT 3,0,2
3330 INPUT " ENTER THE ITEM #  ( E=EXIT ) : ";P$:IF P$= "E"THEN 380
3335 GOSUB 5000
3400 GOSUB 7010:X= LEN (P$):GOSUB 280:FOR M= 1TO NU:GOSUB 250
3460 IF LEFT$ (N$,X)= P$THEN PRINT :GOSUB 260:GOSUB 4500:GOTO 3510
3485 NEXT
3510 B1= B1+ D* H
3530 K= B1:GOSUB 4000
3540 GOSUB 7010:PRINT " TOTAL COST THIS ITEM = ";K$:PRINT
3545 PLOT 12:GOSUB 5500:PRINT :PRINT
3550 INPUT " WOULD YOU LIKE TO CHECK ANOTHER ITEM ? ";X$:IF X$= "Y"OR X$= "YES"THEN PLOT 18:GOTO 3280
3560 GOTO 380
3580 REM
3640 PLOT 12
3650 FILE "C",1,2:PRINT
3660 PRINT :PRINT :PRINT
3690 REM
3700 REM
3710 REM
3990 LOAD "MENU;1":RUN
4000 K$= LEFT$ (STR$ (SGN (K)),1)+ MID$ (STR$ (INT (ABS (K))),2)+ MID$ (STR$ ((ABS (K))- INT (ABS (K))+ 1.001),3,3)
4070 K$= RIGHT$ ("      "+ K$,10):RETURN
4100 XC$= LEFT$ (STR$ (SGN (XC)),1)+ MID$ (STR$ (INT (ABS (XC))),2)+ MID$ (STR$ ((ABS (XC))- INT (ABS (XC))+ 1.001),3,3)
4170 XC$= RIGHT$ ("      "+ XC$,10):RETURN
4500 PRINT TAB( 15)"(1) MODEL OR ITEM # = ";N$:PRINT
4510 PRINT TAB( 15)"(2)         CLASS # = ";C:PRINT
4520 PRINT TAB( 15)"(3)          VENDOR = ";V$:PRINT
4530 PRINT TAB( 15)"(4)     DESCRIPTION = ";E$:PRINT
4535 K= D:GOSUB 4000
4540 PRINT TAB( 15)"(5)            COST = ";K$:PRINT
4550 PRINT TAB( 15)"(6)      LOCATION # = ";L:PRINT
4560 PRINT TAB( 15)"(7)            QTY. = ";H:PRINT
4570 PRINT TAB( 15)"(8)          # SOLD = ";S:PRINT
4580 PRINT TAB( 15)"(9)DATE OF LST SALE = ";A$:PRINT
4585 K= P:GOSUB 4000
4590 PRINT TAB( 15)"(10)  SELLING PRICE = ";K$:PRINT :RETURN
5000 TMP= PEEK (33265):PLOT 27,13:RETURN
5500 POKE 33265,TMP:RETURN
7000 PRINT "---------------------------------------------------------------":RETURN
7010 PRINT "---------------------------------------------------------------":RETURN