Compucolor.org – Virtual Media

Listing of file='MMIND2.BAS;01' on disk='vmedia/chip_21-sector.ccvf'

10 REM  
40 REM       MASTER MIND II        12-1-79
60 REM       COPYRIGHT 1979 BY ROGER SAFFORD
100 REM
110 GOSUB 65000:CLEAR 100:PLOT 6,0,12:K1= 48:K2= 56:DIM R(8,12)
113 HR= 33211:MN= 33210:SC= 33209:N$(0)= "COMPUCOLOR"
116 DEF FN T(T)= PEEK (HR)* 3600+ PEEK (MN)* 60+ PEEK (SC)
120 DEF FN R(Z)= INT (RND (8)* Z):GOSUB 7030:GOSUB 7060
125 IF K= 53THEN PLOT 3,5,29:INPUT "PAUSE ? ";Z$:Z= 1:IF Z$= "N"THEN Z= 0
128 ZK= 0:IF K= 55THEN ZK= 1
130 ON K- 47GOTO 4000,140,140,140,380,470,490,360,135
135 PLOT 1
140 P1= 1:M= K- 48:PLOT 12:GOSUB 7030:PRINT :PRINT TAB( 17);
150 PRINT "HOW MANY PLAYERS ? ( 2 TO 6 )":K1= 50:K2= 54
160 GOSUB 7230:P2= K- 48:FOR I= P1TO P2:PLOT 14,3,15,I* 2+ 6
180 PRINT "NAME OF PLAYER";I;:INPUT " ? ";N$(I)
190 C(I)= M:NEXT I:A$= "YOU BOTH":IF P2> 2THEN A$= "YOU ALL"
200 N$(P2+ 1)= N$(1):PL= 1:GOSUB 210:GOSUB 330:IF K= 89GOTO 420
201 GOTO 400
205 PLOT 3,8+ 3* (I+ 1),Y,6,0,32,32,26,26,10,32,32:RETURN
210 PLOT 15,3,0,3,11,10
220 PRINT "     A STANDARD GAME OF '' MASTER MIND II '' HAS A";
230 PRINT " CODE OF 4":PLOT 11,10
240 PRINT "POSITIONS WITH 6 POSSIBLE COLORS.  HOWEVER, THE NU";
250 PRINT "MBER OF":PLOT 11,10
260 PRINT "POSITIONS AND COLORS ARE SET AT THIS TIME TO DESIR";
270 PRINT "ED QUANITIES.":FOR I= 0TO 20:PLOT 11,10:NEXT I
280 PLOT 14,3,0,13:PRINT "ENTER NUMBER OF POSITIONS FOR ";
290 PRINT "";N$(PL);" ( 2 TO 6 )":K1= 50:K2= 54:GOSUB 7230
300 NP(PL)= K- 48:PLOT 14,3,0,13,11:PRINT "ENTER NUMBER OF C";
310 PRINT "OLORS FOR ";N$(PL);" ( 2 TO 8 )":K2= 56:GOSUB 7230
320 NC(PL)= K- 48:RETURN
330 PLOT 14,3,15,13,11:PRINT "DO ";A$;" PLAY THE SAME NUMBER"
340 PLOT 3,15,15:PRINT "OF POSITIONS AND COLORS ?":K2= 89
350 K1= 78:GOSUB 7230:PLOT 14,3,0,16,11,28,11,28,11:RETURN
360 P1= 0:P2= 0:C(0)= 1:PL= 0:GOSUB 210:RD= 0:GOTO 500
370 PLOT 14,3,14,6:INPUT "ENTER YOUR NAME ";N$(1):RETURN
380 PLOT 12:GOSUB 7030:P1= 1:P2= 1:C(1)= 1:GOSUB 370:PL= 1
390 GOSUB 210:PL= 0:RD= 0:GOTO 500
400 FOR PL= 2TO P2:GOSUB 210:NEXT PL:GOTO 500
420 FOR PL= 2TO P2:NP(PL)= NP(1):NC(PL)= NC(1):NEXT PL:GOTO 500
430 PLOT 14,3,14,6
435 PRINT :PRINT "DO YOU WANT TO STORE YOUR SECRET CODE ? "
440 K1= 78:K2= 89
450 GOSUB 7230:C(0)= 2:IF K= 89THEN C(0)= 3
460 RETURN
470 PLOT 12:GOSUB 7030:P1= 0:P2= 0:GOSUB 370:GOSUB 430
480 PL= 0:GOSUB 210:RD= 0:GOTO 500
490 PLOT 12:GOSUB 7030:P1= 0:P2= 1:C(1)= 1:GOSUB 370:PL= 1
493 GOSUB 430:GOSUB 210:A$= "WE BOTH":GOSUB 330
496 IF K= 89THEN NP(0)= NP(1):NC(0)= NC(1):RD= 0:PL= 0:GOTO 500
498 PL= 0:GOSUB 210:RD= 0
500 IF P1= 0THEN DIM T(1,NC(0),NP(0))
505 IF PL= 0GOTO 530
510 PL= PL+ 1:IF PL< = P2GOTO 540
520 IF P1= 0THEN PL= 0:GOTO 540
530 RD= RD+ 1:PL= 1:IF P2= 0THEN PL= 0
540 PLOT 12:GOSUB 7030:PLOT 15,3,2,3,6,6:PRINT N$(PL)"'S TURN"
550 PLOT 3,45,3:PRINT "ROUND";RD:PRINT :PRINT "     ";NC(PL);
560 PRINT " COLORS: ":II= 0:FOR I= 0TO NC(PL)- 1
570 C= I:X= 17+ 3* I:Y= 4:GOSUB 7010:NEXT I:PLOT 15,3,43,5
580 PRINT NP(PL);" POSITIONS":Q= NC(PL)^ NP(PL):PLOT 15
590 PLOT 3,40,7:PRINT "FOR";INT (Q);" COMBINATIONS"
600 PLOT 14,3,48,13,6,4:PRINT "STATISTICS"
610 PLOT 15,3,50,15:PRINT "LAST   AVERAGE"
620 PLOT 3,39,16:PRINT "PLAYER     SCORE   SCORE"
630 FOR I= P1TO P2:J= I:IF P1= 0THEN J= J+ 1
640 A$= "  "+ STR$ (TM(I)):PLOT 3,50,J* 2+ 16,6,1
650 PRINT MID$ (A$,LEN (A$)- 3):PLOT 3,37,J* 2+ 16,6,4
660 PRINT N$(I):A$= "   "+ STR$ (INT (AS(I)))
670 PLOT 3,58,J* 2+ 16,6,3:PRINT MID$ (A$,LEN (A$)- 3):NEXT I
675 PLOT 3,38,31:PRINT "HIT ''HOME'' KEY TO QUIT";
680 ON C(PL)GOSUB 1010,1020,1070:G= 0:TM(PL)= 0
690 G= G+ 1:PLOT 3,0,G* 2+ 7:PRINT "GUESS NO";G;"":PLOT 3,64,0
695 IF G= 11THEN PLOT 3,35,29:PRINT "LAST CHANCE !":PLOT 3,64,0
700 T= FN T(G):IF PL= 0THEN GOSUB 2010:GOTO 760
705 IF G> 1THEN R(NP(PL)+ 1,G- 1)= R:R(NP(PL)+ 2,G- 1)= M
708 K1= 80:IF C(PL)= 2AND G> 1THEN K1= 79:PLOT 3,0,7:PRINT "TYPE O TO GIVE UP"
710 K2= 79+ NC(PL):POKE 33278,0:FOR I= 1TO NP(PL)
720 GOSUB 7240:IF K= 26THEN I= I- 2:Y= 6+ 2* G:GOSUB 205:NEXT I
730 IF K= 28THEN K= 80+ A(I):CH= CH+ 1
735 IF K= 79THEN CH= NP(PL):GOTO 840
740 C= K- 80:G(I)= C:X= 8+ 3* I:Y= 6+ 2* G:GOSUB 7010
750 R(I,G)= G(I):NEXT I
760 TM(PL)= TM(PL)+ INT ((FN T(G)- T)* (G- 1)/ G)
765 IF DD= 5THEN TM(PL)= INT (AS(PL)):DD= 1:GOTO 540
770 ON C(PL)GOSUB 3010,3120,3010:GOSUB 3060
775 IF G< > 11AND R< > NP(PL)GOTO 690
780 IF C(PL)= 2THEN GOSUB 3300:IF DD= 5GOTO 765
785 IF CH> 0THEN CH= CH* NP(PL)* NC(PL)/ (G^ 2)
790 IF CH> 0THEN TM(PL)= INT (TM(PL)+ CH+ AS(PL)):CH= 0
795 TM(PL)= TM(PL)+ 2* G:Y= 6+ 2* G
800 AS(PL)= (AS(PL)* (RD- 1)+ TM(PL))/ RD
810 FOR I= 1TO NP(PL):C= G(I)+ 64:X= 8+ 3* I:GOSUB 7010:NEXT I
820 PLOT 3,43,10:PRINT "SCORING";TM(PL);" POINTS":PLOT 3,64,0
825 IF Z= 1THEN Z= 0:PLOT 3,5,27:INPUT "HIT RETURN TO CONTINUE ... ";Z$
830 FOR I= 1TO 3000:NEXT I:IF PEEK (33278)= 8THEN RUN 100
833 GOTO 505
840 TM(PL)= TM(PL)+ INT ((FN T(G)- T)* (G- 1)/ G)
850 GOSUB 3310:IF DD= 5GOTO 765
860 GOTO 785
1000 REM  
1010 Y= 29:FOR I= 1TO NP(PL):A(I)= FN R(NC(PL)):IF ZK= 1THEN C= A(I):X= 8+ I* 3:GOSUB 7010
1015 NEXT :RETURN
1020 PLOT 3,1,9:PRINT "THINK OF A CODE OF";NP(PL);" POSITIONS"
1025 PLOT 3,9,7:PRINT "O K  ";N$(PL+ 1);""
1030 PLOT 3,1,11:PRINT "USING THE";NC(PL);" COLORS SHOWN ABOVE"
1040 PLOT 3,5,15,6,1:PRINT "HIT RETURN WHEN READY";
1050 K1= 13:K2= 13:GOSUB 7230:FOR I= 7TO 15:PLOT 3,0,I
1060 PRINT SPC( 31)" ":NEXT I:RETURN
1070 PLOT 3,1,9:PRINT "ENTER A CODE OF";NP(PL);" POSITIONS"
1075 POKE 33278,0
1080 PLOT 3,1,11:PRINT "USING THE";NC(PL);" COLORS SHOWN ABOVE"
1090 Y= 0:K1= 80:K2= 79+ NC(PL):FOR I= 1TO NP(PL):GOSUB 7240
1095 C= K- 80:X= 8+ I* 3:Y= 29:GOSUB 7010
1100 A(I)= K- 80:PLOT 3,0,11,11:PRINT "NOW POSITION";I+ 1
1110 NEXT I:PLOT 3,0,11,11,28,28,11:RETURN
2000 REM
2010 IF G= 1GOTO 2320
2020 R(NP(0)+ 1,G- 1)= R:DD= 1
2030 R(NP(0)+ 2,G- 1)= M:IF R< > 0GOTO 2080
2040 FOR I= 1TO NP(0):T(0,G(I),I)= - 1:NEXT I
2050 DD= 2:IF M< > 0GOTO 2080
2060 FOR I= 1TO NP(0):FOR J= 1TO NP(0)
2070 T(0,G(J),I)= - 1:NEXT J,I
2080 IF R+ M< > NP(0)OR V< > 0GOTO 2120
2090 DD= 2:V= 3:FOR I= 0TO NC(0)- 1:FOR J= 1TO NP(0)
2100 IF R(J,G- 1)= ITHEN NEXT I:GOTO 2120
2110 NEXT J:FOR J= 1TO NP(0):T(0,I,J)= - 1:NEXT J,I
2120 IF G= 2OR DD= 2THEN P= 0:GOTO 2180
2125 II= 0:FOR I= 0TO T(1,NC(0),P)- 1
2130 IF T(1,I,P)= G(P)THEN T(1,I,P)= - 1
2140 IF T(1,I,P)> - 1THEN T(1,II,P)= T(1,I,P):II= II+ 1
2150 NEXT I:IF II> 0GOTO 2220
2155 IF PEEK (33278)= 8THEN RUN 100
2160 P= P- 1:IF P> 1GOTO 2125
2170 II= 0:GOTO 2190
2180 P= P+ 1:G(P)= 9:II= 0
2190 FOR I= 0TO NC(0)- 1:IF T(0,I,P)= G(P)THEN T(0,I,P)= - 1
2200 IF T(0,I,P)> - 1THEN T(1,II,P)= T(0,I,P):II= II+ 1
2210 NEXT I:IF II= 0THEN DD= 1:GOTO 2340
2220 T(1,NC(0),P)= II:Q= FN R(II):G(P)= T(1,Q,P):IF ZK= 1THEN C= G(P):X= 8+ P* 3:Y= 6+ G* 2:GOSUB 7010
2230 IF P= 1GOTO 2180
2240 FOR J= P+ 1TO NP(0):G(J)= 9:NEXT J:L= NP(0)- P
2250 FOR K= G- 1TO 1STEP - 1:FOR I= 1TO NP(0)
2255 P(I)= R(I,K):NEXT I:M= 0:R= 0:GOSUB 3020
2260 IF R> R(NP(0)+ 1,K)OR R< R(NP(0)+ 1,K)- LGOTO 2125
2270 IF R+ M> R(NP(0)+ 1,K)+ R(NP(0)+ 2,K)GOTO 2125
2280 IF R+ M< R(NP(0)+ 1,K)+ R(NP(0)+ 2,K)- LGOTO 2125
2290 NEXT K:IF P< > NP(0)GOTO 2180
2300 FOR I= 1TO NP(0):C= G(I):R(I,G)= C:X= 8+ 3* I
2310 Y= 6+ G* 2:GOSUB 7010:NEXT I:RETURN
2320 V= 0:FOR I= 1TO NP(0):G(I)= FN R(NC(0))
2330 FOR J= 0TO NC(0):T(0,J,I)= J:NEXT J,I:GOTO 2300
2340 PLOT 3,13,7+ 2* G:PRINT "I GIVE UP":GOSUB 3310:RETURN
3000 REM
3010 FOR I= 1TO NP(PL):P(I)= A(I):NEXT I:M= 0:R= 0
3020 FOR I= 1TO NP(PL):IF P(I)= G(I)THEN M= M- 1:R= R+ 1
3030 NEXT I:FOR I= 1TO NP(PL):FOR J= 1TO NP(PL)
3040 IF G(I)= P(J)THEN M= M+ 1:P(J)= 10:NEXT I:RETURN
3050 NEXT J,I:RETURN
3060 IF R< > 0THEN C= 7:F= 100:FOR I= 1TO R:GOSUB 3080:NEXT I
3070 IF M= 0THEN RETURN
3075 C= 3:F= 79:FOR I= R+ 1TO R+ M:GOSUB 3080:NEXT I:RETURN
3080 PLOT 3,28+ I,7+ 2* G,6,C,F,3,64,0:RETURN
3090 IF M= 0THEN RETURN
3100 FOR I= 1TO M
3110 PLOT 3,28+ I,7+ 2* G,6,3,79,3,64,0:NEXT I:RETURN
3115 PLOT 3,28,7+ 2* G,32,32,32,32,32,32
3120 M= 0:R= 0:K1= 48:K2= 48+ NP(PL):PLOT 6,5,3,29,7+ 2* G,63
3130 GOSUB 7230:R= K- 48:IF R= NP(PL)THEN RETURN
3135 GOSUB 3060:K2= K2- R:PLOT 6,3,3,29+ R
3140 PLOT 7+ 2* G,63:GOSUB 7230:IF K= 26OR K= 28GOTO 3115
3150 M= K- 48:PLOT 3,29+ R,7+ 2* G,32:RETURN
3300 G= G+ 1:IF R= NP(PL)THEN G= G- 1:GOTO 3350
3310 PLOT 3,40,7:PRINT " ENTER CORRECT CODE    ":K1= 80
3320 K2= 79+ NC(PL):POKE 33278,0:FOR I= 1TO NP(PL):GOSUB 7240
3330 Y= 8:IF K= 26OR K= 28THEN I= I- 2:GOSUB 205:NEXT I
3340 C= K- 80:G(I)= C:X= 41+ 3* I:GOSUB 7010:NEXT I:GOTO 3360
3350 FOR I= 1TO NP(PL):G(I)= R(I,G):NEXT I:IF G= 1GOTO 3460
3360 FOR K= G- 1TO 1STEP - 1:FOR I= 1TO NP(PL)
3370 P(I)= R(I,K):NEXT I:M= 0:R= 0:GOSUB 3020
3380 IF R= R(NP(PL)+ 1,K)AND M= R(NP(PL)+ 2,K)GOTO 3450
3390 IF DD< > 5THEN GOSUB 3500
3400 DD= 5:PLOT 3,35,7+ 2* K,6,69,60,103,103,6,5,3,64,0
3450 NEXT K
3460 IF DD= 5THEN K1= 8:K2= 127:GOSUB 7230
3470 RETURN
3500 FOR I= 12TO 29:PLOT 3,35,I:PRINT SPC( 28);" ":NEXT I
3510 PLOT 3,35,30:PRINT SPC( 27);" "
3520 RESTORE 8010:GOSUB 8000:A$= "YOU "+ B$
3530 RESTORE 8110:GOSUB 8000:A$= A$+ B$
3540 PLOT 3,47,13,6,3:PRINT N$(PL+ 1):PLOT 3,42,15:PRINT A$
3550 PLOT 3,40,18,6,6:PRINT "NO SCORE.  SO WHEN YOUR"
3560 PLOT 3,40,20:PRINT "READY HIT ANY KEY AND"
3570 PLOT 3,40,22:PRINT "WE'LL TRY THIS AGAIN."
3580 RETURN
4000 REM
4005 PLOT 12,10,10,10,10
4010 PRINT "     '' MASTER MIND II '' IS A GAME OF LOGIC AND";
4011 PRINT " A BATTLE OF    "
4012 PRINT "WITS.  A STANDARD MASTER MIND GAME WILL HAVE A 4 ";
4013 PRINT "POSITION CODE  "
4014 PRINT "OF 6 POSSIBLE COLORS.  ONE PLAYER AS CODEMAKER PI";
4015 PRINT "CKS & ARRANGES "
4016 PRINT "4 OF THE 6 AVAILABLE COLORS INTO ANY DESIRED ORDE";
4017 PRINT "R.  IT THEN    "
4018 PRINT "BECOMES THE TASK OF THE OTHER PLAYER AS CODEBREAK";
4019 PRINT "ER TO GUESS    "
4020 PRINT "THE SECRET CODE.  EACH TIME THE CODEBREAKER MAKES";
4021 PRINT " A GUESS, THE  "
4022 PRINT "CODEMAKER RESPONDS BY INFORMING HOW MANY COLORS A";
4023 PRINT "RE IN THE      "
4024 PRINT "CORRECT POSITIONS AND HOW MANY OTHER COLORS ARE R";
4025 PRINT "IGHT BUT IN THE"
4026 PRINT "WRONG PLACE.  THE CODEBREAKER USES THESE CLUES AN";
4027 PRINT "D CONTINUES TO "
4028 PRINT "MAKE GUESSES UNTIL THE PROPER COLORS ARE IN THE E";
4029 PRINT "XACT ORDER TO  "
4030 PRINT "MATCH THE SECRET CODE.":PRINT :PRINT :PRINT
4031 PRINT TAB( 30);:INPUT "HIT RETURN TO CONTINUE";U
4035 PLOT 12,10,10,10
4040 PRINT "     FOR EXAMPLE, ASSUME THE CODEMAKER SELECTS A ";
4041 PRINT "SECRET CODE OF "
4042 PRINT "4 POSITIONS AS FOLLOWS:"
4043 PLOT 3,25,5,29,17,118,119,26,28,26,116
4044 PLOT 117,25,10,29,18,118,119,26,28,26,116,117,25,10,29,20
4045 PLOT 118,119,26,28,26,116,117,25,10,29,21,118,119,26,28
4046 PLOT 26,116,117,10,10,29,23:PRINT
4050 PRINT "THE CODEBREAKER THEN MAKES A GUESS BY PRESSING TH";
4051 PRINT "E COLORED KEYS.":PRINT "POSSIBLY A CHOICE AS FO";
4052 PRINT "LLOWS:":PLOT 3,33,9,29,18,118,119,26,28,26,116
4053 PLOT 117,25,10,29,23,30,16,118,119,26,28,26,116,117,25
4054 PLOT 10,29,19,118,119,26,28,26,116,117,25,10,29,21,118,119
4055 PLOT 26,28,26,116,117,25,25,29,23,10,100,19,79:PRINT
4057 PLOT 10,6,7:PRINT "     THE CODEMAKER RESPONDS TO GUESSE";
4058 PRINT "S WITH SYMBOLS ( d $ O ).  "
4059 PRINT "WHEN THE ? APPEARS, PRESS (1) FOR ONE DIAMOND AND";
4060 PRINT "(1) FOR ONE O. "
4062 PRINT "THE SYMBOL  d  INDICATES A CORRECT COLOR IN THE R";
4063 PRINT "IGHT PLACE IN  "
4064 PRINT "RESPONSE TO THE ( MAGENTA ).  THE SYMBOL  O  INDI";
4065 PRINT "CATES A CORRECT"
4066 PRINT "COLOR BUT IN THE WRONG PLACE IN RESPONSE TO THE (";
4067 PRINT " GREEN ).      ":PRINT
4070 PRINT "    NOTE - A SINGLE COLOR MAY BE USED MORE THAN O";
4071 PRINT "NCE IN THE SAME"
4072 PRINT "HIDDEN CODE SUCH THAT:  ";:FOR I= 1TO 3
4073 PLOT 25,29,17,118,119,26,28,26,116,117,10:NEXT I
4074 PLOT 25,29,23,118,119,26,28,26,116,117,10,25,25,25
4075 PRINT "IS A LEGAL CODE."
4100 PRINT :PRINT :PRINT :PRINT TAB( 13);
4110 INPUT "HIT RETURN TO CONTINUE INSTRUCTIONS";U
4115 PLOT 12,10,10,10,10,10
4120 PRINT "     '' MASTER MIND II '' IS UNIQUE IN THAT IT HA";
4121 PRINT "S A SCORING    "
4122 PRINT "SYSTEM WHICH IS BASED ON TIME AND NUMBER OF GUESS";
4123 PRINT "ES.  THE OBJECT"
4124 PRINT "IS TO KEEP YOUR SCORE AS LOW AS POSSIBLE.  THE MO";
4125 PRINT "RE TIME USED   "
4126 PRINT "THE HIGHER YOUR SCORE.  THE MORE GUESSES USED ALS";
4127 PRINT "O INCREASES THE"
4128 PRINT "TOTAL.":PRINT
4150 PRINT "     IF I KNOW THE CODE AND YOU WANT TO PEEK PRES";
4152 PRINT "S THE UP ARROW "
4154 PRINT "AND I'LL HELP YOU!!!  IF YOU WISH TO CHANGE YOUR ";
4156 PRINT "GUESS PRESS THE"
4158 PRINT "BACK ARROW.  OTHER INSTRUCTIONS WILL BE PROVIDED ";
4160 PRINT "AS REQUIRED.   "
4165 PRINT TAB( 25)"GOOD LUCK !"
4490 PRINT :PRINT :PRINT :PRINT TAB( 25);
4495 INPUT "HIT RETURN TO PLAY";U
4500 GOTO 110
7010 F= 29:IF C= 0OR C= 64THEN C= C+ 7:F= 30
7015 PLOT 15,3,127,X,Y,C,F,116,117,3,127,X,Y+ 1,C,F,118,119
7020 PLOT 27,27,6,2,29,3,64,0:RETURN
7030 Y= 0:FOR I= 0TO 15:X= I* 3:IF X> 22THEN X= X+ 17
7040 C= FN R(8):GOSUB 7010:NEXT I
7050 PLOT 14,6,3,3,25,0:PRINT "MASTER MIND II":RETURN
7060 PLOT 15,6,6:PRINT TAB( 22)"SELECT MODE OF PLAY"
7070 PRINT :PRINT "     0 - INSTRUCTIONS"
7080 PRINT :PRINT :PRINT "          HUMAN VS HUMAN ( ALT. ";
7090 PRINT "PLAY FOR 2 TO 6 PLAYERS )"
7100 PRINT :PRINT "     1 - COMPUTER PICKS CODE & RESPONDS";
7110 PRINT " TO GUESSES"
7120 PRINT "     2 - HUMAN PICKS CODE & RESPONDS TO GUESSES"
7130 PRINT "     3 - HUMAN STORES CODE FOR QUICK ACCURATE ";
7140 PRINT "COMPUTER RESPONSES"
7150 PRINT :PRINT :PRINT "          HUMAN VS COMPUTER ";
7160 PRINT "( ONE ON ONE )"
7170 PRINT :PRINT "     4 - HUMAN GUESSES COMPUTER'S";
7180 PRINT " HIDDED CODE"
7190 PRINT "     5 - COMPUTER GUESSES HUMAN'S ";
7200 PRINT "HIDDEN CODE"
7210 PRINT "     6 - ALTERNATE PLAY OF MODE 4 & MODE 5"
7220 PRINT :PRINT :PRINT "     7 - COMPUTER PLAYS ITSELF"
7225 PRINT :PRINT "     8 - EXIT MASTER MIND II & RETU";
7226 PRINT "RN TO MENU PROGRAM"
7230 POKE 33278,0
7240 POKE 33247,31:Y= 0
7250 IF PEEK (33278)< > 0GOTO 7280
7260 C= FN R(8):X= FN R(16)* 3:IF X> 22THEN X= X+ 17
7270 GOSUB 7010:GOTO 7250
7280 K= PEEK (33278):POKE 33278,0:IF K= 28OR K= 26GOTO 7310
7290 IF K= 8THEN RUN 100
7300 IF K< K1OR K> K2GOTO 7250
7310 RETURN
8000 READ B:B= FN R(B)+ 1:FOR I= 1TO B:READ B$:NEXT I:RETURN
8010 DATA 4
8020 DATA "IGNORANT ","STUPID ","DUMB ","FOOLISH "
8110 DATA 5
8120 DATA "DONKEY","IDIOT","DIPSTICK","HUMANOID","NERD"
65000 TM= PEEK (32941)* 256+ PEEK (32940)- 7
65005 RESTORE 65005:DATA 245,175,50,255,129,241,201
65010 FOR J= 0TO 6:READ DA:POKE TM+ 1+ J,DA:NEXT
65015 BR= INT (TM/ 256):POKE 33221,195
65020 POKE 33222,TM- BR* 256+ 1:POKE 33223,BR
65025 POKE 32941,BR:POKE 32940,TM- BR* 256:RETURN