Compucolor.org – Virtual Media

Listing of file='HOMEL.BAS;01' on disk='vmedia/chip_39-sector.ccvf'

100 REM  FROM PUBLIC DOMAIN, SUBMITTED BY BUREN HUNTER
110 PLOT 12
120 PRINT TAB( 20);"H O M E  L I B R A R I A N"
130 PRINT :PRINT
140 PRINT "SERVICES AVAILABLE:   "
150 PRINT
160 PRINT TAB( 5);"LIST SUBJECT CLASSIFICATIONS........1"
170 PRINT
180 PRINT TAB( 5);"LIST BOOKS BY LOCATION..............2"
190 PRINT
200 PRINT TAB( 5);"LIST BOOKS BY SELECTED AUTHOR.......3"
210 PRINT
220 PRINT TAB( 5);"FIND SELECTED TITLE.................4"
230 PRINT
240 PRINT TAB( 5);"SEARCH FOR TITLE BY KEY WORD........5"
250 PRINT
260 PRINT TAB( 5);"NO FURTHER SERVICE DESIRED..........6"
270 PRINT :PRINT
280 INPUT " # OF SERVICE DESIRED.....?";N
290 IF N> 0AND N< 7THEN 310
300 PLOT 12:PRINT "SELECT A NUMBER FROM 1 TO 6":PRINT :GOTO 140
310 ON NGOTO 320,670,820,910,1020,1440
320 PLOT 12:PRINT "SUBJECT CLASSIFICATIONS:":PRINT
330 PRINT TAB( 5);"ARTS & CRAFTS......................1"
340 PRINT TAB( 5);"FICTION............................2"
350 PRINT TAB( 5);"HISTORY............................3"
360 PRINT TAB( 5);"MYSTERY............................4"
370 PRINT TAB( 5);"REFERENCE..........................5"
380 PRINT TAB( 5);"PHYSICS............................6"
390 PRINT TAB( 5);"CHEMISTRY..........................7"
400 PRINT TAB( 5);"ELECTRONICS........................8"
410 PRINT TAB( 5);"HAM RADIO..........................9"
420 PRINT TAB( 5);"PHOTOGRAPHY.......................10"
430 PRINT TAB( 5);"COMPUTERS.........................11"
440 PRINT TAB( 5);"GENERAL SCIENCE...................12"
450 PRINT TAB( 5);"GUNS & AMMO.......................13"
460 PRINT TAB( 5);"MATHEMATICS.......................14"
470 PRINT TAB( 5);"LEICA.............................15"
480 PRINT TAB( 5);"SECURITY & PROTECTION.............16"
490 PRINT TAB( 5);"SCIENCE FICTION...................17"
500 PRINT TAB( 5);"MEDICAL & HEALTH..................18"
510 PRINT TAB( 5);"FINANCIAL & INVESTMENTS...........19"
520 PRINT TAB( 5);"CATALOGS..........................20"
530 PRINT TAB( 5);"MISCELLANEOUS.....................21"
540 PRINT TAB( 5);"DOCUMENTARY.......................22"
550 PRINT :PRINT
560 PRINT "WOULD YOU LIKE TO SEE A LIST OF TITLES AVAILABLE"
570 INPUT "IN ONE OF THE ABOVE CLASSIFICATIONS ( Y/N )?  ";A$
580 IF LEFT$ (A$,1)= "N"THEN 110
590 PRINT :INPUT "ENTER CLASSIFICATION #...?";C1:PRINT
600 FOR X= 1TO 100
610 READ L,B,C,AN$,TL$
620 IF AN$= "LAST"THEN 660
630 IF C1< > CTHEN 650
640 GOSUB 1160
650 NEXT
655 PRINT
660 INPUT "ENTER 'C' TO CONTINUE";C$:RESTORE :GOTO 110
670 PLOT 12:PRINT "BOOK LOCATIONS:":PRINT
680 PRINT TAB( 5);"LIVING ROOM...................1"
690 PRINT TAB( 5);"FAMILY ROOM...................2"
700 PRINT TAB( 5);"STUDY.........................3"
710 PRINT TAB( 5);"PHOTO LAB.....................4"
720 PRINT TAB( 5);"WORKSHOP......................5"
730 PRINT TAB( 5);"ATTIC.........................6"
740 PRINT :INPUT "ENTER LOCATION # TO BE LISTED ";L1:PRINT
750 FOR X= 1TO 100
760 READ L,B,C,AN$,TL$
770 IF AN$= "LAST"THEN 810
780 IF L1< > LTHEN 800
790 GOSUB 1160
800 NEXT
810 INPUT "ENTER 'C' TO CONTINUE ";C$:RESTORE :GOTO 110
820 PLOT 12:INPUT "ENTER NAME OF AUTHOR...? ";NA$:PRINT
830 LN= LEN (NA$)
840 FOR X= 1TO 100
850 READ L,B,C,AN$,TL$
860 IF AN$= "LAST"THEN 900
870 IF LEFT$ (AN$,LN)< > NA$THEN 890
880 GOSUB 1160
890 NEXT
900 INPUT "ENTER 'C' TO CONTINUE ";C$:RESTORE :GOTO 110
910 PLOT 12:INPUT "ENTER DESIRED TITLE...? ";DT$:PRINT
920 FOR X= 1TO 100
930 READ L,B,C,AN$,TL$
940 IF AN$= "LAST"THEN 1000
950 IF TL$= DT$THEN 970
960 GOTO 990
970 GOSUB 1160
980 INPUT "ENTER 'C' TO CONTINUE ";C$:RESTORE :GOTO 110
990 NEXT
1000 PLOT 12:PRINT "NO EXACT MATCH FOUND. TRY KEY WORD"
1010 PRINT :PRINT :RESTORE
1020 INPUT "ENTER KEY WORD OF DESIRED TITLE ";KW$:PRINT
1030 RESTORE :LW= LEN (KW$)
1040 FOR X= 1TO 100
1050 READ L,B,C,AN$,TL$
1060 IF AN$= "LAST"THEN 1140
1070 FOR Y= 1TO LEN (TL$)+ 1- LW
1080 IF KW$= MID$ (TL$,Y,LW)THEN 1100
1090 NEXT Y:GOTO 1130
1100 GOSUB 1160
1110 INPUT "CONTINUE SEARCH ? ( Y/N ).... ";CS$
1120 IF LEFT$ (CS$,1)= "N"THEN 110
1130 NEXT
1140 PRINT "SEARCH COMPLETE"
1150 INPUT "ENTER 'C' TO CONTINUE ";C$:RESTORE :GOTO 110
1160 ON LGOTO 1170,1180,1190,1200,1210,1220,1230
1170 L$= "LIVING ROOM":GOTO 1240
1180 L$= "FAMILY ROOM":GOTO 1240
1190 L$= "STUDY":GOTO 1240
1200 L$= "PHOTO LAB":GOTO 1240
1210 L$= "WORKSHOP":GOTO 1240
1220 L$= "ATTIC":GOTO 1240
1230 L$= "INCORRECT":GOTO 1240
1240 PRINT "TITLE:   ";TL$
1250 PRINT "AUTHOR:   ";AN$
1260 PRINT "BOOK #   ";B;"   LOCATION IS:   ";L$
1270 PRINT :PRINT :RETURN
1280 DATA 1,1,5,POOR,"YOU AND THE LAW"
1290 DATA 1,2,3,LANG,"FROM HIROSHIMA TO THE MOON"
1300 DATA 1,3,2,THOMPSON,"NOT AS A STRANGER"
1310 DATA 2,4,2,POLLINI,"SOS AT MIDNIGHT"
1320 DATA 2,5,3,DICKSON,"TALES OF SAN FRANCISCO"
1330 DATA 2,6,2,BURDICK,"THE UGLY AMERICAN"
1340 DATA 5,7,13,HATCHER,"HATCHER'S NOTEBOOK"
1350 DATA 5,8,13,BAKER,"MODERN GUNSMITHING"
1360 DATA 4,9,7,MACDOUGAL,"PHYSICAL CHEMISTRY"
1370 DATA 4,10,10,CHAMPLIN,"CHAMPLIN ON FINEGRAIN"
1380 DATA 4,11,10,FOCAL,"DEVELOPING"
1390 DATA 3,12,15,KISSELBACH,"THE LEICA BOOK"
1400 DATA 3,13,9,COLLINS,"THE RADIO AMATEURS HANDBOOK"
1410 DATA 3,14,8,EASTMAN,"FUNDAMENTALS OF VACUUM TUBES"
1420 DATA 3,15,6,RESNICK,"PHYSICS II"
1430 DATA 6,16,15,HUNTER,"LEICA COLLECTORS MANUAL"
1440 DATA 1,1,1,LAST,NONE