Compucolor.org – Virtual Media

Listing of file='5P2.BAS;01' on disk='vmedia/color_graphics_2_suits-sector.ccvf'

5 REM  PROGRAM 5.2
6 REM  DEMO INTRODUCTION #2
10 GOSUB 100:REM  SET UP
20 GOSUB 200:REM  FILL THE SCREEN
30 GOSUB 300:REM  PRINT A BORDER AROUND THE SCREEN
40 GOSUB 400:REM  SET UP SPACE FOR THE TITLE
50 GOSUB 600:REM  PRINT THE TITLE
60 END
98
99 REM  SUBROUTINE TO SET UP
100 PLOT 15:REM  REGULAR HEIGHT
110 PLOT 6,2:REM  GREEN ON BLACK
120 PLOT 27,24:REM  PAGE MODE
130 RETURN
198
199 REM  SUBROUTINE TO FILL THE SCREEN
200 PLOT 27,25:REM  TEST MODE
210 PLOT 124:REM  SEE CHARACTER CHART, APPENDIX B
220 RETURN
298
299 REM  SUBROUTINE TO ADD A BORDER
300 PLOT 6,16:REM  BACKGROUND TO GREEN
310 PLOT 8,11:REM  HOME CURSOR & ERASE TOP LINE IN GREEN
320 PLOT 28,11:REM  CURSOR UP (=BOTTOM LINE) & ERASE LINE
330 PLOT 27,10:REM  VERTICAL MODE
340 GOSUB 390:REM  ERASE A COLUMN (32 LINES)
350 PLOT 26:REM  CURSOR LEFT (=RIGHT SIDE OF SCREEN)
360 GOSUB 390:REM  ERASE A COLUMN
370 PLOT 27,24:REM  BACK TO PAGE MODE
380 RETURN
388
389 REM  SUBROUTINE TO PRINT 32 SPACES IN VERTICAL MODE
390 FOR J= 1TO 32:PLOT 32:NEXT :RETURN
398
399 REM  SUBROUTINE TO SET UP SPACE FOR THE TITLE
400 PLOT 6,2:REM  GREEN ON BLACK
410 PLOT 30:REM  FLAG ON
420 PLOT 3,20,5:REM  POSITION CURSOR
430 PLOT 110:REM  TOP LEFT CORNER
440 FOR J= 1TO 24:PLOT 101:NEXT :REM  TOP
450 PLOT 111:REM  TOP RIGHT CORNER
460 PLOT 26,10,98:REM  BACK ONE & DOWN, THEN PRINT RIGHT SIDE
470 PLOT 3,20,6:REM  RE-POSITION CURSOR
480 PLOT 97,26,10:REM  LEFT SIDE;CURSOR BACK  & DOWN
490 PLOT 108:REM  BOTTOM LEFT CORNER
500 FOR J= 1TO 24:PLOT 127:NEXT :REM  BOTTOM
510 PLOT 109:REM  BOTTOM RIGHT CORNER
520 PLOT 29:REM  FLAG OFF FOR FUTIRE CONVENIENCE
530 RETURN
598
599 REM  SUBROUTINE TO PRINT THE TITLE
600 PLOT 6,3:REM  YELLOW ON BLACK
610 PLOT 3,21,6:REM  POSITION CURSOR
620 PRINT "ENGINEERING APPLICATIONS"
630 RETURN