Compucolor.org – Virtual Media

Listing of file='DECIDE.BAS;01' on disk='vmedia/ncc_4-sector.ccvf'

4 PLOT 12,14
5 REM  COMPUTER ASSISTED DECISION MAKING FOR THOSE WHO HATE TO MAKE DECISIONS
10 DIM S$(50)
12 PRINT "HI, DECIDE IS HERE TO HELP!"
15 A= 1:REM  LOWER LIMIT OF DECISION MATRIX
16 B= 20:REM  UPPER LIMIT OF DECISION MATRIX
20 RESTORE
30 FOR I= 1TO B
40 READ S$(I)
50 NEXT I
100 FOR I= 1TO 10:PRINT :NEXT I
110 INPUT "NEED A DECISION?  ";Q$
120 A$= LEFT$ (Q$,1)
130 IF A$= "Y"THEN 170
140 IF A$= "N"THEN 500
150 PRINT "ANSWER YES OR NO, PLEASE"
160 GOTO 110
170 GOSUB 1000:REM  FLIP COIN
200 X= (B- A)* RND (1)+ A
210 X= INT (X+ .5)
225 PRINT :PRINT TAB( 10):FOR I= 1TO 20:PRINT :NEXT I
230 PRINT S$(X)
240 GOTO 100
490 REM  TERMINATE THIS SESSION
500 PRINT :PRINT "COME BACK ANYTIME YOU NEED A LITTLE HELP"
520 PRINT :PRINT "I AM "
699 REM  PRE-PROGRAMMED DECISIONS
700 DATA YES,NO,DEFINITELY,"DEFINITELY NOT"
710 DATA MAYBE,"I DON'T THINK SO",PROBABLY,UNLIKELY
720 DATA ALWAYS,NEVER,AFFIRMATIVE,NEGATORY
730 DATA "RUN IT UP THE FLAGPOLE AND SEE WHO SALUTES"
740 DATA "IT WILL NEVER WORK"
750 DATA "THE SOONER THE BETTER","TAKE A RAIN CHECK"
760 DATA YES,NO,"DO IT NOW",MANANA
800 END
1000 REM
1010 REM  FLIP COIN
1020 REM
1100 PLOT 12,15
1110 X= 60:Y= 30
1120 Z= 60:W= 30
1150 FOR I= 1TO 15
1160 X= X- 2:Y= Y- 2
1170 Z= Z- 2:W= W- 2
1180 IF Y= 0THEN GOSUB 3000
1190 GOSUB 2000:REM  CHANGE COLOR
1200 PLOT 3,X,Y+ 1,116,117
1210 PLOT 3,Z,W+ 2,118,119
1220 PLOT 12
1230 FOR J= 1TO 50:NEXT J
1240 NEXT I
1250 PLOT 14
1310 RETURN
1999 REM
2000 REM  CHANGE COLOR
2010 REM
2100 PLOT 29,19+ N
2110 N= N+ 3
2120 IF N= 6THEN N= 0
2210 RETURN
3000 REM
3010 REM  BRING COIN DOWN
3020 REM
3100 FOR K= 1TO 13
3110 Y= Y+ 2
3120 W= W+ 2
3130 GOSUB 2000:REM  CHANGE COLOR
3200 PLOT 3,X,Y+ 1,116,117
3210 PLOT 3,Z,W+ 2,118,119
3220 PLOT 12
3230 FOR L= 1TO 50:NEXT L
3240 NEXT K
3250 RETURN