Compucolor.org – Virtual Media

Listing of file='MENU.BAS;01' on disk='vmedia/ncc_4-sector.ccvf'

1 CLEAR 255
5 DIM F$(1),FINAM$(6),B$(1),H$(1),D$(52)
10 PLOT 29,14,6,2,12,27,11,3,8,0
20 PLOT 6,3:PRINT "C O M P U C O L O R   U S E R S   G R O U P ":PLOT 6,2
30 PRINT
35 PRINT "TYPE IN THE NUMBER OF THE PROGRAM YOU WANT ";
40 PRINT "FROM THE MENU BELOW."
50 PRINT
70 PRINT "2 - CATALOG: ALL PROGRAMS BY NUMBER"
80 PRINT "3 -          BY CATEGORY"
90 PRINT "4 - LISTING: PRINT"
100 PRINT "5 -          CHANGE"
110 PRINT "6 -          ADD"
120 PRINT "7 - ADD PROGRAM & LISTING TO LIBRARY DISK (2 DRIVES)"
140 PRINT "8 - PREPARE PROGRAM FOR SUBMISSION TO LIBRARY"
142 PRINT "9 - EXIT FROM CATALOG MAINTENANCE PROGRAM"
145 PRINT
150 PLOT 6,1
153 INPUT "MENU SELECTION (TYPE NUMBER AND HIT RETURN KEY): ";P
156 PLOT 6,2,15,12
200 ON PGOTO 1,2000,3000,4000,5000,6000,7000,1000,8000
1000 REM  SET UP FILE OF PROGRAMS TO BE DONATED
1100 PLOT 12
1110 PRINT "PROCEDURE:"
1120 PRINT "(1) INPUT NUMBER OF PROGRAMS TO BE DONATED ON DISKETTE."
1130 PRINT "(2) INPUT CATALOG INFORMATION AS REQUESTED BY PROGRAM."
1140 PRINT "(3) PROGRAM WILL CREAT DATA FILE AT END OF DISK."
1150 PRINT "(4) DISK # WILL BE ADDED AT MEETING.  LEAVE BLANK."
1155 PRINT "(5) LOAD PROGRAMS TO BE DONATED TO END OF DISK."
1160 PRINT
1170 INPUT "HOW MANY PROGRAMS ARE ON DISK TO BE DONATED? ";N1
1200 FILE "N","CATALG",N1+ 1,126,3
1210 FILE "R",1,"CATALG",1
1230 PUT 1,1,1;N1+ 1
1240 FILE "C",1
1250 FOR R= 2TO N1+ 1
1300 REM    PRINT SCREEN FORMAT
1350 GOSUB 8001
1400 REM    INPUT CATALOG INFORMATION
1450 GOSUB 9000
1500 NEXT R
1900 INPUT "RETURN TO MENU(Y/N)? ";ANS$
1950 IF ANS$= "Y"THEN GOTO 10
1975 PLOT 12
1999 END
2000 REM  PRINT CATALOG OF DISK
2100 FILE "R",1,"CATALG",1
2150 GET 1,1,1;EOF
2200 FOR R= 2TO EOF
2250 GET 1,R,1;N$[6]:GET 1,R,74;D$[50]
2300 PLOT 6,1:PRINT "#";R- 1;" ";N$;TAB( 12);
2350 PLOT 6,2:PRINT D$
2400 NEXT R
2425 PRINT :PLOT 6,3
2450 INPUT "DO YOU WANT TO LOAD ONE OF THESE PROGRAMS (Y/N)?";ANS$
2470 IF ANS$= "Y"THEN GOTO 2490
2480 FILE "C",1:RUN
2490 PRINT :PLOT 6,2
2500 INPUT "WHAT IS THE NUMBER OF THE PROGRAM?";PROG
2510 GET 1,PROG+ 1,1;N$[6]
2520 FILE "C",1
2530 LOAD N$:END
2999 END
3000 REM  PERFORM CATEGORY SEARCH OF CATALOG
3005 PLOT 12
3007 PRINT "OPTIONS: FINANCIAL"
3010 PRINT "         GAMES"
3020 PRINT "         DISPLAY GRAPHICS"
3030 PRINT "         SUBROUTINE"
3040 PRINT "         MATH/STATISTICS"
3042 PRINT "         ENGINEERING/SCIENCE"
3044 PRINT "         UTILITIES"
3046 PRINT "         TUTORIAL"
3048 PRINT "         OTHER"
3050 PRINT
3075 INPUT "TYPE FIRST LETTER OF CATEGORY TO BE SEARCHED: ";CATEG$
3090 PRINT
3100 FILE "R",1,"CATALG",1
3200 GET 1,1,1;EOF
3250 FOR R= 2TO EOF
3300 GET 1,R,41;TYPE$[1]
3350 IF ASC (TYPE$)< > ASC (CATEG$)THEN GOTO 3500
3375 GET 1,R,1;N$[6]:GET 1,R,74;D$[50]
3400 PLOT 6,1:PRINT "#";R- 1;" ";N$;TAB( 12);
3450 PLOT 6,2:PRINT D$
3500 NEXT R
3800 PRINT :PRINT
3850 PLOT 6,3
3900 INPUT "DO YOU WANT TO LOAD ONE OF THESE (Y/N)?";ANS$
3910 IF ANS$= "Y"THEN GOTO 3930
3920 FILE "C",1:RUN
3925 PRINT
3930 INPUT "WHAT IS THE NUMBER OF THE PROGRAM?";PROG
3940 GET 1,PROG+ 1,1;N$[6]
3950 FILE "C",1:LOAD N$
3975 PLOT 12
3999 END
4000 REM  SEARCH FOR PROGRAM BY NUMBER
4100 INPUT "WHAT PROGRAM NUMBER DO YOU WANT?";NUM
4150 NUM= NUM+ 1
4200 FILE "R",1,"CATALG",1
4300 GET 1,NUM,1;N$[6],K$[2],A$[24],DATE$[8],T$[12],M$[3]
4350 GET 1,NUM,56;S$[4],L$[5],F$[1],FINAM$[6],B$[1],H$[1],D$[50]
4375 FILE "C",1
4400 REM    PRINT CATALOG FORMAT
4450 GOSUB 8100
4500 REM    PRINT CATALOG INFORMATION
4510 PLOT 3,14,1:PRINT N$
4520 PLOT 3,52,1:PRINT K$
4530 PLOT 3,14,4:PRINT A$
4540 PLOT 3,45,4:PRINT DATE$
4550 PLOT 3,14,7:PRINT T$
4560 PLOT 3,47,7:PRINT M$
4570 PLOT 3,14,10:PRINT S$
4580 PLOT 3,39,10:PRINT L$
4590 PLOT 3,7,13:PRINT F$
4600 PLOT 3,40,13:PRINT FINAM$
4610 PLOT 3,7,16:PRINT B$
4620 PLOT 3,41,16:PRINT H$
4630 PLOT 3,13,19:PRINT D$
4640 PLOT 3,1,23
4900 PLOT 6,4:INPUT "DO YOU WANT TO LOAD THIS PROGRAM?";ANS$
4950 IF ANS$= "Y"THEN LOAD N$
4975 PLOT 6,2,12
4999 RUN
5000 REM  CHANGE A CATALOG LISTING
5100 INPUT "WHAT LISTING DO YOU WANT TO CHANGE? ";NUM
5200 REM    PRINT CATALOG FORMAT
5250 GOSUB 8001
5300 REM    INSERT INFORMATION IN CATALOG
5350 R= NUM+ 1:GOSUB 9000
5900 INPUT "RETURN TO MENU(Y/N)?";ANS$
5950 IF ANS$= "Y"THEN GOTO 10
5975 PLOT 12
5999 END
6000 REM  ADD PROGRAM LISTING TO LIBRARY DISK
6010 PLOT 12
6050 FILE "R",1,"CATALG",1
6060 GET 1,1,1;R
6070 FILE "C",1
6100 REM    PRINT SCREEN FORMAT
6150 GOSUB 8001
6200 REM    INPUT CATALOG INFORMATION
6250 R= R+ 1:GOSUB 9000
6300 FILE "R",1,"CATALG",1
6350 PUT 1,1,1;R
6400 FILE "C",1
6900 INPUT "RETURN TO MENU(Y/N)?";ANS$
6950 IF ANS$= "Y"THEN GOTO 10
6975 PLOT 12
6999 END
7000 REM  ADD PROGRAMS TO LIBRARY DISK
7100 PRINT "PROCEDURE:"
7110 PRINT "(1) PUT MEMBER'S DISK IN CD0: AND LIBRARY DISK IN CD1:"
7120 PRINT "(2) INPUT NUMBER OF LIBRARY DISKETTE."
7130 PRINT "(3) INPUT NUMBER OF PROGRAMS ON DISKETTE TO BE DONATED"
7150 PRINT "(4) PROGRAM WILL TRANSFER CATALOG INFORMATION FROM CD0: TO CD1:"
7155 PRINT "(5) SAVE PROGRAMS ON LIBRARY DISKETTE."
7160 PRINT
7200 INPUT "NUMBER OF CURRENT LIBRARY DISKETTE:  ";DISK$
7210 INPUT "NUMBER OF PROGRAMS IN DONOR'S CATALOG FILE:  ";TTL
7300 FOR R= 2TO TTL+ 1
7325 REM    SWITCH TO DRIVE 0 AND RETREIVE CATALOG INFORMATION
7350 PLOT 27,4:PRINT "DEV 0:"
7360 PLOT 27:PLOT 27
7375 FILE "R",1,"CATALG",1
7400 GET 1,R,1;N$[6],K$[2],A$[24],DATE$[8],T$[12],M$[2],S$[4]
7410 GET 1,R,59;L$[5],F$[1],FINAM$[6],B$[1],H$[1],D$[52]
7420 FILE "C",1
7430 REM    SWITCH TO DRIVE 1 AND INPUT CATALOG INFORMATION
7500 PLOT 27,4:PRINT "DEV 1:":PLOT 27,27
7505 FILE "R",1,"CATALG",1
7510 GET 1,1,1;EOF
7520 EOF= EOF+ 1
7530 PUT 1,EOF,1;N$[6],DISK$[2],A$[24],DATE$[8],T$[12],M$[2]
7540 PUT 1,EOF,55;S$[4],L$[5],F$[1],FINAM$[6],B$[1],H$[1],D$[52]
7550 PUT 1,1,1;EOF
7555 FILE "C",1
7560 NEXT R
7900 INPUT "RETURN TO CATALOG(Y/N)?";ANS$
7950 IF ANS$= "Y"THEN GOTO 10
7975 PLOT 12
8000 END
8001 REM  PRINT CATALOG FORMAT
8100 PLOT 6,6,12
8110 FOR Y= 127TO 51STEP - 12
8120 PLOT 2,0,Y,242,127,Y,255
8130 NEXT Y
8140 PLOT 2,0,127,242,0,40,127,40,127,127,255
8200 REM
8210 PLOT 3,1,1
8215 PRINT "PROGRAM NAME: "
8220 PLOT 3,45,1
8225 PRINT "DISK #: "
8230 PLOT 3,1,4
8235 PRINT "AUTHORS NAME: "
8240 PLOT 3,40,4
8245 PRINT "DATE: "
8250 PLOT 3,1,7
8255 PRINT "PROGRAM TYPE: "
8260 PLOT 3,30,7
8265 PRINT "MEMORY REQUIRED: "
8270 PLOT 3,1,10
8275 PRINT "PROGRAM SIZE: "
8280 PLOT 3,30,10
8285 PRINT "LANGUAGE: "
8290 PLOT 3,1,13
8295 PRINT "FILES? "
8300 PLOT 3,30,13
8305 PRINT "FILE NAME: "
8310 PLOT 3,1,16
8316 PRINT "BUGS? "
8320 PLOT 3,30,16
8325 PRINT "HARD COPY? "
8330 PLOT 3,1,19
8335 PRINT "DESCRIPTION: "
8340 PLOT 3,0,24
8400 PRINT "OPTIONS:"
8410 PRINT "PROGRAM NAME:  6 CHARACTERS"
8420 PRINT "AUTHORS NAME: 24 CHARACTERS"
8430 PRINT "LANGUAGE:      5 CHARACTERS"
8440 PRINT "DESCRIPTION:  52 CHARACTERS"
8450 PRINT "TYPE:FINANCE,GAME,DISPLAY,SUBROUTINE,MATH/STAT
8455 PRINT "     ENGR/SCIENCE,UTILITIES,TUTORIAL,OTHER"
8999 RETURN
9000 REM  INPUT CATALOG INFORMATION & PLACE IN FILE
9110 PLOT 3,14,1
9115 INPUT "";N$
9120 PLOT 3,52,1
9125 INPUT "";K$
9130 PLOT 3,14,4
9135 INPUT "";A$
9140 PLOT 3,45,4
9145 INPUT "";DATE$
9150 PLOT 3,14,7
9155 INPUT "";T$
9160 PLOT 3,47,7
9165 INPUT "";M$
9170 PLOT 3,14,10
9175 INPUT "";S$
9180 PLOT 3,39,10
9185 INPUT "";L$
9190 PLOT 3,7,13
9195 INPUT "";F$
9200 PLOT 3,40,13
9205 INPUT "";FINAM$
9210 PLOT 3,7,16
9215 INPUT "";B$
9220 PLOT 3,41,16
9225 INPUT "";H$
9230 PLOT 3,13,19
9235 INPUT "";D$
9300 REM    FILE#R DETERMINED BEFORE SUBROUTINE CALLED
9325 FILE "R",1,"CATALG",1
9350 PUT 1,R,1;N$[6],K$[2],A$[24],DATE$[8],T$[12],M$[3],S$[4]
9355 PUT 1,R,60;L$[5],F$[1],FINAM$[6],B$[1],H$[1],D$[52]
9360 FILE "C",1
9400 PLOT 3,1,23
9999 RETURN
10000 FILE "R",1,"CATALG",1
10100 PUT 1,1,1;6
10200 FILE "C",1
10299 END
10500 FILE "R",1,"CATALG",1
10505 GET 1,1,1;R:PRINT R
10510 FOR R= 2TO 10
10530 GET 1,R,70;D$[52]
10535 FILE "A",1,Q
10540 PRINT Q,D$
10550 NEXT