Compucolor.org – Virtual Media

Listing of file='CAMEL2.BAS;01' on disk='vmedia/ncc_7-sector.ccvf'

0 Y= PEEK (33209):IF Y= 0THEN 0
1 Y= RND (- Y)
5 REM  GRAPHIC MODE ADDED BY WILLIAM B. LEE
10 PLOT 12
20 PRINT TAB( 28);"CAMEL"
35 PRINT :PRINT :PRINT
110 PRINT "WOULD YOU LIKE INSTRUCTIONS";
120 INPUT D$
130 IF LEFT$ (D$,1)= "N"THEN 335
140 PRINT :PRINT "WELCOME TO CAMEL."
150 PRINT "THE OBJECT IS TO TRAVEL 200 MILES ACROSS THE GREAT GOBI DESERT."
160 PRINT "A TRIBE OF KNOCKED KNEED PIGMIES WILL BE CHASING YOU."
170 PRINT "YOU WILL BE ASKED FOR COMMANDS EVERY SO OFTEN."
280 PRINT "YOU HAVE ONE QUART OF WATER WHICH WILL LAST YOU SIX DRINKS."
290 PRINT "YOU HAVE RENEWED YOUR WATER SUPPLY COMPLETELY AT AN OASES."
300 PRINT "YOU GET HALF A QUART IF FOUND BY HELP."
310 PRINT "IF HELP DOES NOT FIND YOU AFTER COMMAND SIX, YOU LOSE."
320 PRINT :PRINT "GOOD LUCK AND GOOD CAMELING!!"
330 PRINT :PRINT "YOU ARE IN THE MIDDLE OF THE DESERT AT AN OASIS."
334 FOR I= 1TO 5000:NEXT I:PLOT 12
335 PLOT 12
336 GOSUB 2000
337 BL$= "                                                               "
340 IF C> 199THEN 1210
350 Z= Z- 1
353 PRINT
355 IF Z= 1THEN PRINT "WARNING --- GET A DRINK"
360 IF Z< 0THEN 1630
370 P= P+ 1
380 X2= INT (10* RND (1)+ 2.5)
390 IF Q> 0THEN 940
400 IF P< 4THEN 470
410 C1= C1+ X2
420 IF C1< CTHEN 460
422 FOR I= 1TO 500:NEXT I
425 PLOT 3,0,15:FOR I= 1TO 14:PRINT BL$:NEXT I:PLOT 3,0,15
430 PRINT :PRINT "THE PYGMIES HAVE CAPTURED YOU."
440 PRINT :PRINT "CAMEL AND PEOPLE SOUP IS THEIR FAVORITE DISH!!!!"
450 GOTO 1560
460 PLOT 3,0,2:PRINT :PRINT "THE PYGMIES ARE "C- C1;" MILES BEHIND YOU."
470 PLOT 3,0,0:PRINT "YOU HAVE TRAVELLED ";C;" MILES ALTOGETHER."
475 GOSUB 3000
480 PLOT 3,0,15:INPUT "WHAT IS YOUR COMMAND   ";Y
495 FOR I= 1TO 14:PRINT BL$:NEXT I
500 ON YGOTO 830,610,680,760,790
550 T= INT (10* RND (1))
560 IF T< > 1THEN 1200
570 PRINT :PRINT "HELP HAS FOUND YOU IN A STATE OF UNCONSCIOUSNESS."
580 S= 3
590 Z= 4
600 GOTO 340
610 F= F+ 1
620 IF F= 8THEN 1190
630 GOSUB 880
640 X1= INT (10* RND (1))
650 C= C+ X1
660 PLOT 3,0,17:PRINT "YOUR CAMEL LIKES THIS PLACE."
670 GOTO 340
680 F= F+ 3
690 IF F> 7THEN 1190
700 GOSUB 880
710 X1= 2* INT (10* RND (1))
720 C= C+ X1
725 PLOT 3,0,18
730 PRINT :PRINT "YOUR CAMEL IS BURNING ACROSS THE DESERT SANDS."
750 GOTO 340
760 PLOT 3,0,17:PRINT "YOUR CAMEL THANKS YOU!"
770 F= 0
780 GOTO 350
790 PLOT 3,0,17
795 PRINT :PRINT "YOUR CAMEL HAS ";7- F;" GOOD DAYS LEFT."
800 PRINT "YOU HAVE ";S;" DRINKS LEFT IN YOUR CANTEEN."
810 PRINT "YOU CAN GO ";Z;" COMMANDS WITHOUT A DRINKING."
830 S= S- 1
840 IF S< 0THEN 1200
850 PLOT 3,0,21:PRINT "BETTER WATCH FOR AN OASES!"
860 Z= 4
870 GOTO 480
880 A= INT (100* RND (1))
890 IF A> 5THEN 1120
895 PLOT 3,0,16
900 PRINT :PRINT "WILD BERBERS HIDDEN IN THE SAND HAVE CAPTURED YOU."
910 PRINT "LUCKY THE LOCAL SHEIK HAS AGREED TO THEIR RANSON DEMANDS."
920 PRINT :PRINT "BUT.....WATCH FOR THE PYGMIES!"
930 PRINT :PRINT "YOU HAVE A NEW CHOICE OF SUB-COMMANDS:"
940 PRINT :PRINT "#7 ATTEMPT AN ESCAPE"
950 PRINT "#8 WAIT FOR PAYMENT"
960 PRINT :PRINT "YOUR SUB-COMMAND";
970 INPUT X
980 IF X= 8THEN 1060
990 X1= INT (10* RND (1))
1000 IF X1< 5THEN 1035
1010 PRINT :PRINT "CONGRADULATIONS, YOU SUCCESSFULLY ESCAPED!!!!"
1020 Q= 0
1022 FOR I= 1TO 600:NEXT I
1025 PLOT 3,0,16:FOR I= 1TO 14:PRINT BL$:NEXT I:PLOT 3,0,17
1030 GOTO 340
1035 PLOT 3,0,16:FOR I= 1TO 14:PRINT BL$:NEXT I:PLOT 3,0,17
1040 PRINT :PRINT "YOU WERE MORTALLY WOUNDED BY A PIG STABBER WHILE ESCAPING."
1050 GOTO 1410
1060 PLOT 3,0,15:FOR I= 1TO 14:PRINT BL$:NEXT I:PLOT 3,0,16
1070 X1= INT (100* RND (1))
1080 IF X1> 24THEN 1100
1090 PRINT :PRINT "YOUR RANSON HAD BEEN PAID AND YOU ARE FREE TO GO."
1095 Q= 0
1096 GOTO 340
1100 PRINT :PRINT "THE LOCAL SULTAN IS COLLECTING....JUST WAIT....."
1110 GOTO 340
1120 A= INT (10* RND (1))
1130 IF A> 2THEN 1240
1135 PLOT 3,0,22
1140 PRINT :PRINT "YOU HAVE ARRIVED AT AN OASES."
1150 PRINT "YOUR CAMEL IS FILLING YOUR CANTEEN AND EATING FIGS."
1160 Z= 4
1170 S= 6
1180 RETURN
1190 PRINT "YOU DIRTY RAPSCALLION! YOU RAN YOUR POOR CAMEL TO DEATH!!"
1200 GOTO 1410
1210 PRINT :PRINT "YOU WIN-- A PARTY IS BEING GIVEN IN YOUR HONOR....."
1220 PRINT "....THE PYGMIES ARE PLANNING TO ATTEND...."
1230 GOTO 1560
1240 X1= INT (100* RND (1))
1250 IF X1> 5THEN 1350
1255 PLOT 3,0,15:FOR I= 1TO 14:PRINT BL$:PLOT 3,0,19
1260 PRINT :PRINT "YOU HAVE BEEN CAUGHT IN A SANDSTORM....GOOD LUCK!"
1270 X5= INT (10* RND (1))
1280 X6= INT (10* RND (1))
1290 IF X6< 5THEN 1320
1300 C= C+ X5
1310 GOTO 1330
1320 C= C- X5
1330 PRINT :PRINT "YOUR NEW POSITION IS ";C;" MILES SO FAR!"
1340 RETURN
1350 X1= INT (100* RND (1))
1360 IF X1> 5THEN RETURN
1370 C1= C1+ 1
1375 PLOT 3,0,24
1380 PRINT :PRINT "YOUR CAMEL HURT HIS HUMP."
1390 PRINT "LUCKILY THE PYGMIES WERE FOOTWEARY!!!"
1400 RETURN
1410 U= INT (10* RND (1))
1415 PLOT 3,0,16
1420 PRINT :PRINT "YOU DIED IN THE DESERT."
1430 IF U> 1THEN 1460
1440 PRINT :PRINT "THE NATIONAL CAMEL'S UNION IS NOT ATTENDING YOUR FUNERAL!!!"
1450 GOTO 1560
1460 IF U> 3THEN 1490
1470 PRINT :PRINT "YOUR BODY WAS EATEN BY VULTURES AND IMPORTED CANNINBALS!!!"
1480 GOTO 1560
1490 IF U> 5THEN 1520
1500 PRINT :PRINT "THE LOCAL SHEIK NOW USES YOUR SKULL FOR A CHANGE PURSE!!!"
1510 GOTO 1560
1520 IF U> 7THEN 1550
1530 PRINT :PRINT "PEOPLE WITH LITTLE INTELLIGENCE SHOULD STAY OUT OF THE DESERT."
1540 GOTO 1560
1550 PRINT :PRINT "TURKEYS SHOULD FLY, NOT RIDE CAMELS!!!!"
1560 PRINT
1570 PRINT
1580 PRINT "WANT A NEW CAMEL AND A NEW GAME";
1590 INPUT D$
1600 IF LEFT$ (D$,1)= "Y"THEN 335
1620 GOTO 1650
1630 PLOT 3,0,21:PRINT "YOU RAN OUT OF WATER....SORRY CHUM!!!"
1640 GOTO 1410
1650 PRINT "-----------"
1655 PRINT "  CHICKEN"
1657 PRINT "-----------"
1658 FOR  I= 1 TO  1000:NEXT
1659 LOAD  "MENU":RUN
1660 END
2000 Z= 4
2010 S= 6
2020 C= 0
2030 C1= 0
2040 Q= 0
2050 F= 0
2060 P= 0
2070 RETURN
3000 PLOT 3,0,7:PRINT "COMMANDS:"
3010 PRINT "#1 DRINK FROM YOUR CANTEEN"
3020 PRINT "#2 AHEAD MODERATE SPEED"
3030 PRINT "#3 AHEAD FULL SPEED"
3040 PRINT "#4 STOP FOR THE NIGHT"
3050 PRINT "#5 STATUS CHECK"
3060 PRINT "#6 HOPE FOR HELP"
3070 RETURN