Compucolor.org – Virtual Media

Listing of file='ADD.BAS;01' on disk='vmedia/nsw_ug_1-sideB-sector.ccvf'

5 REM  *** GLEN YOU CAN GET ADD, SUB, MULTIPLY, AND DIVIDE BY CHANGING CERTAIN LINES.
6 REM  *** IF YOU WANT I WILL MAIL THE LINE NUMBERS TO YOU??***
20 REM         MATH PRACTICE -*- MULTIPLICATION
30 REM  *********** DATA INITIALIZATION ********************
40 Y= 1
50 S= 1
60 M= 50
70 C0= 0
80 W0= 0
90 DIM R$(5)
100 DIM A(5)
110 DIM N1(5)
120 DIM N2(5)
130 DIM C(5)
140 PRINT "ENTER THE NUMBER OF DIGITS FOR THE PRACTICE NUMBERS"
150 INPUT S
160 PRINT "HOW MANY ITEMS SHALL I PRINT? (5,10,15,20,ETC...)"
170 INPUT M
180 PRINT
200 REM   **************  PROCESSING AREA *********************
210 FOR I= 1TO M/ 5
220 FOR J= 1TO 5
230 N1(J)= INT (RND (Y)* 10^ S)
240 N2(J)= INT (RND (Y)* 10^ S)
250 NEXT J
260 FOR J= 1TO 5
270 PRINT " ";
280 FOR K= 1TO S
290 IF N1(J)> = 10^ (S- K)THEN 330
300 IF (S- K)+ N1(J)= 0THEN 330
310 PRINT " ";
320 NEXT K
330 PRINT N1(J);TAB( J* 10);
340 NEXT J
350 PRINT
360 FOR J= 1TO 5
370 PRINT "+";
380 FOR K= 1TO S
390 IF N2(J)> = 10^ (S- K)THEN 430
400 IF (S- K)+ N2(J)= 0THEN 430
410 PRINT " ";
420 NEXT K
430 PRINT N2(J);TAB( J* 10)
440 NEXT J
450 PRINT
460 FOR J= 1TO 5
470 FOR K= 1TO S+ 3
480 PRINT " ";
490 NEXT K
500 PRINT TAB( J* 10);
510 NEXT J
520 FOR J= 1TO 5
530 PRINT
540 NEXT J
550 PRINT "ENTER THE ANSWERS, (WITH A  COMMA BETWEEN"
560 INPUT A(1),A(2),A(3),A(4),A(5)
570 REM   ***** PRINTS GROUP RESULTS *************
580 PRINT
590 PRINT "RESULTS OF THIS GROUP:"
600 PRINT
610 PRINT "ITEM";TAB( 7);"MINE"TAB( 14)"YOURS"TAB( 22)"RESULT"
620 PRINT "--------------------------------------"
630 FOR J= 1TO 5
640 C(J)= N1(J)+ N2(J)
650 IF C(J)< > A(J)THEN 690
660 R$(J)= "CORRECT"
670 C0= C0+ 1
680 GOTO 710
690 R$(J)= "*WRONG*"
700 W0= W0+ 1
710 PRINT J;"."TAB( 5)C(J)TAB( 14)A(J)TAB( 22)R$(J)
720 NEXT J
730 PRINT
740 PRINT
750 NEXT I
760 REM  ********** PROGRAM TERMINATION POINT ******************
770 PRINT
780 PRINT "**************************"
790 PRINT "      SCORE BOARD"
800 PRINT "**************************"
810 PRINT "QUESTIONS "TAB( 15)C0+ W0
820 PRINT
830 PRINT "NUMBER CORRECT"TAB( 20)C0
840 PRINT "NUMBER *WRONG*"TAB( 20)W0
850 PRINT
860 PRINT "YOUR SCORE IS  ";(C0/ (C0+ W0))* 100;"%"
870 PRINT "****************************"
880 PRINT
890 END