Compucolor.org – Virtual Media

Listing of file='PRICES.BAS;01' on disk='vmedia/stamp_price_lists-sector.ccvf'

20 REM  AUCTION PRICES - REALISED LISTING

50 CLEAR 1000
100 PLOT 12,14
110 DIM A(400),RE(300)
120 PRINT "P R I C E S  R E A L I S E D":PRINT :PRINT
130 INPUT "AUCTION NUMBER? ";AN:PRINT :PRINT
135 AN$= "A"+ STR$ (AN)
140 PRINT "CREATE,  UPDATE OR PRINT:"
150 INPUT CU$
170 IF LEFT$ (CU$,1)= "U"THEN 1000
180 IF LEFT$ (CU$,1)= "P"THEN  2000
185 PLOT 12,14
187 PRINT "NOW ENTER PRICES.    TYPE 0 TO END INPUT."
190 PRINT "LOT NO.  PRICE"
200 FOR I= 1TO 400
220 PRINT I;
240 INPUT PR
260 IF PR= 0THEN 500
280 A(I)= PR
300 NEXT I
500 PRINT "ANY CHANGES ";:INPUT AC$
550 IF LEFT$ (AC$,1)= "Y"THEN 1040
600 PRINT :PRINT "INPUT LOT NUMBERS STILL AVAILABLE FOR SALE"
610 PRINT "TYPE 0 WHEN COMPLETE":PRINT
620 FOR R= 1TO 300:INPUT SA
630 IF SA= 0THEN 800
640 RE(R)= SA
660 NEXT R
700 PRINT "IMMEDIATE PRINT";:INPUT IP$
720 IF IP$= "Y"THEN  F1= 1:GOTO 2040
800 SAVE "A.ARY"
820 SAVE "RE.ARY"
880 PRINT "ARRAYS 'A' AND 'RE' SAVED ON DISK"
900 GOTO 2040
1000 LOAD "A.ARY"
1020 LOAD "RE.ARY"
1040 PLOT 12:PRINT "UPDATE PRICES REALISED":PRINT
1050 PRINT "ENTER 0 WHEN COMPLETE"
1060 INPUT "LOT NUMBER: ";L
1070 IF L= 0THEN 600
1080 INPUT "PRICE REALISED: ";PR
1100 IF PR= OTHEN 600
1120 A(L)= PR
1140 GOTO 1060
2000 REM  READ IN ARRAYS FROM DISK
2005 LOAD "A.ARY":LOAD "RE.ARY"
2010 PRINT "ARRAYS LOADED"
2040 PRINT :INPUT "HOW MANY LOTS (TOTAL)? ";HL
2042 POKE  33289,80:REM  SET PRINT WIDTH TO 80
2045 INPUT "HOW MANY LOTS STILL AVAILABLE FOR SALE?: ";RL
2050 NL= 1+ INT (HL/ 4)
2052 INPUT "PRINT, SCREEN LIST, UPDATE OR END : ";PR$
2054 IF LEFT$ (PR$,1)= "P"THEN 2060
2055 IF LEFT$ (PR$,1)= "S"THEN 2066
2056 IF LEFT$ (PR$,1)= "U"THEN 1040
2058 END
2060 INPUT "ENTER BAUD RATE OF PRINTER (1 -7) : ";SP
2062 PLOT 14,27,18,SP,15
2064 GOSUB 9000
2066 PLOT  15:PRINT TAB( 15)"POSTAL SALE No.";AN;" PRICES REALISED":PRINT
2070 PRINT " LOT";TAB( 7)"$";TAB( 17)"LOT";TAB( 23)"$";TAB( 33)"LOT";TAB( 40)"$";TAB( 50)"LOT";TAB( 57)"$"
3000 FOR I= 1TO NL
3020 PRINT I;TAB( 6)A(I);TAB( 16)I+ NL;TAB( 22)A(I+ NL);TAB( 32)I+ 2* NL;TAB( 39)A(I+ 2* NL);TAB( 49)I+ 3* NL;TAB( 56)A(I+ 3* NL)
3060 NEXT I
3062 POKE  33289,62
3065 PRINT :PRINT :PRINT "THE FOLLOWING LOTS (0R DUPLICATES) ARE AVAILABLE AT THE PRICE ABOVE"
3070 PRINT :FOR R= 1TO RL:PRINT RE(R);:NEXT R:PRINT
3100 GOSUB 9500
4000 IF F1= 1THEN 800
5000 GOTO 2052
9000 TMP= PEEK (33265)
9010 PLOT 27,13
9020 RETURN
9500 POKE 33265,TMP
9510 RETURN
9999 END