Compucolor.org – Virtual Media

Listing of file='ROULET.BAS;01' on disk='vmedia/swarms-sector.ccvf'

100 REM ** ROULETTE - JAN 3, 79 - JESSEN **
110 PLOT 6,3,12,12,3,3,15,15,29
120 PRINT "tf tu pq {d ab tf tu a  tu {d    {d tu ab a  {e oe oe {e"
130 PLOT 3,3,16:PRINT "vi vw ab a  vw vi vw l vw a|    a| vw vw l l b  b  l"
140 PLOT 3,80,0
150 CLEAR 200
160 DIM C(38),Y(20),B(20),N(10),W(20)
170 C$= "GGRBRBRBRBRBBRBRBRBRRBRBRBRRBBBRBRBRBR"
180 FOR I= 1TO 38
190 IF MID$ (C$,I,1)= "G"THEN C(I)= 17
200 IF MID$ (C$,I,1)= "B"THEN C(I)= 3
210 IF MID$ (C$,I,1)= "R"THEN C(I)= 11
220 NEXT I
230 FOR I= 1TO 190:W= RND (- PEEK (33209)):NEXT
240 PLOT 6,34,12,15,27,4:PRINT "LOAD TABLE.DIS":PLOT 27,27
250 FOR I= 1TO 19:READ Y(I):W= RND (- PEEK (33209)):NEXT
260 REM

    ** PLACE BETS **

270 FOR I= 1TO 4:C= 48:GOSUB 860:IF S$= "S"THEN I= 4
280 NEXT I:IF S$= "S"THEN 460
290 FOR I= 5TO 10:C= 24:GOSUB 860:IF S$= "S"THEN I= 10
300 NEXT I:IF S$= "S"THEN 460
310 FOR I= 11TO 19:C= 60:PLOT 3,0,Y(I),6,65:PRINT "*";:PLOT 26
320 PLOT 6,C:INPUT "";B$
330 IF B$= "END"THEN PLOT 6,2,12,1
340 IF LEFT$ (B$,1)= "S"THEN I= 19:GOTO 460
350 E= I:B= INT (VAL (B$))
360 IF B$= "00"THEN B= - 1
370 IF B< - 1OR B> 36THEN B= - 99
380 N(I- 10)= B
390 PLOT 3,0,Y(I),6,C
400 C$= STR$ (B):IF B= - 99THEN C$= "        "
410 IF B= - 1THEN C$= " 00"
420 C$= C$+ "        ":PRINT MID$ (C$,2,7)
430 IF B< > - 99THEN GOSUB 860
440 IF S$= "S"THEN I= 19
450 NEXT I
460 REM

    ** SPIN THE WHEEL **

470 BK$= "N":GOSUB 980
480 FOR I= 1TO 29:V= INT (RND (1)* 38+ 1)- 2
490 V$= STR$ (V):IF V> - 1AND V< 10THEN V$= " "+ V$
500 IF V= - 1THEN V$= " 00"
510 V$= V$+ " "
520 PLOT 3,31,0,14,6,C(V+ 2):PRINT V$
530 NEXT I
540 PLOT 15:BK$= "Y":GOSUB 980
550 REM

    ** COLLECT BETS **

560 IF V< 1THEN GOTO 640
570 IF V/ 2< > INT (V/ 2)THEN W(1)= W(1)+ 2* B(1)
580 IF V/ 2= INT (V/ 2)THEN W(2)= W(2)+ 2* B(2)
590 IF C(V+ 2)= 11THEN W(3)= W(3)+ 2* B(3)
600 IF C(V+ 2)= 3THEN W(4)= W(4)+ 2* B(4)
610 IF (V+ 2)/ 3= INT ((V+ 2)/ 3)THEN W(5)= W(5)+ 3* B(5)
620 IF (V+ 1)/ 3= INT ((V+ 1)/ 3)THEN W(6)= W(6)+ 3* B(6)
630 IF V/ 3= INT (V/ 3)THEN W(7)= W(7)+ 3* B(7)
640 IF V< = 12THEN W(8)= W(8)+ 3* B(8)
650 IF V> 12AND V< 25THEN W(9)= W(9)+ 3* B(9)
660 IF V> 24THEN W(10)= W(10)+ 3* B(10)
670 FOR I= 11TO E
680 IF V= N(I- 10)THEN W(11)= W(11)+ B(I)* 37
690 NEXT I
700 REM

    ** PRINT RESULTS **

710 FOR I= 1TO 19:J= I:IF I> 11THEN J= 11
720 W(J)= W(J)- B(I):NEXT I
730 TW= 0
740 FOR I= 1TO 11:Y= Y(I):IF I= 11THEN Y= Y(I)- 1
750 PLOT 6,34,3,56,Y:PRINT W(I)
760 TW= TW+ W(I):NEXT I
770 PLOT 6,44,3,51,26,14:PRINT "        "
780 PLOT 3,51,26:PRINT TW:PLOT 15
790 REM

    ** INITILAZE VARIABLES **

800 FOR I= 1TO 2000:NEXT I
810 FOR I= 1TO 19:B(I)= 0
820 C= 48:IF I> 4THEN C= 24
830 X= 7:L= 6:IF I> 10THEN X= 0:L= 13:C= 60
840 PLOT 6,C,3,X,Y(I):PRINT SPC( L);"":NEXT I
850 S$= "N":GOTO 260
860 REM

     ** ENTER BET **

870 PLOT 3,7,Y(I),6,65:PRINT "*";:PLOT 26
880 PLOT 6,C:INPUT "";B$
890 IF B$= "END"THEN PLOT 6,2,12,1
900 IF LEFT$ (B$,1)= "S"THEN S$= "S":RETURN
910 B= INT (VAL (B$))
920 IF B< 0THEN B= 0
930 IF B> 500THEN B= 500
940 B(I)= B:PLOT 3,7,Y(I),6,C
950 C$= STR$ (B)+ "        "
960 IF B= 0THEN C$= "        "
970 PRINT MID$ (C$,2,6):RETURN
980 REM

     ** DISPLAY A NUMBER **

990 Y= INT ((V- 1)/ 3):X= V+ 3- 3* Y:X= 5* X+ 6:Y= Y* 2+ 5
1000 IF V= - 1THEN X= X- 3
1010 IF V= 0THEN X= X- 2
1020 C= C(V+ 2):C$= " ":IF BK$= "Y"THEN C= C+ 64:C$= "*"
1030 PLOT 3,X,Y,6,C
1040 IF V< 10AND V< > - 1THEN PRINT " ";
1050 V$= STR$ (V):IF V= - 1THEN V$= " 00"
1060 PRINT V$;" ";
1070 PLOT 6,C,3,X,Y:PRINT C$:PLOT 3,X+ 3,Y:PRINT C$
1080 RETURN
1090 DATA 7,8,9,10,13,14,15,16,17,18
1100 DATA 22,23,24,25,26,27,28,29,30