Compucolor.org – Virtual Media

Listing of file='SWARMS.BAS;01' on disk='vmedia/swarms-sector.ccvf'

100 REM  ADAPTED TO COMPUCOLOR BY WALTER DEGLER
110 REM  ORIGINAL VERSION BY RAND K. MILLER IN CREATIVE COMPUTING MAY/JUNE 1977
120 OUT 8,0:TM= 256* PEEK (32941)+ PEEK (32940)
130 Z= TM+ 8:AD= 33283:GOSUB 180:TM= TM+ 1
140 X= 0:Y= 21:H= 11:W= 42:C= 1
150 Z= 28672+ 128* Y+ X+ X:AD= TM+ 126:GOSUB 180
160 Z= 128- W- W:AD= TM+ 149:GOSUB 180:POKE TM+ 129,H- 1
170 POKE TM+ 131,W* (C+ 1):POKE TM+ 143,35* (1- C):GOTO 190
180 ZZ= INT (Z/ 256):POKE AD,Z- 256* ZZ:POKE AD+ 1,ZZ:RETURN
190 W= RND (- PEEK (33209))
200 CLEAR 200:OUT 8,0:PLOT 6,0,12,6,32,15:GOTO 570
210 PLOT 6,2,29:L= L+ 1:IF L= 31THEN ZZ= CALL (1):L= 30
220 PLOT 3,0,31:PRINT SPC( 10)"":GOSUB 230:PRINT SPC( 42)""
230 PLOT 3,0,L:RETURN
240 GOSUB 210:GOTO 210
250 M= M+ 1:PLOT 6,7,3,31,M:PRINT SPC( 31):PLOT 3,31,M:RETURN
260 IF R(A)= - 1THEN PRINT "RAD":GOTO 330
270 IF V(A)= - 1THEN PRINT "EVC":GOTO 330
280 IF U(A)= - 1THEN PRINT "EMP":GOTO 330
290 IF E(A)= 0THEN PRINT "   ":GOTO 330
300 IF E(A)> 0THEN Z= E(A):GOTO 320
310 Z= - U(A)
320 PRINT STR$ (Z);SPC( 3- LEN (STR$ (Z)))""
330 PLOT 15:RETURN
340 PLOT 6,15,14,3,37,16:PRINT "    ":PLOT 3,37,16:PRINT T:PLOT 15:RETURN
350 IF 0= FN C(A)THEN GOSUB 370:GOTO 390
360 GOSUB 480:GOTO 390
370 C= FN C(A):PLOT 6:PLOT B(C):PLOT 3:PLOT ASC (MID$ (Y$,A+ A- 1,1))- 32
380 PLOT ASC (MID$ (Y$,A+ A,1))- 32:Z= E(A):GOTO 260
390 PLOT 6,7:IF RTHEN RETURN
400 IF A= 0THEN PLOT 14,3,50,20:PRINT "TOTAL";:GOTO 440
410 SS= 21* INT ((A- 1)/ 7):TT= A+ 24- 7* INT ((A- 1)/ 7)
420 PLOT 3,SS,TT:PRINT SPC( 21)""
430 PLOT 3,SS+ 1,TT:PRINT ""A""SPC( 6- LEN (STR$ (A)));
440 B= C(A):M= 1:IF B> = 1E6THEN B= INT (B/ 1000+ .5)/ 1000:M= 2
450 PRINT SPC( 7- LEN (STR$ (B)));B""MID$ (" M",M,1)"  "
460 PLOT 15:RETURN
470 IF O= FN C(A)THEN 370
480 C= FN C(A):Z= A:GOSUB 530
490 PLOT 6:PLOT B(FN C(A)):PLOT 3:PLOT ASC (MID$ (X$,A+ A- 1,1))- 32
500 PLOT ASC (MID$ (X$,A+ A,1))- 32:PRINT STR$ (A);MID$ (" *",1- (G(A)< > 0),1):GOTO 370
510 FOR I= 1TO D7STEP 3:READ A7,B7,C7:PLOT 3,B7,A7:PRINT SPC( C7)""
520 NEXT :RETURN
530 PLOT 6:PLOT B(C):Y= ASC (MID$ (C$(Z),1,1))- 32:FOR I= 2TO LEN (C$(Z))STEP 2
540 PLOT 3:PLOT ASC (MID$ (C$(Z),I,1))- 32:PLOT Y:Y= Y+ 1
550 PRINT SPC( ASC (MID$ (C$(Z),I+ 1,1))- 32)""
560 NEXT :RETURN
570 DIM C$(21),B(5),E(21),S(21),U(21),G(21),M(21),D(21),C(21),V(21),K(21),R(21),QM(21)
580 MM= 0:NN= 19
590 DEF FN R(X)= INT (X* RND (1)+ 1)
600 DEF FN C(X)= (K(X)= 0)* ((S(X)> 0)+ (S(X)> 1)+ (S(X)> 4)+ (S(X)> 6))- 5* (K(X)> 0)+ (U(X)= - 1AND S(X)> 1)
610 DATA 2,3,38,1,53,5,6,10,29,5,43,10,7,3,8,10,10,29,9,38,15,14,8,38
620 DATA 13,45,8,18,28,4,18,46,4
630 DATA 2,3,9,2,10,13,2,17,13,2,24,14,2,31,17,2,38,13,5,45,11,15,46,4,15,49,4,5,52,9,2,57,2
640 DATA 11,4,1,12,5,1,13,6,1,14,7,1,16,25,1,17,26,1,18,27,1,3,41,1,4,42,1
650 DATA 4,50,1,3,51,1,2,52,1,7,53,1,6,54,1,5,55,1,4,56,1,14,50,1
660 D7= 33:PLOT 27,24:GOSUB 510
670 D7= 84:PLOT 27,10:GOSUB 510
680 PLOT 27,24
690 FOR I= 0TO 5:READ B(I):NEXT :DATA 7,49,16,24,15,40
700 FOR I= 1TO 21:READ C$(I):NEXT I
710 DATA "#$&$&$&$&","($&$&$&%%&$'#"
720 DATA "#+&+&+&","'+&+&+&","++&+&+&"
730 DATA "#2&2&2&","'2&2&2&","+2&2&2&"
740 DATA "#9&9&9&","'9&9&9&","+9&9&9&"
750 DATA "/9&:%;$","#@&@&@&","'@&@&@&"
760 DATA "+@&@&@&","#G"
770 DATA "*G&G&G&G&"," "
780 DATA "&N&N&N&","*N&N&N&",".N$N#O"
790 C$(16)= C$(16)+ CHR$ (34)+ "G#G$G&G&G&"
800 C$(18)= CHR$ (34)+ "U$T%S%U"+ CHR$ (34)+ "U!"
810 C$(21)= C$(21)+ CHR$ (34)+ "O"+ CHR$ (34)
820 X$= "$#$(+#+'++2#2'2+9#9'9+9/@#@'@+G%G*U"+ CHR$ (34)+ "N&N*N."
830 Y$= "$$$)+$+(+,2$2(2,9$9(9,:0@$@(@,G&G+U#N'N+N/"
840 FOR A= 1TO 21:GOSUB 490:NEXT A
850 PLOT 3:PLOT 4:PLOT 1
860 PRINT TAB( 6);"DISASTER CONTROL-OPERATION KILLER BEES"
870 FOR I= 0TO 5:READ A$:PLOT 3,55,7+ I+ I:PRINT A$:NEXT
880 DATA "DENSITY","     < 1","    1-10","   10-50","    > 50","    DEAD"
890 PLOT 6,15,3,8,16:PRINT SPC( 15)
900 PLOT 3,8,17:PRINT "  S W A R M S  "
910 PLOT 3,8,18:PRINT SPC( 15)
920 FOR I= 0TO 3:READ A$:PLOT 3,33,I+ 15:PRINT A$:NEXT
930 DATA " T       "," I       "," M       "," E       "
940 PLOT 6,6,2,253,0,127,242,127,127,127,48,0,48,0,127
950 PLOT 253,84,48,242,84,0
960 PLOT 255
970 T= 0:GOSUB 340
980 A= FN R(21)
990 B= FN R(21):IF A= BTHEN 990
1000 S(A)= FN R(5)+ 1:S(B)= FN R(5)+ 1:E(A)= FN R(9)+ 5:E(B)= FN R(9)+ 5
1010 GOSUB 2600:GOSUB 360:A= B:GOSUB 360
1020 L= 19:GOTO 1210
1030 GOSUB 360
1040 OUT 8,247:FOR A= 1TO 21:IF E(A)< > 0THEN 1060
1050 IF U(A)= 0THEN 1200
1060 IF S(A)= 1THEN 1200
1070 IF ABS (U(A))= 1THEN 1130
1080 IF ABS (E(A))= 1THEN 1100
1090 E(A)= E(A)- 1:C(A)= C(A)+ 17- E(A):GOTO 1180
1100 IF E(A)< 0THEN 1120
1110 GOSUB 210:PRINT "*BEES ARRIVE AT CITIES IN AREA"A:E(A)= - 1:U(A)= 6
1120 U(A)= U(A)- 1:GOTO 1190
1130 IF U(A)< 0THEN 1200
1140 GOSUB 210:PRINT "*BEES DESTROY CITIES IN AREA"A:U(A)= - 1:IF V(A)< > - 1THEN 1160
1150 GOSUB 210:PRINT "* BUT POPULATION EVACUATED":GOTO 1200
1160 K(A)= 1:C(A)= C(A)+ INT (1E6* (A* RND (1)+ 1))
1170 GOSUB 480
1180 GOSUB 390
1190 GOSUB 370
1200 NEXT A
1210 T= T+ 1:GOSUB 340:IF T< > 30* INT (T/ 30)THEN 1270
1220 AT= 1:FOR A= 1TO 21:IF S(A)= 0AND R(A)= 0AND K(A)= 0THEN QM(AT)= A:AT= AT+ 1
1230 NEXT A:IF AT> 1THEN A= FN R(AT):A= QM(A):GOTO 1250
1240 GOTO 1270
1250 S(A)= FN R(5)+ 1:E(A)= FN R(9)+ 15:C(A)= C(A)+ FN R(10)- 1:GOSUB 360
1260 GOSUB 210:PRINT "*NEW SWARMS REPTORTED IN AREA"A
1270 FOR A= 1TO 21:IF T< > G(A)THEN 1340
1280 IF S(A)< > 1THEN 1310
1290 R(A)= 0:V(A)= 0:S(A)= 0:E(A)= 0:K(A)= 0:U(A)= 0:G(A)= 0:M(A)= 0
1300 GOSUB 210:PRINT "*SWARMS IN AREA"A" DESTROYED":GOSUB 480:GOTO 1340
1310 O= FN C(A):S(A)= S(A)- M(A):GOSUB 210:PRINT "*PHASE IN AREA"A" SUCCESSFUL"
1320 IF S(A)< = 1THEN S(A)= 1:D(A)= 1:GOSUB 210:PRINT "*SWARMS IN AREA"A" DISPERSING"
1330 G(A)= 0:M(A)= 0:GOSUB 480
1340 NEXT A
1350 FOR A= 1TO 21:IF E(A)= 1OR S(A)= 0THEN 1490
1360 IF S(A)= 1THEN 1470
1370 IF S(A)< 8THEN 1460
1380 IF A= 1THEN 1430
1390 B= A- 1:IF S(B)> 0THEN 1430
1400 IF R(B)< > 0THEN 1430
1410 GOSUB 210:PRINT "SWARMS IN AREA"A:GOSUB 210:PRINT " SPREAD TO AREA"B
1420 S(B)= 3:E(B)= FN R(10)+ 4:A1= A:A= B:GOSUB 480:A= A1:GOTO 1490
1430 IF A= 21THEN 1490
1440 B= A+ 1:IF S(B)> 0OR R(B)< > 0THEN 1490
1450 GOTO 1410
1460 O= FN C(A):S(A)= S(A)+ 1:C(A)= C(A)+ S(A):GOSUB 350:GOTO 1490
1470 IF D(A)= 1THEN 1490
1480 GOSUB 210:PRINT "*SWARMS IN AREA"A" IS DISPERSING":D(A)= 1
1490 NEXT A
1500 B= 0:FOR A= 1TO 21:B= B+ S(A):NEXT A:IF B> 0THEN 1520
1510 GOSUB 210:PRINT "*ALL SWARMS DESTROYED*":FOR I= 1TO 1000:NEXT I:GOTO 3140
1520 FOR A= 1TO 21:IF V(A)< > TTHEN 1580
1530 IF U(A)< 0OR K(A)> 0THEN 1560
1540 GOSUB 210:PRINT "*POPULATION IN AREA"A" EVACUATED*":C(A)= C(A)+ FN R(17)- 1
1550 V(A)= - 1:GOSUB 360:GOTO 1580
1560 V(A)= 0:GOSUB 210:PRINT "*POPULATION IN AREA"A" DESTROYED"
1570 GOSUB 210:PRINT "*  BEFORE IT WAS EVACUATED"
1580 NEXT A
1590 FOR A= 1TO 21:IF R(A)< > TTHEN 1610
1600 V(A)= 0:K(A)= 0:R(A)= 0:GOSUB 210:PRINT "*POPULATION RETURNED IN AREA"A:GOSUB 360
1610 NEXT A
1620 GOSUB 2580
1630 B= 0:FOR A= 1TO 21:B= B+ C(A):NEXT A:IF B< 75E6THEN 1650
1640 GOSUB 210:PRINT "*U.S. DESTROYED *":FOR I= 1TO 1000:NEXT I:GOTO 3140
1650 GOSUB 240:OUT 8,255:PRINT "COMMAND:";:POKE 33278,0:AT= 0
1660 AT= AT+ 1:IF AT> 250THEN 1680
1670 PK= PEEK (33278):IF PK= 0THEN 1660
1680 PK= PK- 48:IF PK< 1OR PK> 5THEN OUT 8,247:GOTO 1040
1690 FOR X= 1TO 650:NEXT
1700 ON PKGOTO 1710,2090,2160,2430,3040
1710 GOSUB 210:PRINT "BATTLE PHASE OPTIONS"
1720 GOSUB 210:INPUT "AREA: ";A:IF A< 1OR A> 21THEN GOSUB 210:PRINT "  BAD AREA":GOTO 1040
1730 GOSUB 210:INPUT "PHASE: ";P
1740 IF V(A)> = 1THEN GOSUB 210:PRINT "AREA"A" BEING EVACUATED":GOTO 1030
1750 IF G(A)> 0THEN GOSUB 210:PRINT "ALREADY COMBATTING IN AREA"A:GOTO 1030
1760 IF S(A)= 0THEN GOSUB 210:PRINT "NO SWARMS REPORTED IN AREA"A:GOTO 1030
1770 IF S(A)< > 1THEN 1800
1780 IF P= 5THEN 1820
1790 GOSUB 210:PRINT "USE DESTRUCTION PHASE IN AREA"A:GOTO 1030
1800 IF E(A)= - 1AND P< > 6THEN GOSUB 210:PRINT "USE URBAN DEFENSES IN AREA"A:GOTO 1030
1810 IF E(A)< > - 1AND P= 6THEN GOSUB 210:PRINT "BEES NOT YET IN MAJOR CITIES":GOTO 1030
1820 N= RND (1):ON PGOTO 1840,1860,1880,1900,1920,1940
1830 GOSUB 210:PRINT "	INVALID BATTLE PHASE":GOSUB 2600:GOTO 1030
1840 GOSUB 210:PRINT "ATTEMPTING BEE COCKTAIL":IF N> .85THEN 1030
1850 G(A)= T+ FN R(3):M(A)= S(A)- 2+ 3* (S(A)> 5):GOTO 1030
1860 GOSUB 210:PRINT "ATTEMPTING PROJECT QUEEN":IF N> .82THEN 1030
1870 G(A)= T+ FN R(3)+ 3:M(A)= 1- (S(A)> 3)* (S(A)- 2):GOTO 1030
1880 GOSUB 210:PRINT "ATTEMPTING PROJECT BRUSH FIRE":IF N> .86THEN 1030
1890 G(A)= T+ 1:M(A)= 2:GOTO 1030
1900 GOSUB 210:PRINT "ATTEMPTING PROJECT STERILE MALE":IF N> .79THEN 1030
1910 G(A)= T+ FN R(3)+ 2:M(A)= 4- (S(A)< 7)* (S(A)- 5):GOTO 1030
1920 GOSUB 210:PRINT "ATTEMPTING DESTRUCTION PHASE":IF N> .6THEN 1030
1930 G(A)= T+ FN R(3)+ 1:GOTO 1030
1940 GOSUB 2760
1950 GOSUB 210:INPUT "URBAN DEFENSE: ";D$:GOSUB 2600:C(A)= C(A)+ FN R(200)- 1:IF RND (1)> .7THEN 1030
1960 IF ASC (D$)< 64THEN 1980
1970 ON ASC (D$)- 64GOTO 1990,2000,2010,2020,2030,2040,2050
1980 GOSUB 210:PRINT "INVALID URBAN DEFENSE":GOSUB 2600:GOTO 1030
1990 S(A)= 2- (S(A)< 6)* (S(A)- 3):GOTO 2060
2000 S(A)= S(A)- 3- (S(A)> 4):GOTO 2060
2010 S(A)= 1- (S(A)< 8)* (S(A)- 4):GOTO 2060
2020 S(A)= 1- (S(A)> 3)* (S(A)- 4):GOTO 2060
2030 S(A)= - 2* (RND (1)> .5):GOTO 2060
2040 S(A)= - (RND (1)< .4):GOTO 2060
2050 S(A)= - (S(A)- 4)* (RND (1)< .8)
2060 GOSUB 210:PRINT "URBAN DEFENSE IN AREA"A" A SUCCESS":IF S(A)> 1THEN GOSUB 360:GOTO 1030
2070 S(A)= 1:D(A)= 1:K(A)= 0
2080 GOSUB 210:PRINT "*SWARMS IN AREA"A" DISPERSING":GOSUB 360:GOTO 1030
2090 GOSUB 210:PRINT "EVACUATION PROCEDURE"
2100 GOSUB 210:INPUT "AREA: ";A:IF A< 1OR A> 21THEN GOSUB 210:PRINT "  BAD AREA":GOTO 1040
2110 IF S(A)= 0THEN GOSUB 210:PRINT "NO SWARMS REPORTED IN AREA"A:GOTO 1040
2120 IF V(A)> 0THEN GOSUB 210:PRINT "AREA"A" BEING EVACUATED":GOTO 1040
2130 IF V(A)= - 1THEN GOSUB 210:PRINT "AREA"A" ALREADY EVACUATED":GOTO 1040
2140 IF K(A)> 0OR U(A)< 0THEN GOSUB 210:PRINT "POPULATION IN AREA"A" DEAD":GOTO 1040
2150 GOSUB 210:PRINT "EVACUATION PROCEDURE IN PROGRESS":V(A)= T+ 5:GOTO 1030
2160 REM
2170 GOSUB 210:PRINT "NUCLEAR DESTRUCTION SEQUENCE"
2180 GOSUB 3130
2190 GOSUB 210:INPUT "AREA: ";A:IF A< 1OR A> 21THEN GOSUB 210:PRINT "  BAD AREA":GOTO 1040
2200 IF S(A)= 0THEN 2230
2210 IF E(A)= - 1THEN 2230
2220 GOSUB 210:PRINT "COMPUTER FAILSAFE":GOSUB 210:PRINT "SWARMS NOT IN MAJOR CITIES":GOTO 1040
2230 IF S(A)= 0THEN GOSUB 210:PRINT "COMPUTER FAILSAFE":GOSUB 210:PRINT "NO SWARMS IN AREA"A:GOTO 1040
2240 GOSUB 210:PRINT "BOMB IN AREA"A" ACTIVATED"
2250 IF K(A)> 0OR V(A)< 0OR U(A)= - 1THEN 2290
2260 GOSUB 210:PRINT "AREA"A" NOT EVACUATED"
2270 GOSUB 210:INPUT "ABORT ACTIVATION SEQUENCE? ";K$:IF LEFT$ (K$,1)= "N"THEN 2290
2280 GOSUB 210:PRINT "NUCLEAR DESTRUCTION SEQUENCE ABORTED":GOTO 1040
2290 GOSUB 210:PRINT "COUNTDOWN SEQUENCE":S= T
2300 FOR T= 10TO 0STEP - 1:FOR J= 1TO 100:NEXT J:GOSUB 340:NEXT T
2310 Z= A:FOR C= 4TO 0STEP - 1:GOSUB 530
2320 NEXT C:T= S:GOSUB 340
2330 GOSUB 210:PRINT "SWARMS DESTROYED, CITIES DESTROYED"
2340 C(A)= C(A)+ 2413:S(A)= 0:E(A)= 0:U(A)= 0:D(A)= 0:G(A)= 0:M(A)= 0
2350 IF K(A)= 1THEN 2400
2360 IF V(A)< > - 1THEN 2390
2370 GOSUB 210:PRINT "POPULATION WILL MOVE BACK TO AREA"A" WHEN"
2380 GOSUB 210:PRINT " RADIATION LEVELS ARE SAFER":K(A)= 2:R(A)= T+ 7:GOTO 1030
2390 C(A)= C(A)+ INT (2E6* (A* RND (1)+ 1))
2400 GOSUB 210:PRINT "*NO SURVIVORS IN AREA"A
2410 GOSUB 210:PRINT " BEES WILL NOT ENTER AREA"
2420 GOSUB 210:PRINT " WITH NO HUMAN INHABITANTS":K(A)= 2:R(A)= - 1:GOTO 1030
2430 GOSUB 2510
2440 PLOT 3,12,22
2450 INPUT "PRESS 'RETURN' TO CONTINUE";XX
2460 MM= 32:NN= 22
2470 FOR I= 20TO 31:PLOT 3,0,I:PRINT SPC( 63)"":NEXT
2480 PLOT 6,6,2,84,48,242,84,0,255
2490 L= 20:GOSUB 2600
2500 GOTO 1040
2510 FOR I= 20TO 22:PLOT 3,0,I:PRINT SPC( 63)"":NEXT
2520 R= 0:PLOT 3,10,21,30,14:PRINT "C A S U A L T Y   R E P O R T"
2530 PLOT 6,0,2,84,46,242,84,0,255,6,2,3,0,23,11
2540 PLOT 15:FOR I= 0TO 42STEP 21:PLOT 3,I,24:PRINT SPC( 21)""
2550 PLOT 3,I+ 1,24:PRINT "AREA  CASUALTIES":NEXT
2560 PLOT 15
2570 FOR A= 1TO 21:GOSUB 390:NEXT
2580 IF RTHEN RETURN
2590 B= 0:FOR A= 1TO 21:B= B+ C(A):NEXT :A= 0:C(0)= B:GOTO 390
2600 M= 20:R= 1:U= 43:PLOT 6,2
2610 GOSUB 3050
2620 PRINT "1)BATTLE PHASE OPT."
2630 GOSUB 3050
2640 PRINT " 1.BEE COCKTAIL"
2650 GOSUB 3050
2660 PRINT " 2.PROJ. QUEEN"
2670 GOSUB 3050
2680 PRINT " 3.PROJ. BRUSH FIRE"
2690 GOSUB 3050
2700 PRINT " 4.PROJ. STER. MALE"
2710 GOSUB 3050
2720 PRINT " 5.DESTRUCTION"
2730 GOSUB 3050
2740 PRINT " 6.URBAN DEFENSES"
2750 GOTO 2940
2760 M= 20:U= 43
2770 GOSUB 3050
2780 PRINT "URBAN DEFENSE OPT."
2790 GOSUB 3050
2800 PRINT " A.FLIGHT PATTERNS"
2810 GOSUB 3050
2820 PRINT " B.SONIC BOOM"
2830 GOSUB 3050
2840 PRINT " C.ULTRASONIC BEAMS"
2850 GOSUB 3050
2860 PRINT " D.POLLUTION"
2870 GOSUB 3050
2880 PRINT " E.METHYL PARATHION"
2890 GOSUB 3050
2900 PRINT " F.FIRE WALL"
2910 GOSUB 3050
2920 PRINT " G.STROBE LIGHT"
2930 FOR M= 29TO 31:PLOT 3,U,M:PRINT SPC( 20)"":NEXT M:RETURN
2940 M= 27:U= 43
2950 GOSUB 3050
2960 PRINT "2)EVACUATION PROC."
2970 GOSUB 3050
2980 PRINT "3)NUCLEAR DEST."
2990 GOSUB 3050
3000 PRINT "4)CASUALTY REPORT"
3010 GOSUB 3050
3020 PRINT "5)END PROJECT";:PLOT 8
3030 RETURN
3040 GOTO 3140
3050 M= M+ 1:PLOT 3,U,M:PRINT SPC( 20):PLOT 3,U,M:RETURN
3060 NN= NN+ 1:IF NN< 23THEN 3120
3070 NN= 20:MM= MM+ 32:IF MM< 64THEN 3120
3080 MM= 0
3090 GOSUB 3130
3100 PLOT 6,7
3110 FOR II= 0TO 2:PLOT 3,MM,NN+ II,11:NEXT
3120 RETURN
3130 FOR I= 1TO 800:NEXT I:RETURN
3140 GOSUB 2510:PLOT 6,6
3150 PLOT 3,12,22:OUT 8,255:INPUT "DO YOU WANT TO PLAY AGAIN? ";A$:IF LEFT$ (A$,1)= "Y"THEN 120
3160 PLOT 6,2,12,1