Compucolor.org – Virtual Media

Listing of file='CHVERS.BAS;01' on disk='vmedia/chip_13-sector.ccvf'

10 REM   CUVIC CUVIC CUVIC CUVIC CUVIC CUVIC CUVIC CUVIC
20 REM
30 REM    **********  CHANGE VERSION NUMBER **********
40 REM
50 REM    THIS PROGRAM WILL CHANGE THE VERSION NUMBERS ON THE
60 REM    DIRECTORY BY INCREASING ANY VERSION NUMBER BY ONE.
70 REM
80 REM   WRITTEN BY -  BRUCE MARSHALL
90 REM   COMPUCOLOR/INTECOLOR USERS GROUP VICTORIA
95 REM    P.O. BOX 420, CAMBERWELL, VICTORIA, AUSTRALIA, 3124
100 PLOT 12:GOSUB 400
110 CLEAR 100:PLOT 12
120 CY$= "`":KB= 33278:Y= 6:SC= 28672
130 PLOT 15,12,27,4:PRINT "DIR":PLOT 27,27
132 PLOT 3,49,4:PRINT "COMMANDS"
133 PLOT 3,45,7:PRINT "SPACE BAR - DOWN"
134 PLOT 3,45,9:PRINT "UP ARROW - UP"
135 PLOT 3,45,11:PRINT "RETURN - CHANGE"
136 PLOT 3,53,12:PRINT "VERSION NO."
137 PLOT 3,45,14:PRINT "F - FINISHED WITH"
138 PLOT 3,49,15:PRINT "THIS DISK"
139 PLOT 3,45,17:PRINT "Q - QUIT THE"
140 PLOT 3,49,18:PRINT "PROGRAM"
145 PLOT 3,0,Y:PRINT CY$:PLOT 3,0,Y
150 POKE KB,0
160 G= PEEK (KB):IF G= 0THEN 160
170 IF G= 32THEN Y= Y+ 1:GOTO 145
180 IF G= 28THEN PLOT 3,O,Y:PRINT " ":Y= Y- 1:GOTO 145
190 IF G= 70OR G= 102THEN 620
195 IF G= 81OR G= 113THEN PLOT 12:END
200 IF G< > 13THEN 145
210 AD= SC+ 128* Y
220 IF (PEEK (AD+ 2)< > 48OR PEEK (AD+ 4)< > 51)THEN  RUN  110
230 NA$= "":FOR I= 1TO 6
240 CC= PEEK (AD+ 6+ 2* I):IF CC= 32THEN I= 6:GOTO 260
250 NA$= NA$+ CHR$ (CC)
260 NEXT I
270 TY$= CHR$ (PEEK (AD+ 22))+ CHR$ (PEEK (AD+ 24))+ CHR$ (PEEK (AD+ 26))
280 VE$= CHR$ (PEEK (AD+ 30))+ CHR$ (PEEK (AD+ 32))
290 V= ASC (RIGHT$ (VE$,1)):V= V+ 1:VG$= CHR$ (V)
300 VF$= CHR$ (PEEK (AD+ 30))+ VG$
310 SP$= NA$+ "."+ TY$+ ";"+ VE$
320 SQ$= NA$+ "."+ TY$+ ";"+ VF$
360 PLOT  27,4:PRINT "REN ";SP$;" TO ";SQ$
370 PLOT 27,27,12:RUN 110
400 PLOT 6,35,3,21,2,14:PRINT "CHANGE VERSION NUMBER"
405 PLOT 15,6,6:PRINT :PRINT
410 PRINT "THIS PROGRAM WILL ENABLE THE USER TO CHANGE THE VERSION NUMBERS"
420 PRINT "ON THE DISK DIRECTORY. THIS IS USEFUL FOR GIVING BACK-UP COPIES"
430 PRINT "DIFFERENT VERSION NUMBERS SO THAT, WHEN  USING  THE  CATALOGUE,"
440 PRINT "YOU CAN SELECTIVELY PRINT ONLY THE ORIGINAL VERSION NUMBERS AND"
450 PRINT "THUS NOT REPEAT PROGRAMS ON THE PRINT OUT. THE PROGRAM AS IT IS"
460 PRINT "SET UP WILL INCREASE THE VERSION NUMBER BY 1. IF  YOU  WISH  TO"
470 PRINT "VARY THIS, CHANGE V=V+1 IN LINE 290."
480 PRINT :PRINT "NOTE:";:PLOT 6,6:PRINT "  THE COMPUTER WILL NOT CHANGE VERSION 01 TO VERSION 02 IF"
490 PRINT "VERSION 02 ALREADY EXISTS. CHANGE VERSION 02 FIRST."
500 PRINT :PRINT "THE PROGRAM COULD BE VARIED QUITE EASILY TO RENAME THE FILE  OR"
510 PRINT "CHANGE THE FILE TYPE,AS WELL AS THE VERSION NUMBERS. IF THIS IS"
520 PRINT "REQUIRED,  VARY LINES 230-320,  HOWEVER,  THAT IS PROBABLY BEST"
530 PRINT "ACCOMPLISHED BY USING THE DISK EDITOR PROGRAM."
535 PRINT :PRINT
540 PRINT "TO USE:";:PLOT 6,6:PRINT "    FOLLOW THE COMMANDS GIVEN TO MOVE THE CYAN HATCH AND"
550 PRINT "RUN THE PROGRAM."
600 PLOT 6,2,3,5,30:INPUT "INSERT THE DISK TO BE CHANGED AND PRESS RETURN.";R$
610 RETURN
620 PLOT 12,3,10,16:INPUT "INSERT NEXT DISK AND PRESS RETURN";R$
630 RUN 110