Listing of file='SIN3.BAS;01' on disk='vmedia/chip_36-sector.ccvf'
1 REM REVIEW OF SINE WAVES
2 REM
3 REM TUTORIAL AND REVIEW OF THE AMPLITUDE, PERIOD, AND
4 REM HORIZONTAL AND VERTICAL DISPLACEMENTS OF SINE WAVES
5 REM 16K COMPUCOLOR
6 REM
10 REM PROGRAM WRITTEN BY JEAN BOHRER
11 REM UNDER THE DIRECTION OF MARJORIE A. FITTING
12 REM DEPARTMENT OF MATHEMATICS AND COMPUTER SCIENCE
13 REM SAN JOSE STATE UNIVERSITY, SAN JOSE, CA 95192
20 REM
21 REM "______________________________"
22 REM "! SAN MATEO COUNTY !"
23 REM "! OFFICE OF EDUCATION !"
24 REM "! & !"
25 REM "! COMPUTER-USING EDUCATORS !"
26 REM "! !"
27 REM "! SOFTSWAP !"
28 REM "! !"
29 REM "!333 MAIN STREET, REDWOOD CITY!"
30 REM "!CA 94063 (415)364-5600 EX4401!"
31 REM "_______________________________"
40 REM "_______________________________"
41 REM "! PROGRAMS MAY BE COPIED FOR !"
42 REM "! EDUCATIONAL USE ONLY AND !"
43 REM "! ARE NOT TO BE SOLD. !"
44 REM "!!"
50 REM
60 REM
100 PLOT 12,23
110 PRINT "YOU ARE NOW AWARE OF 4 CONSTANTS THAT AFFECT THE"
120 PRINT "FORM OF THE GRAPH Y=SIN(X). THIS ENABLES US TO"
130 PRINT "STATE THE GENERAL EQUATION OF A SINE WAVE:"
140 PRINT :PRINT
150 PLOT 14
160 PRINT TAB( 10);"Y = A * SIN( B * ( X + C ) ) + D"
170 PLOT 15
180 PRINT :PRINT
190 PRINT "CHOOSE THE NUMBER OF THE CORRECT RESPONSE TO THE"
200 PRINT "QUESTIONS THAT FOLLOW."
210 PRINT
220 PRINT TAB( 6);"(1) PERIOD"
230 PRINT TAB( 6);"(2) VERTICAL TRANSLATION OF GRAPH"
240 PRINT TAB( 6);"(3) PHASE SHIFT"
250 PRINT TAB( 6);"(4) AMPLITUDE"
260 PRINT :PRINT
270 INPUT "WHAT QUANTITY DOES A AFFECT?";A
280 IF A= 4THEN 310
290 PRINT TAB( 4);"NO. A AFFECTS THE AMPLITUDE OF THE CURVE."
300 GOTO 320
310 PRINT TAB( 4);"CORRECT!"
320 PRINT
330 INPUT "WHAT QUANTITY DOES B AFFECT?";B
340 IF B= 1THEN 370
350 PRINT TAB( 4);"SORRY, B AFFECTS THE PERIOD OF THE CURVE."
360 GOTO 380
370 PRINT TAB( 4);"GOOD!"
380 PRINT
390 INPUT "WHAT QUANTITY DOES C AFFECT?";C
400 IF C= 3THEN 430
410 PRINT TAB( 4);"WRONG. C TELLS YOU THE PHASE SHIFT."
420 GOTO 440
430 PRINT TAB( 4);"RIGHT!"
440 PRINT
450 INPUT "WHAT QUANTITY DOES D AFFECT?";D
460 IF D= 2THEN 490
470 PRINT TAB( 4);"NO. D AFFECTS THE VERTICAL TRANSLATION."
480 GOTO 500
490 PRINT TAB( 4);"GOOD JOB!"
500 PLOT 3,35,30
510 INPUT "PRESS RETURN TO CONTINUE";A
520 PLOT 12
530 PLOT 3,0,10
540 PRINT "SOME OR ALL OF THESE CONSTANTS MAY APPEAR IN THE"
550 PRINT "EQUATION OF A PARTICULAR SINE WAVE."
560 PRINT "IN THE EXERCISE THAT FOLLOWS, Y=SIN(X) WILL BE"
570 PRINT "GRAPHED. YOU WILL THEN CHOOSE VALUES FOR A, B,"
580 PRINT "C AND D ONE AT A TIME TO CHANGE THE GRAPH."
590 PLOT 3,35,30
600 INPUT "PRESS RETURN TO CONTINUE.";A
610 PLOT 12
620 GOSUB 1320
630 PLOT 3,4,0
640 A= 0
650 B= 1
660 C= 0
670 D= 0
680 INPUT "LET A BE 1, 1.5, OR 2. A=?";A
690 PLOT 22
700 PLOT 3,39,0
710 PRINT "Y=";A;"*SIN(X)"
720 GOSUB 1750
730 PLOT 3,4,1
740 INPUT "LET B BE .5, 1, OR 2. B=?";B
750 PLOT 19
760 PLOT 3,39,1
770 PRINT "Y=";A;"*SIN(";B;"*X)"
780 GOSUB 1750
790 PLOT 3,4,2
800 INPUT "LET C BE 0, 1, OR 2. C=?";C
810 PLOT 21
820 PLOT 3,39,2
830 PRINT "Y=";A;"*SIN(";B;"*(X+";C;"))"
840 GOSUB 1750
850 PLOT 3,4,3
860 INPUT "LET D BE -1, 0, OR .5. D=?";D
870 PLOT 18
880 PLOT 3,39,3
890 PRINT "Y=";A;"*SIN(";B;"*(X+";C;"))+";D;
900 GOSUB 1750
910 PLOT 3,0,26
920 PLOT 23
930 PRINT "EXAMINE THE LAST GRAPH AND EQUATION."
940 PRINT
950 INPUT "WHAT IS THE AMPLITUDE?";M
960 IF M= ABS (A)THEN PRINT "RIGHT!":GOTO 980
970 PRINT "SORRY, THE AMPLITUDE IS ";ABS (A)
980 GOSUB 1800
990 INPUT "THE PERIOD IS HOW MANY INTERVALS OF PI?";N
1000 IF N= 2/ ABS (B)THEN PRINT "CORRECT!":GOTO 1020
1010 PRINT "SORRY, THE PERIOD IS ";2/ ABS (B);" INTERVALS OF PI."
1020 GOSUB 1800
1030 INPUT "WHAT IS THE PHASE SHIFT?";P
1040 IF P= CTHEN PRINT "GOOD!":GOTO 1060
1050 PRINT "NO, THE PHASE SHIFT IS";C
1060 GOSUB 1800
1070 INPUT "WHAT IS THE DISPLACEMENT FROM THE X-AXIS?";Q
1080 IF Q= DTHEN PRINT "YOU'RE RIGHT!":GOTO 1100
1090 PRINT "NO, THE DISPLACEMENT IS";D
1100 PRINT
1110 INPUT "DO YOU WANT TO TRY ANOTHER SET OF GRAPHS?(Y/N)";A$
1120 IF A$= "Y"THEN 610
1130 PLOT 12,23
1140 PRINT "WE CAN NOW SUMMARIZE WHAT WE KNOW RELATING THE"
1150 PRINT "EQUATIONS AND GRAPHS OF SINE WAVES."
1160 PRINT :PRINT
1170 PLOT 14
1180 PRINT TAB( 10);"Y = A * SIN( B * ( X + C ) ) + D "
1190 PRINT :PRINT
1200 PRINT TAB( 12);"nAn IS THE AMPLITUDE"
1210 PRINT
1220 PRINT TAB( 12);"2*PI/nBn IS THE PERIOD"
1230 PRINT
1240 PRINT TAB( 12);"C IS THE PHASE SHIFT"
1250 PRINT
1260 PRINT TAB( 12);"D IS THE VERTICAL TRANSLATION"
1270 PLOT 15
1280 PRINT :PRINT :PRINT
1290 INPUT "WOULD YOU LIKE TO RUN THIS PROGRAM AGAIN?(Y/N)";A$
1300 IF A$= "Y"THEN 100
1305 LOAD "MENU":RUN
1310 END
1320 REM PLOTS AXES
1330 PLOT 20
1340 FOR X= 3TO 54
1350 PLOT 3,X,14
1360 PRINT "f"
1370 NEXT X
1380 PLOT 3,16,13
1390 PRINT "m"
1400 PLOT 3,28,13
1410 PRINT "o"
1420 PLOT 3,41,13
1430 PRINT "m"
1440 PLOT 3,53,13
1450 PRINT "o"
1460 FOR X= 2TO 25
1470 PLOT 3,3,X
1480 PRINT "o"
1490 NEXT X
1500 PLOT 3,1,3
1510 PRINT "3e"
1520 PLOT 3,1,6
1530 PRINT "2_"
1540 PLOT 3,1,10
1550 PRINT "1i"
1560 PLOT 3,1,14
1570 PRINT "0f"
1580 PLOT 3,0,18
1590 PRINT "-1e"
1600 PLOT 3,0,21
1610 PRINT "-2_"
1620 PLOT 3,0,25
1630 PRINT "-3i"
1640 PLOT 3,55,14
1650 PRINT "(UNITS OF"
1660 PLOT 3,58,15
1670 PRINT "PI)"
1680 PLOT 17
1690 FOR X= 0TO 100STEP 2
1700 PLOT 2,X+ 7,15* SIN (X/ 8)+ 70,255
1710 NEXT X
1720 PLOT 3,46,28
1730 PRINT "Y=A*SIN(B*(X+C))+D"
1740 RETURN
1750 REM GRAPHS Y=ASIN(BX+C)+D
1760 FOR X= 0TO 100STEP 2
1770 PLOT 2,X+ 7,A* 15* SIN (B* (X/ 8+ C))+ 70+ D* 15,255
1780 NEXT X
1790 RETURN
1800 REM ERASES LINES
1810 FOR K= 1TO 2000:NEXT K
1820 PLOT 3,0,28
1830 PRINT " "
1840 PRINT " "
1850 PLOT 3,0,28
1860 RETURN