Listing of file='TRIFCT.BAS;01' on disk='vmedia/chip_36-sector.ccvf'
1 REM FACTORING TRINOMIALS APRIL 1981
2 REM
3 REM GENERATION OF TRINOMIALS AND FACTORS FOR EXERICSES
5 REM 16K COMPUCOLOR
6 REM
10 REM PROGRAM WRITTEN BY JOSEPH SOUSA
11 REM MILPITAS HIGH SCHOOL, AND STUDENT AT
12 REM SAN JOSE STATE UNIVERSITY, SAN JOSE, CA 95192
20 REM
21 REM "______________________________"
22 REM "! SAN MATEO COUNTY !"
23 REM "! OFFICE OF EDUCATION !"
24 REM "! & !"
25 REM "! COMPUTER-USING EDUCATORS !"
26 REM "! !"
27 REM "! SOFTSWAP !"
28 REM "! !"
29 REM "!333 MAIN STREET, REDWOOD CITY!"
30 REM "!CA 94063 (415)364-5600 EX4401!"
31 REM "_______________________________"
40 REM "_______________________________"
41 REM "! PROGRAMS MAY BE COPIED FOR !"
42 REM "! EDUCATIONAL USE ONLY AND !"
43 REM "! ARE NOT TO BE SOLD. !"
44 REM "!!"
45 REM
46 PRINT CHR$ (12)
48 FOR J= 1TO 5:PRINT :NEXT J
49 PRINT ""
50 PRINT " SUPPLEMENTARY EXERCISES IN FACTORING FOR TEACHERS "
60 PRINT " ------------------------------------------------- "
70 PRINT " FACTORS OF TRINOMIALS OF THE FORM: "
75 PRINT
80 PRINT " 2"
90 PRINT " AX + BX + C"
100 PRINT
110 PRINT " A,B,C ARE RANDOMLY POSITIVE OR NEGATIVE"
120 PRINT
140 PRINT " EXERCISES INCREASE GRADUALLY IN LEVEL OF DIFFICULTY."
150 PRINT " SOME EXERCISES MAY DUPLICATE OTHERS DUE TO RANDOM "
160 PRINT " GENERATION OF THE COEFFICIENTS. THE FACTORED FORMS"
170 PRINT " PRODUCED MAY CONTAIN COMMON MONOMIAL FACTORS."
180 PRINT
185 PRINT :INPUT "PREPARE PRINTER AND PRESS <RETURN> WHEN READY. ";Y$
190 P= 1
200 N= 1
210 M= 5
220 M1= 6
230 R1= INT (RND (8)* M+ 1)
240 R2= INT (RND (8)* M+ 1)
250 S1= INT (RND (8)* M+ 1)
260 IF R1= S1THEN 250
270 IF R1/ 2< > INT (R1/ 2)THEN 290
280 IF S1/ 2= INT (S1/ 2)THEN 250
290 IF R1/ 3< > INT (R1/ 3)THEN 310
300 IF S1/ 3= INT (S1/ 3)THEN 250
310 S2= INT (RND (8)* M1+ 1)
320 IF R2= S2THEN 310
330 FOR K= 2TO 3
340 IF R2/ K< > INT (R2/ K)THEN 360
350 IF S2/ K= INT (S2/ K)THEN 310
360 NEXT K
370 IF N> = 8THEN 390
380 IF R1* R2> 9THEN 230
390 IF N< = 16THEN 410
410 IF N< 20THEN 440
420 GOSUB 770
430 R1= R1* T
440 GOSUB 770
450 S1= S1* T
460 GOSUB 770
470 S2= S2* T
480 A= R1* R2
490 B= R1* S2+ R2* S1
500 C= S1* S2
520 PRINT N;".";" 2"
530 PRINT " ";A;"X + ";B;"X + ";C;"= ";
535 PRINT "(";R1;"X + ";S1;")(";R2;"X + ";S2;")"
540 IF N= 6THEN 570
550 PRINT
560 GOTO 590
570 M= M+ 1
580 M1= M1+ 1
590 N= N+ 1
600 IF N= 18THEN 640
620 IF N= 37THEN 640
630 GOTO 230
640 PRINT
650 PRINT " PAGE ";P
660 P= P+ 1
670 FOR K= 1TO 10
680 PRINT
690 NEXT K
700 IF N= 37THEN 840
710 IF N= 19THEN 730
720 GOTO 230
730 M= M+ 2
740 M1= M1+ 3
750 GOTO 230
770 Z7= INT (RND (8)* 9+ 1)
780 IF Z7> 5THEN 810
790 Z7= - 1
800 GOTO 820
810 Z7= 1
820 T= Z7
830 RETURN
840 FOR K= 1TO 2000:NEXT K
850 LOAD "MENU":RUN
900 END