Compucolor.org – Virtual Media

Listing of file='CHOOSE.BAS;01' on disk='vmedia/chip_62-sector.ccvf'

100 PLOT 12,22:REM  FORMATTER OVERLAY
110 REM  PROGRAM TO MODIFY COMPUCOLOR'S DISC FORMATTER DEFAULT
120 REM  INITIALIZATION NAME AND DIRECTORY SIZE ( 'BLANK 03' ),
130 REM  TO A NEW NAME AND A LARGER DIRECTORY.
140 REM
150 REM  BY MYRON T. STEFFY, SUN CITY, ARIZONA  06/10/81 ""
160 REM
200 PLOT 12:PRINT TAB( 18)"PERSONALIZE YOUR FORMATTER":PRINT
210 REM
240 PRINT TAB( 8)"GIVE A FORMATTED DISC A NAME OF YOUR OWN CHOOSING":PRINT
250 PRINT TAB( 12)"AND INCREASE THE DIRECTORY SIZE AS NEEDED.":PRINT
260 PRINT "REQUIRED:"
270 PRINT :PRINT "1. A COPY OF THE COMPUCOLOR DISC FORMATTER PROGRAM IN DRIVE 0."
280 PRINT :PRINT "2. SPACE ON THIS OR ANOTHER DISC FOR THE ALTERED PRORAM."
290 PRINT :PRINT TAB( 3)"( APPROXIMATELY  2030 BYTES )"
300 PRINT :PRINT TAB( 18):INPUT "WHEN READY, PRESS RETURN: ";R
310 IF PEEK (36864)+ PEEK (36865)= 100THEN 340
320 PRINT :PLOT 27,4:PRINT "LOAD FORMAT.PRG;01":PLOT 27,27
330 IF PEEK (36864)+ PEEK (36865)< > 100THEN PRINT "IMPROPER OR MISSING PROGRAM ":PRINT :GOTO 260
340 PRINT
350 PRINT "ENTER NEW DISC NAME TO BE INCLUDED IN THE INITIALIZATION.":PRINT
360 PRINT "NOT MORE THAN 10 LETTERS OR FIGURES, NO PUNCTUATION OR SPACES:"
370 PRINT "______________________________________________________________":PRINT
400 PRINT :PRINT TAB( 33);"           n"
410 PLOT 28:PRINT "TYPE IN YOUR NEW DISK NAME HERE: n";
420 PLOT 22:INPUT "";A$:PLOT 6,2
430 IF LEN (A$)> 10THEN 360
440 PRINT
450 PRINT "EACH DIRECTORY BLOCK HOLDS FIVE PROGRAM LISTINGS. "
460 PRINT
470 PRINT "WE SUGGEST NOT LESS THAN 4 BE SET ASIDE.  YOUR CHOICE ";:INPUT B$
480 PRINT :IF B$= "0"THEN 470
490 PLOT 12,3,0,8
500 FOR L= 38877TO 38897:POKE L,0:NEXT L
510 POKE 37010,221:POKE 37011,151:REM  CHANGE DS OF DRIVE NO.
520 POKE 37120,221:POKE 37121,151:REM  SAME
530 POKE 37126,222:POKE 37127,151:REM  ADDRESS OF NEW NAME
540 POKE 38877,48:REM  DEFAULT DRIVE CD0
550 POKE 38878,58:REM  COLON FOLLOWING 'CD0'
560 C= LEN (A$):I= 1:E= 38879:REM  START OF NAME
570 FOR L= ETO E+ (C- 1)
590 POKE L,ASC (MID$ (A$,I,1))
600 I= I+ 1:NEXT L
610 POKE L,32:L= L+ 1:POKE L,ASC (B$)
630 DATA 13,27,27,239,0,0,0,
640 FOR L= L+ 1TO L+ 5
645 READ I
650 POKE L,I:NEXT L
700 PRINT "DIRECTORY VOLUME NAME AFTER FORMATTING AND INITIALIZATION ":PRINT
710 PRINT "WILL NOW READ: ' DIRECTORY CD0: ";A$+ "  0"+ B$;" '"
715 PRINT
720 PRINT "HAVE DISC TO RECEIVE ALTERED FORMAT PROGRAM IN DRIVE CD0."
725 PRINT
730 INPUT "WHEN READY, PRESS RETURN: ";R
740 PLOT 27,4:PRINT "SAVE FORMAT.PRG 9000 7EF":PLOT 27,27
745 PLOT 12,3,8,6
750 PRINT "PROGRAM HAS BEEN SAVED AS ' FORMAT.PRG;02 '."
760 PRINT
770 PRINT "    CAUTION - REMOVE DISC TO PREVENT FORMATTING IT!"
780 PRINT
790 PRINT "YOU MAY NOW TEST FORMATTING WITH A BLANK DISC BY ENTERING:":PRINT
800 PRINT TAB( 16)"' ESCAPE I ' (2 SECOND WAIT)"
810 PRINT :PRINT TAB( 24)"END":END