Compucolor.org – Virtual Media

Listing of file='GMTEST.BAS;01' on disk='vmedia/cm_0-4_paddle_games-sector.ccvf'

100 REM  COPYRIGHT (C) 1980  BY COLOR-MOD ENTERPRISES 
110 REM  ALL RIGHTS RESERVED 
120 REM
130 REM  GAMER SUBROUTINE TEST PROGRAM BY JIM AMOS
140 REM
150 POKE 32940,172:POKE 32941,159
160 POKE 33283,173:POKE 33284,159:PLOT 6,2,12,15,27,24
170 PLOT 27,4:PRINT "LOA GAMER3.PRG":PLOT 27,27,3,0,10
180 GOSUB 250:PRINT ,,"THIS IS THE PADDLE INPUT TEST"
190 PRINT ,,"I WILL TEST THE PADDLE RESPONSE"
200 PRINT ,,"AND THE TONE GENERATOR....."
210 PRINT :PRINT ,,"HIT ERASE PAGE TO CONTINUE"
220 FOR N= 1TO 25:C= CALL (50):NEXT :POKE 33278,0
230 IF  PEEK (33278)= 12THEN 260
240 GOTO 230
250 PLOT 6,63,2,0,0,242,127,0,127,127,0,127,0,0,255,6,2:RETURN
260 FOR N= 1TO 10:C= CALL (200):NEXT :PLOT 12:GOSUB 250
270 PLOT 3,0,10:PRINT ,,"NOW TESTING  THE TONE GENERATOR"
280 PLOT 3,0,15:PRINT ,,"RANDOM TONE GENERATION......"
290 FOR N= 1TO 50:C= CALL (RND (1)* 251+ 5):NEXT
300 PLOT 3,0,17:PRINT ,,"SEQUENTIAL TONE GENERATION"
310 FOR N= 5TO 75:C= CALL (N):NEXT
320 FOR N= 75TO 5STEP - 1:C= CALL (N):NEXT
330 PLOT 3,0,19:PRINT ,,"MAJOR SCALE TONE GENERATION"
340 FOR N= 1TO 16:READ P:POKE 40957,50:C= CALL (P)
350 FOR D= 1TO 200:NEXT :NEXT
360 DATA 255,227,202,191,170,152,135,128
370 DATA 202,180,161,152,135,120,107,101
380 FOR N= 1TO 20:C= CALL (100):NEXT :GOSUB 250
390 PLOT 12,3,0,10:PRINT ,,"NOW TESTING PADDLES FOR RESPONSE"
400 P1= CALL (1):P2= CALL (2)
410 PLOT 3,0,15,11:PRINT ,,P1,,P2
420 PLOT 3,0,13:PRINT ,,"PDL(1)",,"PDL(2)":GOTO 400