Compucolor.org – Virtual Media

Listing of file='TURKEY.BAS;01' on disk='vmedia/demos-sector.ccvf'

0 REM  TURKEY AND THE HUNTER
10 REM  VISIBLE AND BLIND CURSOR DEMO
20 PLOT 6,2,12:INPUT "VISIBLE OR BLIND CURSOR (V/B)?";A$
30 BC= MID$ (A$,1,1)= "B":VC= MID$ (A$,1,1)= "V"
40 IF BC+ VC< > - 1THEN 20
50 REM  DRAW BORDER AROUND SCREEN
60 PLOT 27,24:REM  PAGE MODE
61 PLOT 15:REM  A7 OFF - SMALL CHARACTERS
62 PLOT 6,0:REM  SET COLOR - BLACK FG/BLACK BG
63 PLOT 12:REM  ERASE PAGE
70 PLOT 6,15:REM  SET COLOR - WHITE FG/RED BG
71 FOR I= 1TO 64:PLOT 32:NEXT :REM  DRAW TOP LINE
72 PLOT 3,0,31:REM  MOVE CURSOR TO BOTTOM LINE
73 FOR I= 1TO 64:PLOT 32:NEXT :REM  DRAW BOTTOM LINE
74 PLOT 27,10:REM  WRITE VERTICAL MODE
75 PLOT 8:REM  MOVE CURSOR TO HOME
76 FOR I= 1TO 32:PLOT 32:NEXT :REM  DRAW LEFT SIDE
77 PLOT 3,63,0:REM  MOVE CURSOR TO TOP RIGHT
78 FOR I= 1TO 32:PLOT 32:NEXT :REM  DRAW RIGHT SIDE
79 PLOT 27,24:REM  PAGE MODE
90 PLOT 3,64,0:REM  MOVE BLINKING CURSOR OFF SCREEN
100 REM  SET UP GAME PARAMETERS
110 HX= 1:HY= 1:REM  HUNTER ORIGINAL POSITION
120 TX= 32:TY= 16:REM  TURKEY INITIAL POSITION
130 TS= 2:REM  TURKEY SPEED
150 HC= 39:TC= 15
180 REM  DEFINE FNR TO RETURN RANDOM INTEGER IN RANGE -X TO X
190 DEF FN R(X)= - X+ INT ((2* X+ 1)* RND (1))
200 REM  MOVE CURSOR TO TURKEY'S OLD POSITION
201 IF VCTHEN PLOT 3,TX,TY,6,0:REM  VISIBLE
202 IF BCTHEN PLOT 3,127,TX,TY,0:REM  BLIND
210 TX= TX+ FN R(TS):REM  CHANGE TURKEY X POSITION
220 TY= TY+ FN R(TS):REM  CHANGE TURKEY Y POSITION
230 IF TX< 1OR TX> 62OR TY< 1OR TY> 30THEN 1000:REM  ESCAPE!
240 PLOT 32:REM  CLEAR TURKEY'S LAST POSITION
250 REM  MOVE CURSOR TO TURKEY'S NEW POSITION
251 IF VCTHEN PLOT 3,TX,TY,6,TC:REM  VISIBLE
252 IF BCTHEN PLOT 3,127,TX,TY,TC:REM  BLIND
260 PLOT ASC ("T"):REM  OUTPUT TURKEY SYMBOL
300 REM  MOVE CURSOR TO HUNTER'S OLD POSITION
301 IF VCTHEN PLOT 3,HX,HY,6,0:REM  VISIBLE
302 IF BCTHEN PLOT 3,127,HX,HY,0:REM  BLIND
310 REM  RANDOM SELECT HUNTER'S MOVE IN X OR Y DIRECTION
320 IF RND (1)> (ABS (TY- HY)+ 1)/ (ABS (TY- HY)+ ABS (TX- HX)+ 2)THEN 500
400 HY= HY+ SGN (TY- HY):REM  MOVE TOWARDS TURKEY IN Y DIRECTION
410 GOTO 600
500 HX= HX+ SGN (TX- HX):REM  MOVE TOWARDS TURKEY IN X DIRECTION
600 PLOT 32:REM  CLEAR HUNTERS LAST POSITION
700 REM  MOVE CURSOR TO HUNTER'S LAST POSITION
701 IF VCTHEN PLOT 3,HX,HY,6,HC:REM  VISIBLE
702 IF BCTHEN PLOT 3,127,HX,HY,HC:REM  BLIND
710 PLOT ASC ("H"):REM  OUTPUT HUNTER SYMBOL
720 IF HX= TXAND HY= TYTHEN 2000:REM  HUNTER CATCHES TURKEY
800 GOTO 200
1000 REM  TURKEY ESCAPES
1010 PLOT 27,27:REM  VISIBLE CURSOR MODE
1020 PLOT 6,2:REM  SET COLOUR - GREEN FG/BLACK BG
1030 PLOT 8:REM  CURSOR HOME
1040 PRINT "TURKEY ESCAPES!!!"
1050 GOTO 3000
2000 REM  HUNTER CATCHES TURKEY
2010 PLOT 27,27:REM  VISIBLE CURSOR MODE
2020 PLOT 6,2:REM  SET COLOUR - GREEN FG/BLACK BG
2030 PLOT 8:REM  CURSOR HOME
2040 PRINT "GOBBLE GOBBLE......."
3000 FOR I= 1TO 1000:NEXT :REM  DELAY FOR A WHILE
3010 RUN