Compucolor.org – Virtual Media

Listing of file='MENU.BAS;01' on disk='vmedia/ncc_16-sector.ccvf'

50 CLEAR 1200
60 DIM F$(18)
100 PLOT 27,11,6,6,15,29,12
109
110 DN$= "3B ":REM  THIS DISK'S NUMBER
111 REM  DISK
115 DM$= "GRAPHIC DEMO # 4"
120 GOSUB 9000
130 FOR J= 1TO 23:D$= D$+ ". ":NEXT
189
190 REM  ENTER PROGRAM DESCRIPTIONS AS DATA STATEMENTS
191 REM  STARTING AT LINE 200.  FOR EXAMPLE:
192 REM
193 REM  200 DATA "STAR TREK (BATTLE THE KLINGONS)"
194 REM  210 DATA "TIC-TAC-TOE","MASTERMIND"
195 REM
196 REM  ...ETC.
197 REM
198 REM  MAXIMUM OF 18 FILES.
199
200 DATA  "HAND   (COMPUCOLOR TYPING-HAND)"
210 DATA  "MODART (CREATE YOUR OWN MASTER-PIECE)"
220 DATA  "FACE   (COMPUCOLOR MAN  VERY DETAILED)"
230 DATA  "SNOOPY (GOOD GRIEF CHARLIE BROWN)"
240 DATA  "NCC718 (CAPT. KIRK'S ENTERPRISE)"
250 DATA  "FUNNY  (GUESS WHO ?)"
260 DATA  "YINYAN (PART OF KOREAN FLAG)"
270 DATA "EUROPEAN ROULET- SIMILAR TO CCII #6"
998
999 REM  GET THE DESCRIPTIONS FOR THE MENU
1000 DATA "!"
1010 J= 0
1020 READ F$:IF (F$= "!")OR (J= 18)THEN 1100
1030 J= J+ 1:IF LEN (F$)/ 2< > INT (LEN (F$)/ 2)THEN F$= F$+ " "
1040 F$= LEFT$ (F$+ D$,47):IF J< 10THEN F$= F$+ " "
1050 F$(J)= F$+ STR$ (J)
1060 GOTO 1020
1100 IF J= 0THEN PRINT :PRINT TAB( 21)"NO PROGRAMS ON MENU":END
1110 IF J< 8THEN PLOT 14:PRINT
1120 IF (J< 5)OR ((J= 8)OR (J= 9))THEN EL= 1
1128
1129 REM  PRINT THE MENU
1130 PRINT :FOR K= 1TO J:PRINT TAB( 6)F$(K):IF ELTHEN PRINT
1140 NEXT
1150 IF J> 4THEN PRINT
1158
1159 REM  GET USER'S CHOICE
1160 INPUT "  ENTER THE NUMBER FOR YOUR CHOICE, THEN PRESS RETURN: ";C$
1170 C= VAL (C$)
1190 IF C< 1OR C< > INT (C)OR C> JTHEN PLOT 28,11:GOTO 1160
1198
1199 REM  REPRINT CHOSEN FILE DESCRIPTION IN RED
1200 Y= 4* C+ 5
1210 IF J> 4THEN Y= 2* C+ 9
1220 IF J> 7THEN Y= 2* C+ 9
1230 IF J> 9THEN Y= 10+ C
1240 PLOT 6,65:PLOT 3,6,Y:PRINT F$(C):PLOT 3,64,0
1249
1250 ON CGOTO 1301,1302,1303,1304,1305,1306,1307,1308,1309
1260 ON C- 9GOTO 1310,1311,1312,1313,1314,1315,1316,1317,1318
1297
1298 REM  ENTER LOAD AND RUN INSTRUCTIONS ON LINES
1299 REM  1301,1302,1303, ... , 1318.
1300 REM
1301 LOAD "HAND":RUN
1302 LOAD "MODART":RUN
1303 LOAD "FACE":RUN
1304 LOAD "SNOOPY":RUN
1305 LOAD "NCC718":RUN
1306 LOAD "FUNNY":RUN
1307 LOAD "YINYAN":RUN
1308 LOAD "RULET":RUN
7997
7998
7999 END
8998
8999 REM  LOGO
9000 REM
9170 PRINT TAB( 5)"COMPUCOLOR USERS' GROUP OF SYDNEY, NEW SOUTH WALES"
9190 PLOT 6,4,30:PRINT TAB( 10)"":PLOT 29
9200 PRINT TAB( 10);:PLOT 6,33:PRINT " DISK  # ";DN$
9210 PLOT 6,2:PLOT 3,35,5:PRINT DM$
9230 RETURN