Compucolor.org – Virtual Media

Listing of file='CRREC7.BAS;01' on disk='vmedia/stamp_price_lists-sector.ccvf'

100 REM  CREATE RANDOM RECORDS;42 BYTES EACH.
150 CLEAR 1000
200 REM  ASC YY DESCRIPTION_________________ $$$.CC
250 PRINT " CREATE OR ADD TO A RANDOM FILE OF 42 BYTE RECORDS."
300 PRINT
350 PLOT  14
400 PLOT 22
450 INPUT "ARE YOU ADDING TO AN EXISTING FILE? (Y OR N)";AD$
500 IF AD$< > "N"THEN PRINT "YES":AD= 1
550 PLOT  19
600 INPUT  "FILENAME?";F$
650 IF AD= 1THEN 850
700 PLOT  22
750 INPUT  "NO. OF RECORDS TO BE CREATED:";RE
800 FILE "N",F$,RE,42,6
850 FILE "R",1,F$,2
950 DIM A$(50)
1000 PLOT 18
1050 DIM C$(50)
1075 DIM OL$(42)
1100 PLOT  23:INPUT  "WAPEX NUMBER:";WN$:PLOT  18
1150 WN= VAL (WN$)
1170 IF WN= 999THEN 2300
1175 IF WN> 300THEN PRINT "NUMBER CANNOT BE >300.":GOTO 1100
1250 IF  WN< > 0 THEN 1370
1300 W1= W1+ 1
1350 WN= W1
1370 IF AD= 0THEN 1400
1373 IF WN> 300THEN PRINT "NUMBER IS >300.":GOTO 1100
1375 GET 1,WN;OL$[42]
1380 PLOT 19:PRINT WN,OL$:PLOT 18
1390 W1= WN
1395 INPUT "AMMEND?(Y OR N)";AM$
1396 IF AM$< > "Y"THEN 1100
1400 PRINT "CREATE OR AMMEND RECORD FOR WAPEX NO.",WN
1450 PRINT " ASC YY DESCRIPTION_________"
1500 INPUT  A$
1550 INPUT "MUH $$$.CC:";B$
1600 FOR I= LEN (A$)TO  27
1650 A$= A$+ " "
1700 NEXT I
1750 GOTO 2550
1800 INPUT "F.USED $$$.CC:";U$
1850 FOR  U= LEN (U$)TO  6
1900 U$= " "+ U$
1950 NEXT  U
2000 C$= A$+ B$+ U$
2050 PLOT  21:PRINT  C$:PLOT  18
2100 PUT 1,WN,1;C$[42]
2150 W1= WN
2200 PRINT "RECORD FOR WAPEX N0:",WN,"WRITTEN."
2250 GOTO 1100
2300 FILE "C",1
2350 PLOT 21
2400 PRINT "FILE CLOSED"
2450 PLOT 18
2500 GOTO 2750
2550 FOR J= LEN (B$)TO 6
2600 B$= " "+ B$
2650 NEXT J
2700 GOTO 1800
2725 FILE "T",2730
2730 FILE "E",FL,ER,LN
2735 PRINT "DISK ERROR:",ER,"OCCURRED IN LINE:",LN
2740 GOTO 1100
2750 END