Compucolor.org – Virtual Media

Listing of file='LISTPG.BAS;01' on disk='vmedia/taylor_4-sector.ccvf'

65000 REM PROGRAM NAME: PRINT
65010 REM AUTHOR: RICKI A. VICK 3APR80
65020 REM FUNCTION: PRINT PROGRAM LISTINGS ON LINE PRINTER WITH DATE/TIME
65030 REM CATEGORY: BASIC
65040 REM MEMORY REQUIRED: 8K
65050 REM VERSION: V6.78 OR V8.79
65060 REM SPECIAL HARDWARE: LINE PRINTER VIA RS232 PORT
65070 REM SPECIAL SOFTWARE: NONE
65080 PLOT  30,16,29,18 : PRINT "PRINT LISTING OF THIS PROGRAM ON THE PRINTER":PLOT  29,17
65090 ADR= 256* PEEK (32941)+ PEEK (32940)
65100 IF ADR= 65535GOTO 65120
65110 YR= PEEK (ADR+ 1):MO= PEEK (ADR+ 2):DY= PEEK (ADR+ 3):IF  YR> = 80GOTO 65240
65120 INPUT  "TODAY'S DATE (YEAR/MONTH/DAY HOURSMINUTES) IS?";D$
65130 YR= VAL (LEFT$ (D$,4))- 1900:D$= RIGHT$ (D$,(LEN (D$)- 5))
65140 MO= VAL (LEFT$ (D$,2)):D$= RIGHT$ (D$,(LEN (D$)- 3))
65150 DY= VAL (LEFT$ (D$,2))
65160 ADR= ADR- 15:ZZ= INT (ADR/ 256):POKE 32940,ADR- 256* ZZ:POKE 32941,ZZ
65170 POKE ADR+ 1,YR:POKE ADR+ 2,MO:POKE ADR+ 3,DY
65180 IF  LEN (D$)= 2 THEN 65240
65190 D$= RIGHT$ (D$,(LEN (D$)- 3))
65200 HR= VAL (LEFT$ (D$,2)):D$= RIGHT$ (D$,(LEN (D$)- 2))
65210 MI= VAL (LEFT$ (D$,2))
65220 SS= 0
65230 POKE  33209,SS:POKE  33210,MI:POKE  33211,HR
65240 SS= PEEK (33209):MI= PEEK (33210):HR= PEEK (33211)
65250 PRINT  "TODAY'S DATE IS: ";YR* 100+ MO;".";RIGHT$ (STR$ (DY+ 100),2)
65260 PRINT  "THE TIME IS:      ";RIGHT$ (STR$ (HR* 100+ MI+ 10000),4);":";RIGHT$ (STR$ (SS+ 100),2)
65270 PRINT "ENTER THE ";:PLOT 34:PRINT "VOLUME:FILE NAME";:PLOT 34:INPUT  " (IN QUOTES): ";N$
65280 IF VAL (N$)= 0THEN N$= "R VICK 09:PRINT.BAS;01"
65290 PLOT 15,27,18,7:POKE 33289,79:PLOT 27,13,27,117,1,12
65300 SS= PEEK (33209):MI= PEEK (33210):HR= PEEK (33211)
65310 PRINT N$;" LISTING AS OF: ";YR* 100+ MO;".";RIGHT$ (STR$ (DY+ 100),2);"  ";
65320 PRINT RIGHT$ (STR$ (HR* 100+ MI+ 10000),4);":";RIGHT$ (STR$ (SS+ 100),2)
65330 PRINT :PRINT
65340 OUT 8,255:OUT 8,4:POKE  33265,14:LIST :PRINT :PLOT 12,12:OUT 8,255:POKE 33265,0:POKE 33289,64
65350 END