Compucolor.org – Virtual Media

Listing of file='COLORH.BAS;01' on disk='vmedia/trader-sector.ccvf'

100 REM Y ******************************************************
110 REM COLOR HUNT 01/01/81, FOR 3650/9650 SERIES BY GAB
120 REM COPYRIGHT (C) 1981 BY INTELLIGENT SYSTEMS CORP.
130 POKE 32940,55
140 OUT 8,207:REM ENABLE KEYBOARD
150 TM= 256* PEEK (32941)+ PEEK (32940)
160 Z= TM+ 1:AD= 33283
170 ZZ= INT (Z/ 256):POKE AD,Z- 256* ZZ:POKE AD+ 1,ZZ
180 POKE 33282,195
190 PLOT 29,27,24,15,14,6,33,12
200 PLOT 3,25,10:PRINT " COLOR HUNT "
210 T= PEEK (33209):FOR I= OTO T:R= RND (1)
220 CLEAR 100
230 PRINT "

SELECT:
":PRINT "		    1. REGULAR COLOR HUNT
240 PRINT "		    2. ADVANCED COLOR HUNT
"
250 PRINT ,,,:PLOT 7:INPUT "ENTER 1 OR 2: ";Q:IF Q< 1OR Q> 2THEN 250
260 Q= Q- 1:M= 4+ Q
270 DIM G(M),S(M),D(M),C(M)
280 PLOT 29,15,6,38,12,6,2:FOR I= 2TO 6:PLOT 3,6,I
290 PRINT "                     ":NEXT I
300 PLOT 3,12,3:PRINT "INTECOLOR"
310 IF Q= 1THEN PLOT 3,12,4:PRINT "ADVANCED"
320 PLOT 3,11,5:PRINT "COLOR HUNT"
330 V$= "                     ":H$= "                     "
340 H$= MID$ (H$,3- 2* Q,19+ 4* Q)
350 T$= " X X X X X "
360 T$= LEFT$ (T$,22+ 5* Q)
370 B$= "           ":B$= LEFT$ (B$,9+ 2* Q)
380 H= 38:V= 6
390 PLOT 27,10:FOR I= 0TO 1:PLOT 6,56- 24* I
400 FOR X= 0TO M- 1:PLOT 3,H+ I* 2* (M+ 1)+ X* 2+ 1,V:PRINT V$
410 NEXT X:NEXT I:FOR X= 0TO 2* M+ 1
420 PLOT 6,- (X> M)* 40
430 PLOT 3,H+ 2* X,V:PRINT V$:NEXT X:PLOT 27,24,6,0
440 FOR Y= VTO V+ 20STEP 2:PLOT 3,H+ 1,Y
450 PLOT 30,16:PRINT H$:NEXT Y:PLOT 30,16
460 FOR Y= V- 4TO V- 2:PLOT 3,H,Y:PRINT B$:NEXT Y
470 PLOT 3,H,V- 3:PRINT T$
480 PLOT 29,3,8,9,6,38:PRINT "INSTRUCTIONS":PRINT
490 PRINT "  USE THE 6 COLOR KEYS TO GUESS  "
500 PRINT "  WHAT IS HIDDEN UNDER EACH X,"
510 PRINT "  NOT WHITE OR BLACK."
520 PRINT "  PRESS  R  TO REPEAT LINE.":PRINT :PRINT
530 PRINT ,"CLUES:":PRINT
540 PRINT "  BLACK   = 1 RIGHT COLOR & PLACE"
550 PRINT "  WHITE   = RIGHT COLOR WRONG PLACE"
560 PRINT "  MAGENTA = COLOR & PLACE WRONG.":PRINT :PRINT
570 PRINT "  NOTE: POSITION OF BLACK AND WHITE"
580 PRINT "  DOESN'T CORRESPOND TO THE SQUARES"
590 PRINT "  THAT YOU ARE TRYING TO GUESS."
600 FOR I= 1TO M:C(I)= 9* (1+ INT (6* RND (1))):NEXT I
610 Y= V+ 1
620 FOR I= 29TO 30:PLOT 6,38,3,0,I,11:NEXT I
630 C= 63:FOR X= 1TO M:GOSUB 880:NEXT X:X= 1
640 C= 57:GOSUB 890:I= CALL (2):IF I= - 1THEN 640
650 IF I= 82THEN 620
660 ON - (I< 17OR I> 22)GOTO 640:C= 9* (I- 16):G(X)= C
670 GOSUB 880:X= X+ 1:IF X< M+ 1THEN 640
680 PLOT 3,14,29,6,38:PRINT "PRESS RETURN IF YOU ARE SATISFIED"
690 PLOT 3,14,30:PRINT " OR PRESS  R  TO REPEAT THE ROW:";
700 I= CALL (2):ON - (I= - 1OR I< > 13AND I< > 82)GOTO 700
710 PRINT :ON - (I= 82)GOTO 620
720 N= 1:FOR I= 1TO M:D(I)= C(I):S(I)= 45:NEXT I
730 FOR I= 1TO M
740 IF G(I)= D(I)THEN S(N)= 0:G(I)= 0:D(I)= 1:N= N+ 1
750 NEXT I:FOR I= 1TO M:FOR J= 1TO M
760 IF G(I)= D(J)THEN S(N)= 63:G(I)= 0:D(J)= 1:N= N+ 1
770 NEXT J:NEXT I
780 FOR I= 1TO M:X= I+ M+ 1:C= S(I):GOSUB 880:NEXT I
790 P= 0:FOR I= 1TO M:IF S(I)= 0THEN NEXT I:P= 1:GOTO 810
800 Y= Y+ 2:IF Y< V+ 21THEN 620
810 P$(0)= "BAD LUCK !!  BETTER LUCK NEXT TIME."
820 P$(1)= "CONGRATULATIONS !!  ALL CORRECT."
830 Y= V- 3:FOR X= 1TO M:C= C(X):GOSUB 880:NEXT X
840 PLOT 6,38,3,0,29,11,10,11,3,16,28:PRINT P$(P)
850 PRINT ,,"PRESS RETURN TO PLAY AGAIN,"
860 PRINT ,,"ENTER  M  TO SEE MENU:  ";:PLOT 7:INPUT "";Z$
870 ON - (Z$< > "M")GOTO 190:PLOT 6,2,12,1
880 PLOT 3,H- 1+ 2* X,Y,6,C,32,26:RETURN
890 PLOT 3,H- 1+ 2* X,Y,6,C,31,63,15,26:RETURN